#include "minigui.ch" 
 #include "tsbrowse.ch" 
  
  
 MEMVAR oBrw 
  
 FUNCTION Main() 
    LOCAL cDbf := 'Test.dbf' 
    LOCAL i := 0 
  
    REQUEST DBFCDX  
  
    SET CENTURY ON 
    SET DELETED OFF 
    RDDSETDEFAULT('DBFCDX') 
  
    if !file(cDbf) 
       DBCreate( cDbf , {{"String", "C", 50 , 0}, {"number", "N", 5, 0} } ) 
       USE (cDbf) Excl New Alias "TEST" 
       FOR i := 1 TO 200 
           TEST->(DbAppend()) 
           TEST->String := RandStr(50) 
           TEST->Number := Random( 200) 
           IF( i % 3 == 0, TEST->(DbDelete()) , NIL ) 
       END 
     
       INDEX ON Number TAG "ALL" TO ("TEST") 
       INDEX ON Number TAG "DEL" TO ("TEST") FOR ( !Deleted() ) 
  
       USE 
    end 
      
  
  
  
    DEFINE WINDOW Form_0 ; 
           At 0, 0 ; 
           WIDTH 800 ; 
           HEIGHT 450 ; 
           TITLE 'TsBrowse sample' ; 
           ICON 'lupa.ico' ; 
           MAIN ; 
  
  
        DEFINE STATUSBAR  SIZE 10 BOLD 
            STATUSITEM "" 
            STATUSITEM "Right mouse button - the popup menu TBROWSE" WIDTH 380  
            STATUSITEM " Recno: 0/0" WIDTH 200  
            STATUSITEM "Alias: "+ ALIAS() WIDTH 115  
            DATE 
        END STATUSBAR 
  
  
     END WINDOW 
  
  
    USE (cDbf) Shared New Alias "TEST" INDEX ("TEST.CDX") 
    TEST->(OrdSetFocus("DEL")) 
  
    CreateBrowse( "oBrw", 'Form_0', 30, 2, Form_0.Width-20, Form_0.Height-95, 'TEST' ) 
    AEval( oBrw:aColumns, { |oCol| oCol:lEdit := oCol:lFixLite := TRUE } ) 
    oBrw:SetColor( { 6 }, { { |a,b,c| IF( c:nCell == b, { Rgb( 66, 255, 236 ), Rgb( 111, 183, 155 ) } ,  { Rgb( 220, 220, 220 ), Rgb( 220, 220, 220 ) })  }   } )  // фон курсора 
    oBrw:bChange := { || oBrwChange() } 
    oBrw:lNoChangeOrd := .T.   
    oBrw:SetColSize( "String", 600 ) 
    oBrw:SetColSize( "Number", 150 ) 
  
  
    oBrw:Display() 
  
     DEFINE CONTEXT MENU CONTROL oBRW OF FORM_0 
            MENUITEM "Enable display of deleted records"  ACTION { || RecnoViewDel(.T.) }  NAME A1 
            MENUITEM "Disable display of deleted records" ACTION { || RecnoViewDel(.F.) }  NAME A2 
     END MENU 
  
  
  
    CENTER WINDOW Form_0 
    ACTIVATE WINDOW Form_0 
  
 RETURN Nil 
  
 FUNCTION CreateBrowse( cBrw, cParent, nRow, nCol, nWidth, nHeight, cAlias ) 
    LOCAL i 
  
    PUBLIC &cBrw 
  
    DEFINE TBROWSE &cBrw ; 
           AT nRow, nCol ; 
           ALIAS cAlias ; 
           OF &cParent ; 
           WIDTH  nWidth ; 
           HEIGHT nHeight ; 
           COLORS { CLR_BLACK, CLR_BLUE } ; 
           FONT "MS Sans Serif" ; 
           SIZE 8 
  
       :SetAppendMode( .F. ) 
       :SetDeleteMode( .F. ) 
  
       :lNoHScroll := .T. 
       :lCellBrw := .F. 
  
    END TBROWSE 
  
    LoadFields( cBrw, cParent ) 
  
  
    &cBrw:nHeightCell += 6 
    &cBrw:nHeightHead += 14 
    &cBrw:nWheelLines := 1 
  
    &cBrw:SetColor( {  3 },  {        RGB( 255, 255, 255 )})                              
    &cBrw:SetColor( {  4 },  { { || { RGB(  43, 149, 168 ), RGB(   0,  54,  94 )}}})      
    &cBrw:SetColor( { 12 },  { { || { RGB( 128, 128, 128 ), RGB( 250, 250, 250 )}}})      
    &cBrw:SetColor( {  2 },  { { ||   IF( !(oBrw:cAlias)->(Deleted()), RGB( 230, 240, 255 ), RGB( 130, 140, 155 )) }})                             
    &cBrw:SetColor( {  1 },  { { ||   IF( !(oBrw:cAlias)->(Deleted()), RGB(   0,   0,   0 ), RGB( 130, 40, 55 )) }})                          
    &cBrw:SetColor( {  5 },  { { ||   RGB(   0,   0, 255 )}})                             
    &cBrw:SetColor( { 11 },  { { ||   RGB(   0,   0,   0 )}})                             
  
    &cBrw:nClrLine := COLOR_GRID 
  
    &cBrw:ResetVScroll() 
  
 RETURN Nil 
  
  
  
 FUNCTION RandStr( nLen ) 
  
    LOCAL cSet  := "qwertyuiopasdfghjklzxcvbnmQWERTYUIOPASDFGHJKLZXCVBNM" 
    LOCAL cStr := "" 
    LOCAL i := 0 
  
    FOR i := 1 TO nLen 
       cStr += SubStr( cSet, Random( 52 ), 1 ) 
    NEXT 
  
 RETURN cStr 
  
  
 STATIC FUNCTION oBrwChange() 
    LOCAL cVal := HB_NToS( (oBrw:cAlias)->(OrdKeyNo()) ) + ' / ' + HB_NToS( (oBrw:cAlias)->(OrdKeyCount()) ) 
    Form_0.StatusBar.Item(3) := " RecnO: " + cVal 
    Form_0.oBrw.Setfocus 
 RETURN Nil 
  
 FUNCTION RecnoViewDel(lVal) 
     LOCAL cMsg 
  
     IF lVal  
        TEST->(DbSetOrder("ALL")) 
        cMsg := "Included a display of deleted records !" 
     ELSE 
        TEST->(DbSetOrder("DEL")) 
        cMsg := "Offline mode display of deleted records !" 
     ENDIF 
  
     oBrw:Reset() 
  
     MsgInfo(cMsg ) 
  
     Eval( oBrw:bChange ) 
 RETURN Nil