* Fixed missed hiding of all controls on a FOCUSED deleted TabPage in the 
   function _DeleteTabPage(). 
   It exists in the official version too. 
  
 * Added possibility to modify the following Windows events at runtime: 
 	- OnInit 
 	- OnRelease 
 	- OnInteractiveClose 
 	- OnGotFocus 
 	- OnLostFocus 
 	- OnNotifyClick 
 	- OnMouseclick 
 	- OnMouseDrag 
 	- OnMouseMove 
 	- OnMove 
 	- OnSize 
 	- OnMaximize 
 	- OnMinimize 
 	- OnPaint 
 	- OnRestore 
 	- OnDropFiles 
  
 * Added the useful pseudo-functions RGB2n( n1 [, n2] [, n3] ) and 
   n2RGB( n ) for converting of a color array. 
  
 * The 'Cursor' property is supported in the function GetProperty() 
   for the Forms. 
  
 * Added possibility to modify of 'OnEnter' event for the controls 
   at runtime. 
  
 * Added possibility to modify of the 'OnListDisplay/OnDropDown' and 
   'OnListClose/OnCloseUp' events for ComboBox control at runtime. 
  
 * The Spinner control supports now a changing of the INCREMENT 
   property at runtime. 
  
 * The Timer control supports now a changing of the INTERVAL and 
   ONCE properties at runtime. 
  
 * The BTNTEXTBOX control supports now a changing of the separated 
   TOOLTIPs for the edit box and buttons at runtime. 
  
 * The GETBOX control supports now a changing of the separated 
   TOOLTIPs for the edit box and buttons at runtime. 
  
 * The global fonts which were defined by the command DEFINE FONT 
   <font> FONTNAME <name> ... will preserved after closing of a form. 
  
 * A 'Value' property will changed to a first available item in the 
   RadioGroup control if a focused item was disabled with a putting of 
   'ReadOnly' property. 
  
 * Updated the TSBrowse, HBPrinter and Sqlite3 libraries. 
  
 * Added the new interesting samples and updated some Basic and 
   Advanced samples. 
 

 
 METHOD LoadFields( lEditable, aColSel, cAlsSel, aNameSel ) CLASS TSBrowse 
  
    Local n, nE, cHeading, nAlign, nSize, cData, cType, nDec, hFont, cPicture, ; 
          cBlock, nCols, aNames, cKey, ; 
          aColSizes := ::aColSizes, ; 
          cOrder, nEle, ; 
          cAlias, ; // := ::cAlias, ; 
          aAlign := { "LEFT", "CENTER", "RIGHT", "VERT" }, ; 
          aStru     //:= ( ::cAlias )->( DbStruct() ) 
    Local cName 
  
    Default lEditable := ::lEditable, ; 
            aColSizes := {} 
  
    cAlias    := If( HB_ISCHAR ( cAlsSel ), cAlsSel, ::cAlias  ) 
    aStru     := ( cAlias )->( DbStruct() ) 
    aNames    := If( HB_ISARRAY( aColSel ), aColSel, ::aColSel ) 
 //   aNames    := ::aColSel 
    nCols     := If( aNames == Nil, ( cAlias )->( FCount() ), Len( aNames ) ) 
    aColSizes := If( Len( ::aColumns ) == Len( aColSizes ), Nil, aColSizes ) 
  
    For n := 1 To nCols 
  
       nE := If( aNames == Nil, n, ( cAlias )->( FieldPos( aNames[ n ] ) ) ) 
  
       If ValType( ::aHeaders ) == "A" .and. ! Empty( ::aHeaders ) .and. n <= Len( ::aHeaders ) 
          cHeading := ::aHeaders[ n ] 
       Else 
          cHeading := ::Proper( ( cAlias )->( Field( nE ) ) ) 
       EndIf 
  
       If ( nEle := AScan( ::aTags, {|e| Upper( cHeading ) $ Upper( e[ 2 ] ) } ) ) > 0 
          cOrder := ::aTags[ nEle, 1 ] 
          cKey   := ( cAlias )->( OrdKey() ) 
  
          If Upper( cHeading ) $ Upper( cKey ) 
             ::nColOrder := If( Empty( ::nColOrder ), Len( ::aColumns ) + 1, ::nColOrder ) 
          EndIf 
       Else 
          cOrder := "" 
       EndIf 
  
       nAlign := If( ::aJustify != Nil .and. Len( ::aJustify ) >= nE, ::aJustify[ nE ], ; 
                     If( ( cAlias )->( ValType( FieldGet( nE ) ) ) == "N", 2, ; 
                     If( ( cAlias )->( ValType( FieldGet( nE ) ) ) == "L", 1, 0 ) ) ) 
  
       nAlign := If( ValType( nAlign ) == "L", If( nAlign, 2, 0 ), ; 
                 If( ValType( nAlign ) == "C", AScan( aAlign, nAlign ) - 1, nAlign ) ) 
  
       nSize := If( ! aColSizes == Nil .and. Len( aColsizes ) >= nE, aColSizes[ nE ], Nil ) 
  
       cType := aStru[ nE, 2 ] 
       If cType == "C" 
          cPicture := "@K " + Replicate( 'X', aStru[ nE, 3 ] ) 
       ElseIf cType == "N" 
          cPicture := Replicate( '9', aStru[ nE, 3 ] ) 
          IF aStru[ nE, 4 ] > 0 
             cPicture := SubStr( cPicture, 1, aStru[ nE, 3 ]-aStru[ nE, 4 ] - 1 ) + '.' + Replicate( '9', aStru[ nE, 4 ] ) 
          endif 
          cPicture := "@K " + cPicture 
       EndIf 
  
       If nSize == Nil 
          cData := ( cAlias )->( FieldGet( nE ) ) 
          cType := aStru[ nE, 2 ] 
          nSize := aStru[ nE, 3 ] 
          nDec  := aStru[ nE, 4 ] 
          hFont := If( ::hFont != Nil, ::hFont, 0 ) 
  
          If cType == "C" 
             cData := PadR( Trim( cData ), nSize, "B" ) 
             nSize := GetTextWidth( 0, cData, hFont ) 
          ElseIf cType == "N" 
             cData := StrZero( cData, nSize, nDec ) 
             nSize := GetTextWidth( 0, cData, hFont ) 
          ElseIf cType == "D" 
             cData := cValToChar( If( Empty( cData ), Date(), cData ) ) 
             nSize := Int( GetTextWidth( 0, cData + "B", hFont ) ) + If( lEditable, 30, 0 ) 
          ElseIf cType == "M" 
             nSize := If( ::nMemoWV == Nil, 200, ::nMemoWV ) 
          Else 
             cData := cValToChar( cData ) 
             nSize := GetTextWidth( 0, cData, hFont ) 
          EndIf 
  
          nSize := Max( GetTextWidth( 0, Replicate( "B", Len( cHeading ) ), hFont ), nSize ) 
          nSize += If( ! Empty( cOrder ), 14, 0 ) 
  
       ElseIf ValType( ::aColSizes ) == "A" .and. ! Empty( ::aColSizes ) .and. n <= Len( ::aColSizes ) 
          nSize := ::aColSizes[ n ] 
       EndIf 
  
       If ValType( ::aFormatPic ) == "A" .and. ! Empty( ::aFormatPic ) .and. n <= Len( ::aFormatPic ) 
          cPicture := ::aFormatPic[ n ] 
       EndIf 
  
       cBlock := 'FieldWBlock("' + aStru[ nE, 1 ] + '",Select("' + cAlias + '"))' 
       ::AddColumn( TSColumn():New( cHeading, FieldWBlock( aStru[ nE, 1 ], Select( cAlias ) ),cPicture, ; 
                                    { ::nClrText, ::nClrPane }, { nAlign, DT_CENTER }, nSize,, lEditable,,, cOrder,,,, ; 
                                    5,,,, Self, cBlock ) ) 
  
       cName := ( cAlias )->( FieldName( nE ) ) 
  
       ATail( ::aColumns ):cData     :=   cAlias + "->" + FieldName( nE ) 
 //    ATail( ::aColumns ):cName     := ( cAlias )->( FieldName( nE ) )  // 21.07.2015 
       ATail( ::aColumns ):cField    := ( cAlias )->( FieldName( nE ) )  // 08.06.2018 
       ATail( ::aColumns ):cFieldTyp := aStru[ nE, 2 ]  // 18.07.2018 
       ATail( ::aColumns ):nFieldLen := aStru[ nE, 3 ]  // 18.07.2018 
       ATail( ::aColumns ):nFieldDec := aStru[ nE, 4 ]  // 18.07.2018 
  
       If HB_ISARRAY( aNameSel ) .and. Len( aNameSel ) > 0 .and. n <= Len( aNameSel ) 
          If HB_ISCHAR( aNameSel[ n ] ) .and. !Empty( aNameSel[ n ] ) 
             cName :=   aNameSel[ n ] 
          EndIf 
       EndIf 
  
       ATail( ::aColumns ):cName := cName 
  
       If cType == "L" 
          ATail( ::aColumns ):lCheckBox := .T. 
       EndIf 
  
       If ! Empty( cOrder ) 
          ATail( ::aColumns ):lIndexCol := .T. 
       EndIf 
  
    Next 
  
    If ::nLen == 0 
       cAlias := ::cAlias 
       ::nLen := If( ::bLogicLen == Nil, Eval( ::bLogicLen := {||( cAlias )->( LastRec() ) } ), Eval( ::bLogicLen ) ) 
    EndIf 
  
 Return Self