FUNCTION MLogFile( cFile )   // Получить \ установить имя файла вывода ф-ии MLog(...) 
 LOCAL cOld 
  STATIC MLog_File := "_MsgLog.txt" 
  cOld := MLog_File 
  If cFile != NIL; MLog_File := cFile 
  EndIf 
 RETURN cOld 
  
 FUNCTION MLog( ... )         // Сначала идет CRLF (первый параметер .T.\.F.) потом данные вывода 
 LOCAL i, k 
 LOCAL aParams := hb_aParams() 
 LOCAL nParams := len(aParams) 
 LOCAL hFile, cFile := MLogFile(), xVal, cTp, lCrLf := .T. 
  
  hFile := iif( File(cFile), FOpen(cFile, 2) , FCreate(cFile) ) 
  IF hFile < 1; RETURN .F. 
  ENDIF 
  FSeek( hFile, 0, 2) 
  IF nParams > 0 
     k := 1 
     If hb_IsLogical(aParams[1]) 
        k := 2 
        lCrLf := aParams[1] 
     EndIf 
     If lCrLf 
        FWrite( hFile, CRLF, 2 ) 
     EndIf 
     FOR i := k TO nParams 
         xVal := aParams[ i ] 
         cTp  := ValType( xVal ) 
         IF     cTp == 'C' ; xVal := iif(Empty(xVal), "'"+"'", trim(xVal)) 
         ELSEIF cTp == 'N' ; xVal := hb_ntos(xVal) 
         ELSEIF cTp == 'L' ; xVal := iif(xVal, ".T.", ".F.") 
         ELSEIF cTp == 'D' ; xVal := hb_DtoC(xVal, 'DD.MM.YYYY') 
         ELSEIF cTp == 'A' ; xVal := "ARRAY["  + hb_NToS( Len(xVal) ) + "]"  
         ELSEIF cTp == 'H' ; xVal :=  "HASH["  + hb_NToS( Len(xVal) ) + "]"  
         ELSEIF cTp == 'B' ; xVal := "'" + "B" + "'" 
         ELSEIF cTp == 'T' ; xVal := hb_TSToStr(xVal, .T.) 
         ELSEIF cTp == 'U' ; xVal := 'NIL' 
         ELSE              ; xVal := "'" + cTp + "'" 
         ENDIF    
         FWrite(hFile, xVal + Chr(9) ) 
     NEXT 
  ELSE 
     FWrite( hFile, CRLF, 2 ) 
  ENDIF 
  FClose( hFile ) 
  
 RETURN .T. 
  
 в комплекте с: 
  
 #command ?  [<explist,...>] => MLog( .T., <explist> ) 
 #command ?? [<explist,...>] => MLog( .F., <explist> ) 
 #command ?a [<arr>]         => aEval( <arr>, {|xv,ne| MLog(.T., ne, xv), MLog() }) 
 #command ?v [<arr>]         => aEval( <arr>, {|xv,ne| MLog(.T., ne, iif( Valtype(xv)=="A", hb_valtoexp(xv), xv )), MLog() }) 
  
 использовать 
  
 ?  nKey, chr(nKey), cKey, cTxt, aDim 
 ?a aDim 
 ?v aDim 
 ...