*-----------------------------------------------------------------------------* 
 FUNCTION HMG_Alert( cMsg, aOptions, cTitle, nType, cIcoFile, nIcoSize, aBtnColors, bInit, lClosable, cFont ) 
 *-----------------------------------------------------------------------------* 
    LOCAL nLineas 
    LOCAL aIcon  := { "ALERT", "QUESTION", "INFO", "STOP" } 
    LOCAL lFont  := .F. 
    LOCAL lEmpty := ( Empty( aOptions ) .OR. ISNUMERIC( aOptions ) ) 
    LOCAL cForm  := "oDlg" 
  
    IF _IsWindowDefined( cForm ) 
       nLineas := 0 
       WHILE _IsWindowDefined( cForm := 'oDlg' + hb_ntos( ++nLineas ) ) 
       END 
    ENDIF 
  
    lPressButton := .F. 
    lIsWin10 := hb_osisWin10() 
  
    hb_default( @aBackColor, nRGB2Arr( GetSysColor( COLOR_BTNFACE ) ) ) 
    hb_default( @aFontColor, nRGB2Arr( GetSysColor( COLOR_BTNTEXT ) ) ) 
  
    DEFAULT cTitle TO "Attention", aOptions TO { "&OK" }, lClosable TO .F. 
  
    IF ValType( aOptions ) == "A" 
       DEFAULT nType := iif( Len( aOptions ) > 1, 2, 1 ) 
    ELSE 
       DEFAULT nType := 1 
    ENDIF 
  
 #ifdef _HMG_COMPAT_ 
    CHECK TYPE cMsg       AS USUAL, ; 
               aOptions   AS USUAL, ; 
               cTitle     AS CHARACTER, ; 
               nType      AS NUMERIC, ; 
               cIcoFile   AS USUAL, ; 
               nIcoSize   AS USUAL, ; 
               aBtnColors AS USUAL, ; 
               bInit      AS USUAL, ; 
               lClosable  AS LOGICAL 
 #endif 
    IF nType < 1 .OR. nType > 4 
       nType := 1 
    ENDIF 
  
    AEval( aIcon, {|x, i| aIcon[ i ] := "ZZZ_B_" + x } ) 
  
    DEFAULT cIcoFile := aIcon[ nType ], nIcoSize := 32, cFont := "DlgFont" 
     
    IF GetFontHandle( cFont ) == 0 
       lFont := .T. 
       DEFINE FONT &cFont FONTNAME GetDefaultFontName() SIZE GetDefaultFontSize() - iif( lIsWin10, 1, 0 ) 
    ENDIF 
  
    cMsg    := cValToChar( cMsg ) 
    cMsg    := StrTran( cMsg, ";", CRLF ) 
    nLineas := MLCount( cMsg, 254 ) 
  
    IF lEmpty 
       lClosable := .T. 
       _HMG_ModalDialogReturn := 0 
    ELSE 
       hb_default( @_HMG_ModalDialogReturn, 0 ) 
    ENDIF 
  
    DEFINE WINDOW &cForm WIDTH 0 HEIGHT 0 TITLE cTitle MODAL NOSIZE BACKCOLOR aBackColor ; 
       ON INTERACTIVECLOSE ( lPressButton .OR. lClosable ) ; 
       ON RELEASE iif( ! lPressButton .AND. lClosable, _HMG_ModalDialogReturn := 0, NIL ) 
  
       FillDlg( cMsg, aOptions, nLineas, cIcoFile, nIcoSize, aBtnColors, bInit, lClosable, cFont ) 
  
    END WINDOW 
  
    ACTIVATE WINDOW &cForm  
  
    IF lFont 
       RELEASE FONT &cFont 
    ENDIF 
  
 RETURN _HMG_ModalDialogReturn 
  
 *-----------------------------------------------------------------------------* 
 STATIC FUNCTION FillDlg( cMsg, aOptions, nLineas, cIcoFile, nIcoSize, aBtnColors, bBlock, lClosable, cFont ) 
 *-----------------------------------------------------------------------------* 
    LOCAL hWnd 
    LOCAL hDC 
    LOCAL hDlgFont 
    LOCAL aBut := {} 
    LOCAL cForm := ThisWindow.Name 
    LOCAL cLblName 
    LOCAL cBtnName 
    LOCAL nCol 
    LOCAL nOpc := 1 
    LOCAL nMaxLin := 0 
    LOCAL nMaxBoton := 0 
    LOCAL nLenBotones 
    LOCAL nLenaOp 
    LOCAL nWidthCli, nHeightCli 
    LOCAL nWidthDlg, nHeightDlg 
    LOCAL nChrHeight 
    LOCAL nHeightBtn 
    LOCAL nVMARGIN_BUTTON := VMARGIN_BUTTON 
    LOCAL nSeconds 
    LOCAL n 
    LOCAL lExt 
     
 #ifdef _HMG_COMPAT_ 
    CHECK TYPE cMsg     AS CHARACTER, ; 
               aOptions AS USUAL, ; 
               nLineas  AS NUMERIC, ; 
               cIcoFile AS CHARACTER, ; 
               nIcoSize AS NUMERIC 
 #endif 
    IF ValType( aOptions ) == "N" 
  
       nSeconds := aOptions 
       aOptions := { "&OK" } 
  
       DEFINE TIMER oTimer OF &cForm INTERVAL nSeconds * 1000 ACTION ( lPressButton := .T., ThisWindow.Release() ) 
  
       This.oTimer.Enabled := .F. 
  
    ENDIF 
  
    nLenaOp := iif( ValType( aOptions ) == "A", Len( aOptions ), 1 ) 
  
    IF ( lExt := ( ISARRAY( aBtnColors ) .AND. Len( aBtnColors ) == nLenaOp ) ) 
       nVMARGIN_BUTTON := 3 * VMARGIN_BUTTON 
    ENDIF 
  
    hDlgFont := GetFontHandle( cFont ) 
  
    // calculate the column of the text output 
  
    nCol := MARGIN_ICON + iif( nIcoSize == 32, 0, MARGIN_ICON / iif( nIcoSize == 64, 2.8, 3.2 ) ) 
  
    hWnd := This.Handle 
    hDC := GetDC( hWnd ) 
  
    // calculate the character height for the dialog font 
  
    nChrHeight := GetTextHeight( hDC, aOptions[ 1 ], hDlgFont ) + nVMARGIN_BUTTON / 2 
  
    // calculate the maximum width of the lines 
  
    FOR n := 1 TO nLineas 
  
       nMaxLin := Max( nMaxLin, GetTextWidth( hDC, AllTrim( MemoLine( cMsg,, n ) ), hDlgFont ) ) 
  
    NEXT 
  
    // calculate the maximum width of the buttons 
  
    FOR n := 1 TO nLenaOp 
  
       nMaxBoton := Max( nMaxBoton, GetTextWidth( hDC, aOptions[ n ], hDlgFont ) ) 
  
    NEXT 
  
    ReleaseDC( hWnd, hDC ) 
  
    nMaxBoton += ( HMARGIN_BUTTON * iif( ! lExt .AND. lIsWin10 .AND. nLenAop > 2, 1.1, iif( nLenAop > 1, 2, 3 ) ) ) 
  
    // calculate the width of the options + their separations 
  
    nLenBotones := ( nMaxBoton + SEP_BUTTON ) * nLenaOp 
  
    nHeightBtn := nVMARGIN_BUTTON + nChrHeight + nVMARGIN_BUTTON 
  
    // calculate the width of the client area 
  
    nWidthCli := Max( MARGIN_ICON + nMaxLin + MARGIN, MARGIN + nLenBotones + MARGIN - HMARGIN_BUTTON ) + iif( nIcoSize > 48, MARGIN / 4, 0 ) 
  
    nWidthDlg := nWidthCli + GetBorderWidth() 
  
    nHeightCli := ( ( nLineas + iif( nLineas == 1, 4, 3 ) ) * nChrHeight ) + nVMARGIN_BUTTON + nHeightBtn + GetBorderHeight() 
  
    nHeightDlg := nHeightCli + GetTitleHeight() + SEP_BUTTON + GetBorderHeight() / iif( lIsWin10, 2.5, 1 ) 
  
    IF MSC_VER() > 0 .AND. _HMG_IsThemed 
       nWidthDlg += 10 
       nHeightDlg += 10 
    ENDIF 
  
    This.Width  := nWidthDlg 
    This.Height := nHeightDlg 
  
    IF nLineas > 1 
  
       FOR n := 1 TO nLineas 
  
          cLblName := "Say_" + StrZero( n, 2 ) 
  
          @ nChrHeight * ( n + iif( nLineas == 1, .5, 0 ) ) + GetBorderHeight(), nCol ; 
             LABEL &cLblName VALUE AllTrim( MemoLine( cMsg,, n ) ) OF &cForm ; 
             FONT cFont WIDTH nWidthCli - nCol - GetBorderWidth() - MARGIN / 4 HEIGHT nChrHeight ; 
             FONTCOLOR aFontColor BACKCOLOR aBackColor VCENTERALIGN 
  
       NEXT n 
  
    ELSE 
  
       @ nChrHeight * 1.5 + GetBorderHeight(), nCol ; 
          LABEL Say_01 VALUE AllTrim( cMsg ) OF &cForm ; 
          FONT cFont WIDTH nWidthCli - nCol - GetBorderWidth() - MARGIN / 4 HEIGHT nChrHeight ; 
          FONTCOLOR aFontColor BACKCOLOR aBackColor VCENTERALIGN 
  
    ENDIF 
  
    DRAW ICON IN WINDOW &cForm ; 
       AT nChrHeight + GetBorderHeight(), MARGIN / iif( nIcoSize == 32, 1.4, iif( nIcoSize == 48, 1.7, 2 ) ) ; 
       PICTURE cIcoFile WIDTH nIcoSize HEIGHT nIcoSize TRANSPARENT 
  
    FOR n := 1 TO nLenaOp 
  
       cBtnName := "Btn_" + StrZero( n, 2 ) 
  
       AAdd( aBut, cBtnName ) 
  
       IF lExt 
  
          @ 0, 0 BUTTONEX &cBtnName OF &cForm CAPTION aOptions[ n ] ; 
             FONTCOLOR aFontColor BACKCOLOR aBtnColors[ n ] NOXPSTYLE HANDCURSOR ; 
             FONT cFont WIDTH nMaxBoton HEIGHT nVMARGIN_BUTTON + nChrHeight + nVMARGIN_BUTTON ; 
             ACTION ( _HMG_ModalDialogReturn := This.Cargo, lPressButton := .T., ThisWindow.Release() ) 
  
       ELSE 
  
          @ 0, 0 BUTTON &cBtnName OF &cForm CAPTION aOptions[ n ] ; 
             FONT cFont WIDTH nMaxBoton HEIGHT nVMARGIN_BUTTON + nChrHeight + nVMARGIN_BUTTON ; 
             ACTION ( _HMG_ModalDialogReturn := This.Cargo, lPressButton := .T., ThisWindow.Release() ) 
  
       ENDIF 
  
       This.&( aBut[ nOpc ] ).Cargo := nOpc++ 
  
    NEXT n 
  
    nOpc := 1 
  
    FOR n := nLenaOp TO 1 STEP -1 
  
       This.&( aBut[ n ] ).Row := nHeightCli + SEP_BUTTON + GetBorderHeight() / iif( lIsWin10, 2.5, .9 ) - nChrHeight - nHeightBtn 
       This.&( aBut[ n ] ).Col := nWidthCli + iif( lIsWin10, 0, GetBorderWidth() / 2 ) - ( nMaxBoton + SEP_BUTTON ) * nOpc++ 
  
    NEXT n 
  
    This.Closable := lClosable 
  
    This.&( aBut[ Max( 1, Min( nLenaOp, _HMG_ModalDialogReturn ) ) ] ).SetFocus() 
  
    This.Center() 
  
    IF lClosable 
       ON KEY ESCAPE OF &cForm ACTION ( _HMG_ModalDialogReturn := 0, lPressButton := .T., ThisWindow.Release() ) 
    ENDIF 
     
    IF HB_ISBLOCK( bBlock ) 
       Do_WindowEventProcedure( bBlock, This.Index, 'WINDOW_ACTIVATE' ) 
    ENDIF 
  
    IF _IsControlDefined( "oTimer", cForm ) 
       This.oTimer.Enabled := .T. 
    ENDIF 
  
 RETURN NIL