FUNCTION Do_WaitWindow( bBlk, nMax, nStep, cCapt )  
  LOCAL nY   := GetBorderHeight() 
  LOCAL nX   := GetBorderWidth() 
  LOCAL nH   := 60, nTime := 1000 //, lClose := .F. 
  LOCAL hWnd, aHmg, lBlk := HB_ISBLOCK(bBlk) 
  LOCAL y := 0, x := 0, w := 320, h := nH 
  
  PRIV  lClose := .F. 
  
  DEFAULT bBlk  := {|| Nil }, ; 
          nStep := 10,        ; 
          nMax  := 250,       ; 
          cCapt := gTxt(Wait) 
  
  hWnd := iif( _HMG_BeginWindowMDIActive, GetActiveMdiHandle(), GetActiveWindow() ) 
  aHmg := Save_Rest_HMG(hWnd) 
  
  DEFINE WINDOW wWait                                        ;  
     AT         y, x                                         ;  
     WIDTH      w + nX * 2                                   ;  
     HEIGHT     h + nY * 2 + GetTitleHeight()                ;  
     TITLE      cCapt                                        ; 
     MODAL      NOSIZE       NOSYSMENU                       ; 
     ON INIT    ( SetWaitCursor( App.Handle ),               ; 
                  SetWaitCursor( This.ProgressBar.Handle ),  ; 
                  CursorWait(), oWin:PostMsg(1),             ; 
                  This.tWait.Enabled := .T., DoEvents(),     ; 
                  Eval(bBlk, oWin),                          ; 
                  oWin:PostMsg(2), DoEvents() )              ; 
     ON RELEASE ( This.tWait.Enabled := .F.,                 ; 
                  This.ProgressBar.Value := oWin:Cargo[3],   ; 
                  InkeyGui(500),                             ; 
                  SetArrowCursor( This.ProgressBar.Handle ), ; 
                  SetArrowCursor( App.Handle ),              ; 
                  CursorArrow(), InkeyGui(100),              ; 
                  Save_Rest_HMG(aHmg) )                      ; 
     ON INTERACTIVECLOSE lClose 
  
     PRIV  oWin := ThisWindow.Object 
  
     oWin:Cargo := { nStep, 0, nMax } 
  
     oWin:Event( 1, {|ow,nk| nk := ow:Cargo[2] + ow:Cargo[1],        ; 
                      ow:Cargo[2] := iif( nk > ow:Cargo[3], 0, nk ), ; 
                      wWait.ProgressBar.Value := ow:Cargo[2],        ; 
                      iif( ow:Cargo[2] == 0, ow:PostMsg(1), ),       ; 
                      wWait.tWait.Enabled := .T., DoEvents() } ) 
     oWin:Event( 2, {|| lClose := .T., wWait.Release } ) 
     oWin:Event( 3, {|| wWait.tWait.Enabled := .F., DoEvents() } ) 
     oWin:Event( 4, {|| wWait.tWait.Enabled := .T., DoEvents() } ) 
  
  
     @ y, x PROGRESSBAR ProgressBar RANGE 0, nMax                 ; 
                                    WIDTH  ThisWindow.ClientWidth ; 
                                    HEIGHT ThisWindow.ClientHeight 
  
     DEFINE TIMER tWait INTERVAL nTime ACTION ( wWait.tWait.Enabled := .F., oWin:PostMsg(1) ) 
  
     This.tWait.Enabled := .F. 
  
     y := App.Row + int((App.Height - h) / 2) 
     x := App.Col + int((App.Width  - w) / 2) 
     h += nY 
      
     MoveWindow( oWin:Handle, x, y, w, h ) 
  
  END WINDOW 
  
  ACTIVATE WINDOW wWait 
  
  Save_Rest_HMG(aHmg) 
  
 RETURN NIL