* Enhanced: Added a third parameter nFlags (defined in the header file 
            i_misc.ch) and fourth parameter lNewFolderButton to the function 
            GetFolder() and the 3rd and 4th parameters cTitle, cInitPath to 
            the function BrowseForFolder(). These parameters are an optional. 
            If an initial path or BIF flag were not specified then a new 
            UI with an editbox and validation will be used by default in 
            the above functions. 
            Syntax: 
            GetFolder( [ Title ], [ InitPath ], [ BIF Flag ], ; 
               [ New Folder Button ] ) -> Folder Name 
            BrowseForFolder( [Folder Type], [ BIF Flag ], [ Title ], ; 
               [ InitPath ] ) -> Folder Name 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo in folder \samples\Basic\GetFolder) 
   * Enhanced: Tuning of a back color of the Slider, transparent CheckBox 
            and RadioGroup controls at an owner-draw colored TAB. 
            If the back color of above controls was not specified then 
            it will be defined automatically as Tab's back color. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
   * Changed: Removed a silent assigning of 'Transparent' property to 
            the Label and CheckBox controls when a such control was placed 
            into a Tab control (introduced in the build 18). 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
   * Updated: DO REPORT command: cleanup of using of the private variables. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo in folder \samples\Basic\DO_REPORT) 
   * Updated: The header file i_winuser.ch used to resolve WinAPI constants. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see i_winuser.ch in folder \include) 
   * Updated: Adaptation FiveWin Class TSBrowse 9.0 in HMG:  
            - New: added handling of the var cName in TSColumn class; 
            - New: added handling of a new Column var lOnGotFocusSelect; 
            - Updated: minor correction in the function cValToChar(). 
            Contributed by SergKis. 
   * Updated: HbSQLite3 library: 
            - update for using SQLITE3 version 3.8.11.1 (from 3.8.11). 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
   * Updated: Harbour Compiler 3.2.0dev (SVN 2015-08-01 13:14): 
            - added a new code for the function ASort(). 
              Contributed by Przemyslaw Czerpak. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (look at ReadMe.txt in folder \harbour) 
   * Updated: 'WAIT WINDOW with an expectation in a thread' sample. 
            Contributed by Verchenko Andrey <verchenkoag@gmail.com>. 
            (see demo2.prg in folder \samples\Basic\WAIT_WINDOW_2) 
   * Updated: 'Paths' sample (demo functions for show system paths). 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see in folder \samples\Basic\Paths) 
   * Updated: 'Process Information' sample is based on the ProcInfo library: 
            - added a hung detection for the applications (based upon the 
              undocumented WinAPI function IsHungAppWindow()); 
            - added a test hunging application. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see in folder \samples\Advanced\ProcInfo) 
 

 
 h_tbrowse.prg 
 ~~~~~~~~~~~~~ 
 ... 
  
 Function SetArray2( ControlName, ParentForm, Arr, uFontHF, aHead, aSizes, uFooter, aPicture, aAlign, aName ) 
     Local ix, oBrw 
     ix := GetControlIndex (ControlName,ParentForm) 
     oBrw:= _HMG_aControlIds [ix] 
     oBrw:SetArray2(Arr, uFontHF, aHead, aSizes, uFooter, aPicture, aAlign, aName) 
 Return oBrw 
 ... 
  
 CLASS TSBrowse FROM TControl 
 ... 
  
    METHOD SetArray( aArray, lAutoCols, aHead, aSizes )      //V90 
    METHOD SetArray2( aArray, uFontHF , aHead, aSize, uFooter, aPicture, aAlign, cName ) 
  
 ENDCLASS 
  
 ... 
  
 METHOD SetArray2( aArray, uFontHF, aHead, aSizes, uFooter, aPicture, aAlign, aName )   CLASS TSBrowse   
  
    Local nColumns, nI, cType, nMax, bData, cHead 
    Local nN, cData, aDefMaxVal, aDefMaxLen, aDefType, aDefAlign, aDefFooter, oCol, ; 
          nAlign, aAligns, lFooter := .F., cFooter, nFooter, cTemp, cPict, ; 
          hFont := If( ::hFont != Nil, ::hFont, 0 ), aFont, lSelected, ; 
          lFont := hFont != 0, hFontHead := hFont, hFontFoot := hFont 
  
    If empty(aArray) .or. ValType(aArray) != "A" 
       nN := 1000 
       aArray := Array(nN) 
       For nI := 1 To nN 
           aArray[ nI ] := { nI, PadR("Line - "+StrZero(nI, 5), 20), ; 
                                 Date()+(nI-1), ; 
                                 Round(nN / nI, 3), ; 
                                 nI % 2 == 0 } 
       Next 
    EndIf 
  
    Default aHead     := AClone(::aHeaders), ;             
            aSizes    := AClone(::aColSizes), ;   
            aPicture  := AClone(::aFormatPic), ; 
            aAlign    := If( ISARRAY(::aJustify), AClone(::aJustify), {} ), ; 
            aName     := {} 
  
    If empty(uFontHF) 
       uFontHF := { hFontHead, hFontFoot } 
    ElseIf ValType(uFontHF) == "N" .and. uFontHF != 0 
       uFontHF := { uFontHF, uFontHF } 
    ElseIf ValType(uFontHF) == "A" 
       If Len(uFontHF) < 2 
          ASize(uFontHF, 2) 
       EndIf 
       If ValType(uFontHF[1]) != "N" .or. empty(uFontHF[1]) 
          uFontHF[1] := hFontHead 
       EndIf 
       If ValType(uFontHF[2]) != "N" .or. empty(uFontHF[2]) 
          uFontHF[2] := hFontFoot 
       EndIf 
    Else 
       uFontHF := { hFontHead, hFontFoot } 
    EndIf 
  
    hFontHead     := uFontHF[1] 
    hFontFoot     := uFontHF[2] 
  
    ::aArray      := aArray 
  
    ::lPickerMode := .F. 
  
    nColumns    := If( ! Empty( aHead ), Len( aHead ), If( ! Empty( ::aArray ), Len( ::aArray[ 1 ] ), 0 ) ) //V90 
    ::aDefValue := Array( Len( aArray[ 1 ] ) )      //V90 
  
    aDefMaxVal := Array(nColumns) 
    aDefType   := Array(nColumns) 
    aDefAlign  := Array(nColumns) 
    aDefMaxLen := Array(nColumns) 
  
    If Len(aPicture) != nColumns 
       ASize(aPicture, nColumns) 
    EndIf 
  
    If Len(aAlign) != nColumns 
       ASize(aAlign, nColumns) 
    EndIf 
  
    If Len(aName) != nColumns 
       ASize(aName, nColumns) 
    EndIf 
  
    For nI := 1 To nColumns 
       cType := ValType( ::aArray[ 1, nI ] ) 
       aDefType[ nI ] := cType 
  
       If cType $ "CM" 
          ::aDefValue[ nI ] := Space( Len( ::aArray[ 1, nI ] ) ) 
          aDefMaxVal [ nI ] := ::aArray[ 1, nI ] 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_LEFT 
       ElseIf cType == "N" 
          ::aDefValue[ nI ] := 0 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_RIGHT 
       ElseIf cType == "D" 
          ::aDefValue[ nI ] := CToD( "" ) 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_CENTER 
       ElseIf cType == "T" 
    #ifdef __XHARBOUR__ 
          ::aDefValue[ nI ] := CToT( "" ) 
    #else 
          ::aDefValue[ nI ] := HB_CTOT("") 
    #endif 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_LEFT 
       ElseIf cType == "L" 
          ::aDefValue[ nI ] := .F. 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_CENTER 
       Else                                // arrays, objects and codeblocks not allowed 
          ::aDefValue[ nI ] := "???"       // not user editable data type 
          aDefMaxVal [ nI ] := "???" 
          aDefMaxLen [ nI ] := 0 
          aDefAlign  [ nI ] := DT_LEFT 
       EndIf 
    Next 
  
    ::nAt       := 1 
    ::bKeyNo    := { |n| If( n == Nil, ::nAt, ::nAt := n ) }     //V90 
    ::cAlias    := "ARRAY"     // don't change name, used in method Default() 
    ::lIsArr    := .T. 
    ::lIsDbf    := .F.         //JP V90 
    ::nLen      := Eval( ::bLogicLen := { || Len( ::aArray ) + If( ::lAppendMode, 1, 0 ) } ) 
    ::lIsArr    := .T. 
    ::bGoTop    := { || ::nAt := 1 } 
    ::bGoBottom := { || ::nAt := Eval( ::bLogicLen ) } 
    ::bSkip     := { |nSkip, nOld| nOld := ::nAt, ::nAt += nSkip, ::nAt := Min( Max( ::nAt, 1 ), ::nLen ), ::nAt - nOld } //V90 
    ::bGoToPos  := { |n| Eval( ::bKeyNo, n ) }     //V90 
    ::bBof      := { || ::nAt < 1 }                //V90 
    ::bEof      := { || ::nAt > Len( ::aArray ) }  //V90 
  
    ::lHitTop    := .F. 
    ::lHitBottom := .F. 
    ::nRowPos    := 1 
    ::nColPos    := 1 
    ::nCell      := 1 
  
    ::HiliteCell( 1 ) 
  
    aDefFooter := Array(nColumns) 
    aFill(aDefFooter, "") 
     
    If     ValType(uFooter) == "L" 
       lFooter := uFooter  
    ElseIf ValType(uFooter) == "A" 
       lFooter := .T. 
       For nI := 1 To Min( nColumns, Len(uFooter) ) 
           aDefFooter[ nI ] := cValToChar(uFooter[ nI ]) 
       Next 
    EndIf 
  
    If Empty( aHead ) 
       aHead := AutoHeaders( Len( ::aArray[ 1 ] ) ) 
    EndIf 
  
    If aSizes != Nil .and. ValType( aSizes ) != "A" 
       aSizes := AFill( Array( Len( ::aArray[ 1 ] ) ), nValToNum( aSizes ) ) 
    ElseIf ValType( aSizes ) == "A" .and. ! Empty( aSizes  ) 
       If Len( aSizes ) < nColumns 
          nI := Len( aSizes ) + 1 
          ASize( aSizes, nColumns ) 
          AFill( aSizes, aSizes[ 1 ], nI ) 
       EndIf 
    Else 
       aSizes := Nil 
    EndIf 
  
    For nI := 1 To Len(::aArray) 
        For nN := 1 To nColumns 
            cData := cValToChar( ::aArray[ nI, nN ] ) 
            If len(cData) > len(aDefMaxVal[ nN ]) 
               aDefMaxVal[ nN ] := cData 
               aDefMaxLen[ nN ] := Max( aDefMaxLen[ nN ], Len(cData) ) 
            EndIf 
        Next 
    Next 
  
    ::aHeaders   := Array(nColumns) 
    ::aColSizes  := Array(nColumns) 
    ::aFormatPic := Array(nColumns) 
    ::aJustify   := Array(nColumns) 
  
    For nI := 1 To nColumns 
  
       bData     := ArrayWBlock( Self, nI ) 
       cHead     := cValToChar( aHead[ nI ] ) 
       nAlign    := aDefAlign[ nI ] 
       cPict     := Nil 
       lSelected := .F. 
  
       If     aDefType[ nI ] == "C" 
          lSelected := .T. 
          If ValType(aPicture[ nI ]) == "C" 
             cPict := aPicture[ nI ] 
             cTemp := If( left(cPict, 2) == "@K", subs(cPict, 4), cPict) 
          Else 
             cPict := repl("X", aDefMaxLen[ nI ]) 
             cTemp := cPict 
          EndIf 
          If Len(cTemp) > Len(::aDefValue[ nI ]) 
             ::aDefValue[ nI ] := Space( Len( cTemp ) ) 
          EndIf 
       ElseIf aDefType[ nI ] == "N" 
          lSelected := .T. 
          If ValType(aPicture[ nI ]) == "C" 
             cPict := aPicture[ nI ] 
          Else 
             cPict := repl("9", aDefMaxLen[ nI ]) 
             If ( nN := At(".", aDefMaxVal[ nI ]) ) > 0 
                cTemp := subs(aDefMaxVal[ nI ], nN) 
                cPict := left(cPict, Len(cPict) - Len(cTemp))+"."+repl("9", Len(cTemp)-1) 
             EndIf 
          EndIf 
       ElseIf aDefType[ nI ] == "D" 
          lSelected := .T. 
       EndIf 
  
       If ValType(aAlign[ nI ]) == "N" .and. ( aAlign[ nI ] == DT_LEFT   .or. ; 
                                               aAlign[ nI ] == DT_CENTER .or. ; 
                                               aAlign[ nI ] == DT_RIGHT ) 
          nAlign := aAlign[ nI ] 
       EndIf 
  
       If lFooter 
          aAligns := { nAlign, DT_CENTER, nAlign } 
          cFooter := aDefFooter[ nI ] 
          If CRLF $ cFooter 
             cTemp := "" 
             AEval(hb_aTokens(cFooter, CRLF), {|x| cTemp := If( Len(x) > Len(cTemp), x, cTemp )}) 
          Else 
             cTemp := cFooter 
          EndIf 
          nFooter := GetTextWidth( 0, cTemp, hFontFoot ) 
       Else 
          aAligns := { nAlign, DT_CENTER } 
          cFooter := Nil 
          nFooter := 0 
       EndIf 
  
       If CRLF $ cHead 
          cTemp := "" 
          AEval(hb_aTokens(cHead, CRLF), {|x| cTemp := If( Len(x) > Len(cTemp), x, cTemp )}) 
       Else 
          cTemp := cHead 
       EndIf 
  
       nMax := Max( GetTextWidth( 0, aDefMaxVal[ nI ]+'B', hFont ), GetTextWidth( 0, cTemp, hFontHead ) ) 
       nMax := Max( nMax, 60 ) 
       nMax := Max( nMax, nFooter ) 
  
       If ! Empty( aSizes ) 
          If     valtype(aSizes[ nI ]) == 'N' .and. aSizes[ nI ] > 0 
             nMax := aSizes[ nI ] 
          ElseIf valtype(aSizes[ nI ]) == 'C' 
             nMax := GetTextWidth( 0, aSizes[ nI ], hFont ) 
          EndIf 
       EndIf 
  
       ::aHeaders  [ nI ] := cHead 
       ::aColSizes [ nI ] := nMax 
       ::aFormatPic[ nI ] := cPict 
       ::aJustify  [ nI ] := aAligns 
  
       oCol := TSColumn():New( cHead, bData, cPict,, aAligns, nMax,, ::lEditable,,,,cFooter,,,,,,, ; 
                               Self, "ArrayWBlock(::oBrw," + LTrim( Str( nI ) ) + ")" ) 
       If lFont 
          oCol:hFontHead := hFontHead 
          If lFooter 
             oCol:hFontFoot := hFontFoot 
          EndIf 
       EndIf 
  
       If ! empty(aName[ nI ]) .and. ValType(aName[ nI ]) == "C" 
          oCol:cName := aName[ nI ] 
       EndIf 
  
       oCol:lOnGotFocusSelect := lSelected 
  
       ::AddColumn( oCol ) 
    Next 
  
    ::lNoPaint := .F. 
    ::ResetVScroll( .T. ) //V90 
 //V90 
    If ::lPainted 
       ::GoTop() 
       ::Refresh() 
    EndIf 
 //end 
  
 Return Self 
 

 
 Demo.prg 
 ~~~~~~~~ 
 #include "minigui.ch" 
 #include "common.ch" 
 #include "TSBrowse.ch" 
  
 //REQUEST HB_CODEPAGE_RU1251, HB_CODEPAGE_RU866, HB_LANG_RUWIN 
 //REQUEST HB_LANG_RUWIN 
 //REQUEST HB_LANG_RU866 
  
 //SET CODEPAGE TO RUSSIAN 
 //HB_LANGSELECT( "RU" ) 
  
 Proc MAIN 
 Local oBrw, aDatos, aArray, aHead, aSize, aFoot, aPict, aAlign, aName, aFontHF 
 Local hFontHead, hFontFoot 
 Local cFontName := _HMG_DefaultFontName 
 Local nFontSize := 10 
  
 Public aFont := {} 
  
  SET DECIMALS TO 4 
  SET DATE     TO GERMAN 
  SET EPOCH    TO 2000 
  SET CENTURY  ON 
  SET EXACT    ON 
  
  DEFINE FONT Font_1  FONTNAME cFontName SIZE nFontSize 
  DEFINE FONT Font_2  FONTNAME cFontName SIZE nFontSize BOLD 
  
  AADD( aFont, GetFontHandle( "Font_1" ) ) 
  AADD( aFont, GetFontHandle( "Font_2" ) ) 
  
  DEFINE WINDOW MAGAZIN   AT 0, 0  ; 
         TITLE  "TEST" ; 
         MAIN   NOMAXIMIZE NOSIZE  
  
     DEFINE STATUSBAR OF MAGAZIN  
         STATUSITEM "0"            // WIDTH 0  FONTCOLOR BLACK 
         STATUSITEM "1" WIDTH 230  // FONTCOLOR BLACK 
         STATUSITEM "2" WIDTH 230  // FONTCOLOR BLACK 
         STATUSITEM "3" WIDTH 230  // FONTCOLOR BLACK 
     END STATUSBAR 
  
     DEFINE TBROWSE oBrw AT 0, 0 ; 
            WIDTH MAGAZIN.WIDTH - 2 * GetBorderWidth() ; 
            HEIGHT MAGAZIN.HEIGHT - GetTitleHeight() - GetTitleHeight() - ; 
                   GetProperty( "MAGAZIN", "StatusBar", "Height" ) - ; 
                   2 * GetBorderHeight() ; 
            ENUMERATOR ; 
            FONT   cFontName   SIZE   nFontSize ; 
            GRID   EDIT 
  
       aDatos   := CreateDatos() 
  
       aArray   := aDatos[1] 
       aHead    := aDatos[2] 
       aSize    := aDatos[3] 
       aFoot    := aDatos[4] 
       aPict    := aDatos[5] 
       aAlign   := aDatos[6] 
       aName    := aDatos[7] 
  
 //    hFontHead := aFont[1]                  // normal Header 
 //    hFontFoot := aFont[2]                  //  bold  Footer 
 //    aFontHF   := { hFontHead, hFontFoot } 
  
 //    aFontHF   := aFont[1]                  // normal Header, Footer 
       aFontHF   := aFont[2]                  //  bold  Header, Footer 
                                                               
       oBrw := SetArray2("oBrw", "MAGAZIN", aArray, aFontHF, aHead, aSize, aFoot, aPict, aAlign, aName) 
 //    oBrw := SetArray2("oBrw", "MAGAZIN")    // Demo array 
  
       oBrw:nWheelLines   := 1 
       oBrw:nClrLine      := COLOR_GRID 
       oBrw:nHeightCell   += 2  
       oBrw:nHeightHead   += 4  
          If ! empty(aFoot) 
       oBrw:nHeightFoot   += 4  
          EndIf 
          If oBrw:lEnum 
       oBrw:nHeightSpecHd := oBrw:nHeightCell 
          EndIf 
           
     END TBROWSE 
      
  END WINDOW 
  
  DoMethod("MAGAZIN","Activate")	 
  
 return 
 ************************ 
  
 STATIC FUNCTION CreateDatos() 
 Local i, k := 1000, aDatos := {}, aHead, aSize, aFoot, aPict, aAlign, aName 
  
  aDatos := Array(k) 
  for i := 1 to k  
      aDatos[ i ] := {" ", ;                                       // 1 
                      i, ;                                         // 2 
                      ntoc(i) + "_123", ;                          // 3 
                      date()+i, ;                                  // 4 
                      PadR("Test line - " + ntoc(i), 20), ;        // 5 
                      round((10000-i) * i/3, 2), ;                 // 6 
                      100.00 * i, ;                                // 7 
                      0.12, ;                                      // 8 
                      round(100.00 * i * 0.12, 2), ;               // 9 
                      Round(1234567.00 / i, 3), ;                  // 10 
                      PadR("Line "+StrZero(i, 5), 20), ;           // 11 
                      date(), ;                                    // 12 
                      time(), ;                                    // 13 
                      i % 2 == 0  }                                // 14 
  next 
  
    aHead  := aClone(aDatos[1]) 
 //   AEval(aHead, {|x,n| aHead[ n ] := "Head_" + hb_ntos(n) }) 
      AEval(aHead, {|x,n| aHead[ n ] := "Head_" + hb_ntos(n) + ; 
            iif(n % 2 == 0, CRLF + "My_"+hb_ntos(n), "") }) 
  
    aFoot  := array(len(aDatos[1])) 
    AEval(aFoot, {|x,n| aFoot[ n ] := n }) 
 //   aFoot  := .T.                      // подножие есть с пустыми значениями 
     
    aPict     := array(len(aDatos[1]))   // можно не задавать, формируются 
    aPict[10] := "99999999999.999"       // автоматом для C,N по мах значению 
  
    aSize     := array(len(aDatos[1]))   // можно не задавать, формируются    
    aSize[10] := aPict[10]               // автоматом по мах значению в колонке 
                                          
    aAlign    := array(len(aDatos[1]))   // тип поля C   - DT_LEFT 
    aAlign[2] := DT_CENTER               //          D,L - DT_CENTER 
                                         //          N   - DT_RIGHT 
  
    aName     := array(len(aDatos[1])) 
    AEval(aName, {|x,n| aName[ n ] := "MyName_"+hb_ntos(n) }) 
  
 RETURN { aDatos, aHead, aSize, aFoot, aPict, aAlign, aName } 
 

 
 METHOD SetArray2( aArray, uFontHF, aHead, aSizes, uFooter, aPicture, aAlign, aName )   CLASS TSBrowse   
  
    Local nColumns, nI, cType, nMax, bData, cHead 
    Local nN, cData, aDefMaxVal, aDefMaxLen, aDefType, aDefAlign, aDefFooter, oCol, ; 
          nAlign, aAligns, lFooter := .F., cFooter, nFooter, cTemp, cPict, ; 
          hFont := If( ::hFont != Nil, ::hFont, 0 ), ; 
          lFont := hFont != 0, hFontHead := hFont, hFontFoot := hFont 
  
    If empty(aArray) .or. ValType(aArray) != "A" 
       nN := 1000 
       aArray := Array(nN) 
       For nI := 1 To nN 
           aArray[ nI ] := { nI, PadR("Line - "+StrZero(nI, 5), 20), ; 
                                 Date()+(nI-1), Round(nN / nI, 3), nI % 2 == 0 } 
       Next 
    EndIf 
  
    Default aHead     := AClone(::aHeaders), ;             
            aSizes    := AClone(::aColSizes), ;   
            aPicture  := AClone(::aFormatPic), ; 
            aAlign    := If( ISARRAY(::aJustify), AClone(::aJustify), {} ), ; 
            aName     := {} 
  
    If     ValType(uFontHF) == 'N' .and. uFontHF != 0 
       hFontHead := uFontHF 
       hFontFoot := uFontHF 
    ElseIf ValType(uFontHF) == 'A' .and. Len(uFontHF) >= 2 
       If ValType(uFontHF[1]) == 'N' .and. uFontHF[1] != 0 
          hFontHead := uFontHF[1] 
       EndIf 
       If ValType(uFontHF[2]) == 'N' .and. uFontHF[2] != 0 
          hFontFoot := uFontHF[2] 
       EndIf 
    EndIf 
  
    ::aArray      := aArray 
    ::lPickerMode := .F. 
  
    nColumns := If( ! Empty( aHead ), Len( aHead ), If( ! Empty( ::aArray ), Len( ::aArray[ 1 ] ), 0 ) ) //V90 
  
    ::aDefValue := Array( Len( aArray[ 1 ] ) )      //V90 
  
    aDefMaxVal  := Array(nColumns) 
    aDefType    := Array(nColumns) 
    aDefAlign   := Array(nColumns) 
    aDefMaxLen  := Array(nColumns) 
  
    aFill(aDefMaxLen, 0) 
  
    If Len(aPicture) != nColumns 
       ASize(aPicture, nColumns) 
    EndIf 
  
    If Len(aAlign) != nColumns 
       ASize(aAlign, nColumns) 
    EndIf 
  
    If Len(aName) != nColumns 
       ASize(aName, nColumns) 
    EndIf 
  
    For nI := 1 To nColumns 
       cType := ValType( ::aArray[ 1, nI ] ) 
       aDefType[ nI ] := cType 
  
       If cType $ "CM" 
          ::aDefValue[ nI ] := Space( Len( ::aArray[ 1, nI ] ) ) 
          aDefMaxVal [ nI ] := Trim( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_LEFT 
       ElseIf cType == "N" 
          ::aDefValue[ nI ] := 0 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_RIGHT 
       ElseIf cType == "D" 
          ::aDefValue[ nI ] := CToD( "" ) 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_CENTER 
       ElseIf cType == "T" 
    #ifdef __XHARBOUR__ 
          ::aDefValue[ nI ] := CToT( "" ) 
    #else 
          ::aDefValue[ nI ] := HB_CTOT("") 
    #endif 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_LEFT 
       ElseIf cType == "L" 
          ::aDefValue[ nI ] := .F. 
          aDefMaxVal [ nI ] := cValToChar( ::aArray[ 1, nI ] ) 
          aDefMaxLen [ nI ] := Len( aDefMaxVal [ nI ] ) 
          aDefAlign  [ nI ] := DT_CENTER 
       Else                                // arrays, objects and codeblocks not allowed 
          ::aDefValue[ nI ] := "???"       // not user editable data type 
          aDefMaxVal [ nI ] := "???" 
          aDefMaxLen [ nI ] := 0 
          aDefAlign  [ nI ] := DT_LEFT 
       EndIf 
    Next 
  
    ::nAt       := 1 
    ::bKeyNo    := { |n| If( n == Nil, ::nAt, ::nAt := n ) }     //V90 
    ::cAlias    := "ARRAY"     // don't change name, used in method Default() 
    ::lIsArr    := .T. 
    ::lIsDbf    := .F.         //JP V90 
    ::nLen      := Eval( ::bLogicLen := { || Len( ::aArray ) + If( ::lAppendMode, 1, 0 ) } ) 
    ::lIsArr    := .T. 
    ::bGoTop    := { || ::nAt := 1 } 
    ::bGoBottom := { || ::nAt := Eval( ::bLogicLen ) } 
    ::bSkip     := { |nSkip, nOld| nOld := ::nAt, ::nAt += nSkip, ::nAt := Min( Max( ::nAt, 1 ), ::nLen ), ::nAt - nOld } //V90 
    ::bGoToPos  := { |n| Eval( ::bKeyNo, n ) }     //V90 
    ::bBof      := { || ::nAt < 1 }                //V90 
    ::bEof      := { || ::nAt > Len( ::aArray ) }  //V90 
  
    ::lHitTop    := .F. 
    ::lHitBottom := .F. 
    ::nRowPos    := 1 
    ::nColPos    := 1 
    ::nCell      := 1 
  
    ::HiliteCell( 1 ) 
  
    aDefFooter := Array(nColumns) 
    aFill(aDefFooter, "") 
     
    If     ValType(uFooter) == "L" 
       lFooter := uFooter  
    ElseIf ValType(uFooter) == "A" 
       lFooter := .T. 
       For nI := 1 To Min( nColumns, Len(uFooter) ) 
           aDefFooter[ nI ] := cValToChar(uFooter[ nI ]) 
       Next 
    EndIf 
  
    If Empty( aHead ) 
       aHead := AutoHeaders( Len( ::aArray[ 1 ] ) ) 
    EndIf 
  
    If aSizes != Nil .and. ValType( aSizes ) != "A" 
       aSizes := AFill( Array( Len( ::aArray[ 1 ] ) ), nValToNum( aSizes ) ) 
    ElseIf ValType( aSizes ) == "A" .and. ! Empty( aSizes  ) 
       If Len( aSizes ) < nColumns 
          nI := Len( aSizes ) + 1 
          ASize( aSizes, nColumns ) 
          AFill( aSizes, aSizes[ 1 ], nI ) 
       EndIf 
    Else 
       aSizes := Nil 
    EndIf 
  
    For nI := 1 To Len(::aArray) 
        For nN := 1 To nColumns 
            cData := cValToChar( ::aArray[ nI, nN ] ) 
            If len(cData) > len(aDefMaxVal[ nN ]) 
               If aDefType[ nN ] == "C" 
                  aDefMaxVal[ nN ] := Trim(cData) 
                  aDefMaxLen[ nN ] := Max( aDefMaxLen[ nN ], Len(aDefMaxVal[ nN ]) ) 
               Else 
                  aDefMaxVal[ nN ] := cData 
                  aDefMaxLen[ nN ] := Max( aDefMaxLen[ nN ], Len(cData) ) 
               EndIf 
            EndIf 
        Next 
    Next 
  
    ::aHeaders   := Array(nColumns) 
    ::aColSizes  := Array(nColumns) 
    ::aFormatPic := Array(nColumns) 
    ::aJustify   := Array(nColumns) 
  
    For nI := 1 To nColumns 
  
       bData  := ArrayWBlock( Self, nI ) 
       cHead  := cValToChar( aHead[ nI ] ) 
       nAlign := aDefAlign[ nI ] 
       cPict  := Nil 
  
       If     aDefType[ nI ] == "C" 
          If ValType(aPicture[ nI ]) == "C" .and. Len(aPicture[ nI ]) > 0 
             cTemp := If( left(aPicture[ nI ], 2) == "@K", subs(aPicture[ nI ], 4), aPicture[ nI ]) 
          Else 
             cTemp := repl("X", aDefMaxLen[ nI ]) 
          EndIf 
          If Len(cTemp) > Len(::aDefValue[ nI ]) 
             ::aDefValue[ nI ] := Space( Len( cTemp ) ) 
          EndIf 
          cPict := repl("X", Len(::aDefValue[ nI ])) 
       ElseIf aDefType[ nI ] == "N" 
          If ValType(aPicture[ nI ]) == "C" 
             cPict := aPicture[ nI ] 
          Else 
             cPict := repl("9", aDefMaxLen[ nI ]) 
             If ( nN := At(".", aDefMaxVal[ nI ]) ) > 0 
                cTemp := subs(aDefMaxVal[ nI ], nN) 
                cPict := left(cPict, Len(cPict) - Len(cTemp))+"."+repl("9", Len(cTemp)-1) 
             EndIf 
          EndIf 
       EndIf 
  
       If ValType(aAlign[ nI ]) == "N" .and. ( aAlign[ nI ] == DT_LEFT   .or. ; 
                                               aAlign[ nI ] == DT_CENTER .or. ; 
                                               aAlign[ nI ] == DT_RIGHT ) 
          nAlign := aAlign[ nI ] 
       EndIf 
  
       If lFooter 
          aAligns := { nAlign, DT_CENTER, nAlign } 
          cFooter := aDefFooter[ nI ] 
          If CRLF $ cFooter 
             cTemp := "" 
             AEval(hb_aTokens(cFooter, CRLF), {|x| cTemp := If( Len(x) > Len(cTemp), x, cTemp )}) 
          Else 
             cTemp := cFooter 
          EndIf 
          nFooter := GetTextWidth( 0, cTemp, hFontFoot ) 
       Else 
          aAligns := { nAlign, DT_CENTER } 
          cFooter := Nil 
          nFooter := 0 
       EndIf 
  
       If CRLF $ cHead 
          cTemp := "" 
          AEval(hb_aTokens(cHead, CRLF), {|x| cTemp := If( Len(x) > Len(cTemp), x, cTemp )}) 
       Else 
          cTemp := cHead 
       EndIf 
  
       nMax := Max( GetTextWidth( 0, aDefMaxVal[ nI ]+'W', hFont ), GetTextWidth( 0, cTemp, hFontHead ) ) 
       nMax := Max( nMax, 32 ) 
       nMax := Max( nMax, nFooter ) 
  
       If ! Empty( aSizes ) 
          If     valtype(aSizes[ nI ]) == 'N' .and. aSizes[ nI ] > 0 
             nMax := aSizes[ nI ] 
          ElseIf valtype(aSizes[ nI ]) == 'C' 
             nMax := GetTextWidth( 0, aSizes[ nI ], hFont ) 
          EndIf 
       EndIf 
  
       ::aHeaders  [ nI ] := cHead 
       ::aColSizes [ nI ] := nMax 
       ::aFormatPic[ nI ] := cPict 
       ::aJustify  [ nI ] := aAligns 
  
       oCol := TSColumn():New( cHead, bData, cPict,, aAligns, nMax,, ::lEditable,,,,cFooter,,,,,,, ; 
                               Self, "ArrayWBlock(::oBrw," + LTrim( Str( nI ) ) + ")" ) 
       If lFont 
          oCol:hFontHead := hFontHead 
          If lFooter 
             oCol:hFontFoot := hFontFoot 
          EndIf 
       EndIf 
  
       If aDefType[ nI ] == "L" 
          oCol:lCheckBox := .T. 
       EndIf 
  
       If ! empty(aName[ nI ]) .and. ValType(aName[ nI ]) == "C" 
          oCol:cName := aName[ nI ] 
       EndIf 
  
       ::AddColumn( oCol ) 
    Next 
  
    ::lNoPaint := .F. 
    ::ResetVScroll( .T. ) //V90 
 //V90 
    If ::lPainted 
       ::GoTop() 
       ::Refresh() 
    EndIf 
 //end 
 Return Self