/* 
  * Harbour MiniGUI Demo 
 */ 
  
 #include "minigui.ch" 
  
 FUNCTION Main 
  
    LOCAL cTitle := 'WAIT WINDOW DEMO' 
    LOCAL cFont  := "Arial", nSize := 16 
    LOCAL cMsg   := "... WAIT FOR COMPLETION ...;"+App.ExeName+";" 
  
    SET FONT TO cFont, nSize-2 
  
    _DefineFont("DlgFont" , cFont , nSize   , .F., .F. )    
  
    SET WAITWINDOW PROMPT TO &cMsg  ; 
                   FONT "DlgFont"   ; 
                   FONTCOLOR YELLOW ; 
                   BACKCOLOR RED 
  
    DEFINE WINDOW Win_1 ; 
       AT 0,0 ; 
       WIDTH 400 ; 
       HEIGHT 400 ; 
       TITLE cTitle ; 
       MAIN 
  
       @ 015,70 BUTTON Button_0 ; 
                          CAPTION 'WAIT WINDOW "Press any key..."' ; 
                          ACTION Test() WIDTH 250 
  
       @ 050,70 BUTTON Button_1 ; 
                          CAPTION 'WAIT WINDOW "Processing..." NOWAIT' ; 
                          ACTION Test1() WIDTH 250 
  
       @  95,70 BUTTON Button_2 ; 
                          CAPTION 'WAIT CLEAR' ; 
                          ACTION Test2( cTitle ) WIDTH 250 
  
       @ 145,70 BUTTON Button_3 CAPTION 'WAIT NEW' WIDTH 250 ; 
                          ACTION {|| 
                                  WaitWindow(.T.) 
                                  wApi_Sleep(3000) 
                                  WaitWindow() 
                                  Return Nil 
                                  } 
  
       @ 175,70 BUTTON Button_4 CAPTION 'MODAL NEW' WIDTH 250 ; 
                          ACTION Test4() 
  
       @ 205,70 BUTTON Button_5 CAPTION 'WAIT OLD' WIDTH 250 ; 
                          ACTION {|| 
                                  WaitWindow("... WAIT FOR COMPLETION ...;", .T.) 
                                  wApi_Sleep(3000) 
                                  WaitWindow() 
                                  Return Nil 
                                  } 
  
       @ 225,70 BUTTON Button_6 CAPTION 'WAIT OLD 2' WIDTH 250 ; 
                          ACTION {|| 
   WaitWindow ( {"... WAIT FOR COMPLETION 2 ...", App.ExeName }, .T.,600,16, "DlgFont", YELLOW, BLUE ) 
                                  wApi_Sleep(3000) 
                                  WaitWindow() 
                                  Return Nil 
                                  } 
  
    END WINDOW 
  
    CENTER WINDOW Win_1  
  
    ACTIVATE WINDOW Win_1 
  
 RETURN Nil 
  
 PROCEDURE Test4() 
     LOCAL b := {|| 
                 wApi_Sleep(3000) 
                 ThisWindow.Release 
                 Return Nil 
                 } 
  
    WaitWindow(.T., b) 
  
 RETURN 
  
 PROCEDURE Test() 
  
    WAIT WINDOW "Press any key to continue..." 
  
 RETURN 
  
  
 PROCEDURE Test1() 
  
    WAIT WINDOW "Please press the 'WAIT CLEAR' button for closing of this intermediate window..." NOWAIT 
  
    Win_1.Title := "Processing..." 
  
    Win_1.Setfocus() 
  
 RETURN 
  
  
 PROCEDURE Test2( cTitle ) 
  
    WAIT CLEAR 
  
    Win_1.Title := cTitle 
  
 RETURN