////////////////////////////////////////////////////////////////////////////////// 
 FUNCTION myDebugVar(oWnd,ky,xv)  // variable output 
    LOCAL cLog, cObj, cMsg, o, a, ob, nI, nJ, a2Dim, aName, aData, nPost := ky 
    LOCAL aTmp, cTmp, xTmp, lTmp 
  
    cObj := UPPER(xv) 
    IF cObj == "BUTTON_1" 
       cLog := GetStartUpFolder() + "\_msg.App-Cargo.log" 
       DELETEFILE(cLog) 
       _SetGetLogFile( cLog )  // new log file output name 
  
       cMsg := "  App.Cargo:" 
       ? ProcNL(), "oWnd:Name =", oWnd:Name, oWnd,ky,xv 
       ? " Объект App.Cargo доступен всегда в любом месте программы" 
       ? " The App.Cargo object is always available anywhere in the program" 
       o := App.Cargo 
  
    ELSE 
       cLog := GetStartUpFolder() + "\_msg.oWnd-Cargo.log" 
       DELETEFILE(cLog) 
       _SetGetLogFile( cLog )  // new log file output name 
  
       cMsg := "  oWnd:Cargo:" 
       ? ProcNL(), "oWnd:Name =", oWnd:Name, oWnd,ky,xv 
       ? " Объект окна доступен через переменную oWnd в функции или через App.Cargo:oWindow" 
       ? " В данном случае App.Cargo:oWindow это главное окно этой программы" 
       ? " The window object is available through the oWnd variable in the function or through App.Cargo:oWindow" 
       ? " In this case, App.Cargo:oWindow is the main window of this program" 
       o := oWnd:Cargo           // we take data from the button that we put earlier 
  
    ENDIF 
  
    ? Repl("-",LINE_FILL) 
    a2Dim  := o:GetAll() // get an array with a key 
    /*FOR nI := 1 TO Len(a2Dim)    // this is a list of ALL keys and their values 
         ? cMsg, nI, "Key =", a2Dim[nI][1], "Val =" 
       IF VALTYPE(a2Dim[nI][2]) == "A" 
          ?? HB_ValToExp(a2Dim[nI][2]) 
       ELSEIF VALTYPE(a2Dim[nI][2]) == "C" 
          ?? AtRepl( CRLF, a2Dim[nI][2], " | " ) 
       ELSE 
          ?? a2Dim[nI][2] 
       ENDIF 
    NEXT */ 
    FOR EACH a IN a2Dim 
       nI := hb_EnumIndex( a ) 
       ? cMsg, nI, "Key =", a[1], "Val =" 
       IF hb_IsArray(a[2]) 
          IF Len(a[2]) > 0 .and. hb_IsArray(a[2][1]) 
             ?? a[2] , " = {" 
             FOR nJ := 1 TO LEN(a[2]) 
                 ?? HB_ValToExp(a[2][nJ]) + IIF( nJ==LEN(a[2]), "", "," ) 
             NEXT 
             ?? "}" 
          ELSE 
             ?? HB_ValToExp(a[2]) 
          ENDIF 
       ELSEIF hb_IsChar(a[2]) 
          ?? AtRepl( CRLF, a[2], " | " ) 
       ELSEIF hb_IsObject(a[2]) 
          ob := a[2] 
          ?? ob 
          ?? ob:ClassName 
          IF ob:ClassName $ "THMGDATA,TKEYDATA,TTHRDATA"                // контейнеры 
             ?? ob:GetAll() ; ?v ob:GetAll() ; ? 
          ELSEIF ob:ClassName == "TSBROWSE" 
             ?? ob:cParentWnd, ob:cControlName, ob:cAlias, ob:nLen 
             aName := __objGetMethodList( ob ) 
             //? HB_ValToExp(aName) 
          ELSEIF ob:ClassName $ "TCNLDATA,TGETDATA,TSTBDATA,TTSBDATA"  // контролы 
             ?? ob:Name, ob:Type, ob:Index, ob:Handle 
          ELSEIF ob:ClassName $ "TINIDATA"                             //  ini file 
             // см. примеры там вывод секций и их переменных 
             ?? ob:cIni, ob:lIni, ob:lUtf8 
          ELSEIF ob:ClassName $ "TWNDDATA"                             //  окно формы 
             ?? ob:Name 
             ?? ob:GETLISTTYPE() , HB_ValToExp( ob:GETLISTTYPE() ) 
             ?? ob:CLIENTWIDTH, ob:CLIENTHEIGHT 
             ? space(5) + "VARIABLE:" 
             aName := __objGetMsgList( ob, .T., 2 ) 
             aTmp := {} 
             FOR nJ := 1 TO LEN(aName) 
                 ? SPACE(5) + ob:Name + ":" + a[1], Hb_NtoS(nJ), aName[nJ] 
                 lTmp := .F. 
                 cTmp := aName[nJ] 
                 xTmp := "protected" 
                 BEGIN SEQUENCE WITH {|e| break( e ) } 
                    xTmp := __objSendMsg( ob, cTmp ) 
                    lTmp := .T. 
                 END SEQUENCE 
                 IF lTmp  // доступ есть 
                    AAdd(aTmp, {cTmp, xTmp}) 
                 ENDIF 
                 ?? "=", xTmp 
             NEXT 
             ? 
             ? space(5) + "METHOD:" 
             aName := __objGetMsgList( ob, .F. ) 
             FOR nJ := 1 TO LEN(aName) 
                 ? SPACE(5) + ob:Name + ":" + a[1], Hb_NtoS(nJ), aName[nJ] 
             NEXT 
             //? 
             //? space(5) + "!!! aVariable =", hb_valtoexp(aTmp) 
             ? 
             ? space(5) + "*** aVariable : {" 
             FOR nI := 1 TO LEN(aTmp) 
                 ? "  >", nI, aTmp[nI][1]+" =", HB_ValToExp(aTmp[nI][2]) 
             NEXT 
             ? " }" 
             ? 
          ELSE 
             //  TWNDDATA 'O' - окно формы 
             // здесь только ф-ями про объекты из "Harbour для начинающих" на сайте А.Кресина 
             aName := __objGetMethodList( ob ) 
             //aData := __objGetValueList( ob, [aExcept] ) 
             //aData := __objGetValueList( ob ) 
             ? HB_ValToExp(aName) 
             ? HB_ValToExp(aData) 
             ? ob:CLIENTWIDTH, ob:CLIENTHEIGHT 
             ? ob:GETLISTTYPE() ; ?v ob:GETLISTTYPE() 
          ENDIF 
       ELSE 
          ?? a[2] 
       ENDIF 
    NEXT 
    ? "..." 
  
    cMsg := HB_MemoRead(cLog) 
    AlertInfo(cMsg, "log file - " + cLog ) 
  
    _SetGetLogFile( App.Cargo:cLog ) // вернём главное имя вывода лог-файла 
  
 RETURN NIL