FUNCTION MAIN( Base )                                 // MAIN function 
 ... 
    DEFINE  WINDOW         wMain                       ; 
       AT                  0, 0                        ; 
       WIDTH               nWidth                      ; 
       HEIGHT              nHeight                     ; 
       MINWIDTH            nWdth                       ; 
       MINHEIGHT           nHeig                       ; 
       MAXWIDTH            nWdth                       ; 
       MAXHEIGHT           nHeig                       ; 
       TITLE               oApp:Title + ". "           ; 
       ICON                oApp:Icon                   ; 
       MAIN                MDI      TOPMOST            ; 
       ON INIT             wMainInit()                 ; 
       ON RELEASE          wMainClose()                ;  
       ON INTERACTIVECLOSE wMainIsClose()              ;  
       BACKCOLOR           oApp:BColor 
  
  
       PUBL oMain := ThisWindow.Object 
  
       WITH OBJECT ThisWindow.Object                                           // ---- Window events 
        :Event( 101, {|ow,ky| Artikul_Child (ow, ky)  } ) 
        :Event( 102, {|ow,ky| ow:Release() } ) 
       END WITH                                                                // ---- Window events 
 ... 
 * ----------------------------------------------------------------------------------- * 
 STATIC FUNC wMainInit()    
 * ----------------------------------------------------------------------------------- * 
  
    This.Topmost := .F. 
     
    (ThisWindow.Object):PostMsg(101) 
  
    RETURN NIL 
  
 * ------------------------------------------------------------------------------------ * 
 FUNC Artikul_Child( oWn, nKy ) 
 * ------------------------------------------------------------------------------------ * 
 ... 
    DEFINE WINDOW &cWnd                                                          ; 
       TITLE            ' '+cCapt+' '                                            ; 
       MDICHILD         FOCUSED   NOMINIMIZE                                     ; 
       ON RELEASE     ( iif( select(cAls) > 0, (cAls)->( dbCloseArea() ), Nil ) )  
  
       cThisForm := cWnd 
       oThisForm := Thiswindow.Object 
        
       DEFINE SPLITBOX HANDLE hSpl 
       DEFINE TOOLBAR  ToolBar_1 BUTTONSIZE 24,24 FLAT 
           BUTTON BEDIT PICTURE   'Edit'      ACTION (ThisWindow.Object):PostMsg(4)             ; 
                        TOOLTIP   ' ' + gTxt(RedLine) + '. ' + gTxt(Art) +'.' + space(8) + 'F4' ; 
                        SEPARATOR 
           BUTTON BENTR PICTURE   'Vibor'     ACTION (ThisWindow.Object):PostMsg(5)         ; 
                        TOOLTIP   ' ' + gTxt(Nam) + '  =>  ' + gTxt(Art) + space(8) + 'F5'  ; 
                        SEPARATOR 
           BUTTON BEMP1 PICTURE   'br_empty'  ACTION NIL ;                            
                        SEPARATOR 
           BUTTON BKODS PICTURE   'p_ind'     ACTION (ThisWindow.Object):PostMsg(6) ; 
                        TOOLTIP   ' ' + gTxt(Sort ) + space(8) + 'F6'               ; 
                        SEPARATOR 
           BUTTON BFIND PICTURE   'p_find'    ACTION (ThisWindow.Object):PostMsg(7) ; 
                        TOOLTIP   ' ' + gTxt(Find ) + space(8) + 'F7'               ; 
                        SEPARATOR 
           BUTTON BEMP2 PICTURE   'br_empty'  ACTION NIL ;                            
                        SEPARATOR 
           BUTTON BSERV PICTURE   'srv_to'    ACTION (ThisWindow.Object):PostMsg(9) ; 
                        TOOLTIP   ' ' + gTxt(ToServ) + space(8) + 'F9'              ; 
                        SEPARATOR 
       END TOOLBAR 
       DEFINE TOOLBAR ToolBar_2 BUTTONSIZE 24,24 FLAT 
           BUTTON BEXIT PICTURE   'exit'      ACTION (ThisWindow.Object):PostMsg(10) ; 
                        TOOLTIP   ' ' + gTxt(Exit) 
       END TOOLBAR 
       END SPLITBOX 
  
       nW := ThisWindow.ClientWidth 
       nY := GetWindowHeight(hSpl) 
       nX := 0 
       nH := ThisWindow.ClientHeight - nY 
  
       DEFINE TBRW &cBrw TO oTbr AT nY,nX WIDTH nW HEIGHT nH ALIAS cAls  CELL 
    
         :aColSel   := aColumn 
         :hFontHead := aFont[ 1 ] 
         :hFontFoot := aFont[ 2 ] 
    
         :LoadFields(.T.)  
  
         :nWheelLines  := 1  
         :nClrLine     := COLOR_GRID  
         :nHeightCell  += nDcell 
         :nHeightHead  += nDcell 
         :nHeightFoot  := :nHeightCell 
         :lNoGrayBar   := .F.  
         :lDrawFooters := .T.  
         :lFooting     := .T.  
         :lNoVScroll   := .F.  
         :lNoHScroll   := .T.  
         :nFireKey     := VK_F4        // default Edit  
         :nLineStyle   := LINES_ALL    // LINES_NONE LINES_ALL LINES_VERT LINES_HORZ LINES_3D LINES_DOTTED 
       
         :SetColor( { CLR_FOCUSB }, { { |a,b,c| If( c:nCell == b, {Rgb( 66, 255, 236), Rgb(209, 227, 248)}, ;   
                                                                  {Rgb(220, 220, 220), Rgb(220, 220, 220)} ) } } )             
    
         For nI := 1 To nK 
             oCol                   := :aColumns        [ nI ] 
             oCol:cName             := aName            [ nI ] 
             oCol:cField            := aColumn          [ nI ] 
             oCol:cHeading          := aHeader          [ nI ] 
             oCol:nWidth            := aWidth           [ nI ] 
             oCol:lEdit             := aEdit            [ nI ] 
             oCol:nAlign            := aAlign           [ nI ]  
             oCol:nFAlign           := aFAlign          [ nI ] 
             oCol:lFixLite          := aFixLite         [ nI ] 
             oCol:lOnGotFocusSelect := aOnGotFocusSelect[ nI ] 
             oCol:lEmptyValToChar   := aEmptyValToChar  [ nI ] 
             oCol:nEditMove         := aEditMove        [ nI ] 
                If ! empty(aPicture  [ nI ]) 
             oCol:cPicture          := aPicture         [ nI ] 
                EndIf 
                If ! empty(aOrder[ nI ]) 
             oCol:cOrder            := aOrder           [ nI ] 
                EndIf 
                If     oCol:cName == "NMP" 
             oCol:cFooting := { |nc,obr| nc := (obr:cAlias)->( OrdKeyNo() ), ; 
                                         iif( empty(nc), '', hb_ntos(nc) ) }  
                ElseIf oCol:cName == "EAN" 
             oCol:cFooting := { |nc,obr| nc := (obr:cAlias)->( OrdKeyCount() ), ; 
                                         ' '+iif( empty(nc), '', hb_ntos(nc) ) }  
                EndIf 
                If ! empty(aBlockData[ nI ]) 
                   If HB_ISCHAR(aBlockData[ nI ]) 
             oCol:bData             := AliasBlock(aBlockData[ nI ], cAls, .T.) 
                   Else 
             oCol:bData             :=            aBlockData[ nI ] 
                   EndIf 
                EndIf 
                If ! empty(aFields   [ nI ]) 
             oCol:cField            := aFields          [ nI ] 
                EndIf 
         Next 
    
         :nFreeze      := :nColumn('EAN') 
         :lLockFreeze  := .T.  
         :nCell        := :nColumn('NAM')  
         :aSortBmp     := { LoadImage("br_up"), LoadImage("br_dn") }  
         :bChange      := {|obr| obr:DrawFooters() }  
         :bLDblClick   := {|p1,p2,p3,obr| p1:=p2:=p3:=Nil, Do_Obj(obr:hWndParent):PostMsg(4) } 
    
         :SetIndexCols( :nColumn('KOD'), :nColumn('NAM') )  
         :SetOrder( :nColumn('NAM') )  
    
         if :nLen > :nRowCount()  
            :ResetVScroll( .T. )  
            :oHScroll:SetRange(0,0)  
         EndIf  
    
         :UserKeys(VK_F5    , {|obr,nky,cky| cky := (obr:cAlias)->( mGet('R_3') ), ; 
                                                    (obr:cAlias)->( mPut('R_34', cky) ), ; 
                                                     obr:DrawSelect() }) 
         :UserKeys(VK_F6    , {|obr,nky,cky| Order_Set (obr,nky,cky)  }) 
         :UserKeys(VK_F7    , {|obr        | Press_Key (obr        )  }) 
         :UserKeys(VK_F9    , {|obr        | Modify_Srv(obr        )  }) 
         :UserKeys(VK_RETURN, {|obr        | Do_Obj(obr:hWndParent):PostMsg(4) }) 
         :UserKeys(         , {|obr,nky,cky| Press_Key(obr,nky,cky)}) 
          
         :GoPos(1, :nFreeze + 1) 
    
       END TBRW 
  
       oTbr:SetNoHoles()  
       oTbr:SetFocus()  
  
       cPic := StrTran( oTbr:GetColumn('KOD'):cPicture, '@K ', '' ) 
       oCel := oTbr:GetCellInfo( 1, oTbr:nColumn('KOD') ) 
       nY   := This.ClientHeight - oTbr:nHeightFoot 
       nX   := 2 
       nW   := oCel:nWidth - 5 
       nH   := oTbr:nHeightCell 
    
       @ nY, nX GETBOX KOD OBJ oGet HEIGHT nH WIDTH nW VALUE space(len(cPic)) ; 
                BACKCOLOR      oApp:BColorGet PICTURE cPic ; 
                ON CHANGE      Seek__Set(oTbr) ; 
                INVISIBLE      NOTABSTOP 
    
       oGet:lOnGotFocusSelect := .F. 
       oGet:OnEscape          := {|og| og:GetObj():Hide(), oTbr:SetFocus(), .T. } 
       oGet:OnEnter           := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
       oGet:OnDown            := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
       oGet:OnUp              := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
    
       cPic := StrTran( oTbr:GetColumn('NAM'):cPicture, '@K ', '' ) 
       oCel := oTbr:GetCellInfo( 1, oTbr:nColumn('NAM') ) 
       nX   := oCel:nCol + 2 
       nW   := oCel:nWidth - 10 
    
       @ nY, nX GETBOX NAM OBJ oGet HEIGHT nH WIDTH nW VALUE space(len(cPic)) ; 
                BACKCOLOR      oApp:BColorGet PICTURE cPic ; 
                ON CHANGE      Seek__Set(oTbr) ; 
                INVISIBLE      NOTABSTOP 
    
       oGet:lOnGotFocusSelect := .F. 
       oGet:OnEscape          := {|og| og:GetObj():Hide(), oTbr:SetFocus(), .T. } 
       oGet:OnEnter           := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
       oGet:OnDown            := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
       oGet:OnUp              := {|og| og:GetObj():Hide(), oTbr:SetFocus()      } 
  
       WITH OBJECT This.Object                                                 // ---- Window events 
          :Event( 4, {|| oTbr:PostMsg( WM_KEYDOWN, VK_F4, 0 ) } ) 
          :Event( 5, {|| oTbr:PostMsg( WM_KEYDOWN, VK_F5, 0 ) } ) 
          :Event( 6, {|| oTbr:PostMsg( WM_KEYDOWN, VK_F6, 0 ) } ) 
          :Event( 7, {|| oTbr:PostMsg( WM_KEYDOWN, VK_F7, 0 ) } ) 
          :Event( 9, {|| oTbr:PostMsg( WM_KEYDOWN, VK_F9, 0 ) } ) 
          :Event(10, {|ow| ow:Release(), oMain:PostMsg(102)   } ) 
       END WITH                                                                // ---- Window events 
  
    END WINDOW 
  
    RETURN Nil 
 ... 
 * ------------------------------------------------------------------------------------ * 
 STATIC FUNC Modify_Srv( oBrw ) 
 * ------------------------------------------------------------------------------------ * 
    LOCAL i, n 
    LOCAL oWnd := Do_Obj(oBrw:hWndParent) 
    LOCAL cWnd := oBrw:cParentWnd 
    LOCAL cBrw := oBrw:cControlName 
  
    If oWnd:Action 
       oBrw:Enabled(.F.) 
       oWnd:Action := .F. 
       DoEvents() 
     
       oMain:StatusBar:Say(gTxt(Wait)) 
        
       For i := 1 To 20 
           oMain:StatusBar:Say(hb_ntos(i), 2) 
           For n := 1 To 10 
           wApi_Sleep(100) 
           DoEvents() 
           Next 
       Next 
     
       oMain:StatusBar:Say('', 2) 
       oMain:StatusBar:Say('') 
        
       oBrw:Enabled(.T.) 
       oWnd:Action := .T. 
       DoEvents() 
    EndIf 
    oBrw:SetFocus() 
     
    RETURN Nil 
 ...