// oW:aKrt_Field - массив для нужных контролов 
  
    y   += nHn + nGapsH 
  
    x   := nWl 
    cNm := 'VALSTS'; cTx := gTxt(cPref+'R_11A')         // COUNTRY     (СТРАНА) ТЕКСТ 
  @ y, x LABEL &('Lbl_'+cNm) WIDTH nLn  HEIGHT nHn  VALUE cTx    BACKCOLOR BC  ; 
                                                                 FONTCOLOR FC 
  
    x   += nLn + nGapsW                                           // COUNTRY     (СТРАНА КОД)  
    cNm := 'VALSTSK';  nLen := oSt:W('05') + 5 
  @ y, x GETBOX &cNm  WIDTH nLen  HEIGHT nHn  VALUE ''    ACTION oW:BtnGet()   ; 
                                                          VALID  VldValsts()   ; 
                                                                 BACKCOLOR BG  ; 
                                                                 FONTCOLOR FC 
    nNm := GetControlIndex (cNm, oW:cWnd) 
    hNm := GetControlHandle(cNm, oW:cWnd) 
    oNm := _HMG_aControlHeadClick[ nNm ] 
    oNm:OnDblClick := {|oGet| oSelfObj:SelRecEdit('VALSTSK')} 
    oNm:OnF5 := {|oGet| oSelfObj:BtnGet( oGet ) }                  // VK_F5 
    CONTROLREADONLY(hNm, .T.) 
    CONTROLTABSTOP (hNm, .F.)  
    aAdd(oW:aKrt_Field, { cNm, nNm, hNm, 'R_11A', .T., , , })  // .T. - снимаем ReadOnly, R_11A - FieldName 
  
    x   += nLen // + nGapsW 
    cNm := 'VALSTSN';  nLen := oSt:W('30') - 5              // COUNTRY     (СТРАНА НАИМЕН.) 
  @ y, x GETBOX &cNm  WIDTH nLen  HEIGHT nHn  VALUE '' READONLY  BACKCOLOR BG  ; 
                                                                 FONTCOLOR FC 
    nNm := GetControlIndex (cNm, oW:cWnd) 
    hNm := GetControlHandle(cNm, oW:cWnd) 
    oNm := _HMG_aControlHeadClick[ nNm ]              // object GetBox 
    oNm:OnDblClick := {|oGet| oSelfObj:SelRecEdit('VALSTSK')} 
    CONTROLTABSTOP(hNm, .F.)  
    aAdd(oW:aKrt_Field, { cNm, nNm, hNm, 'R_12A', .F., , , })  // .F. - не снимаем ReadOnly, R_12A - FieldName 
 ... 
 вот включаю корректировку по массиву: 
  
 METHOD SelRecEdit( cFocus )   CLASS Child_Mdi_UMZ_KLI 
 LOCAL a,i,j,k,n, nF, cC, oW := oSelfObj 
 LOCAL aBColor := oW:aBColorGet 
 LOCAL aFColor := oW:aFColorGet 
  
  ::lSetKrtEdit  := .T.                   // вошли в редактирование 
  
  k := len(::aKrt_Field) 
  FOR i := 1 TO k 
      a := ::aKrt_Field[ i ] 
      IF a[ 5 ]                                // { cNm, nNm, hNm, 'R_1' , .F., , , }  
         cC := a[ 1 ]                          // Name  controlа 
         IF nF == NIL; nF := a[ 2 ]            // Index controlа для SetFocus 
         ENDIF 
  
         a[ 6 ] := _GetBackColor( cC, ::cWnd )  // сохраняем цвета  Getbox 
         a[ 7 ] := _GetFontColor( cC, ::cWnd )   // --"--- 
  
         CONTROLREADONLY( a[ 3 ], .F. )        // включаем корректировку и 
         CONTROLTABSTOP ( a[ 3 ], .T. )        // переход по TabStop 
  
         _SetBackColor( cC, ::cWnd, aBColor )  // ставим цвета GetBox 
         _SetFontColor( cC, ::cWnd, aFColor )   // в коректировке 
      ENDIF 
  NEXT 
  
  SetProperty(::cWnd, 'BTN_OK'    , 'Visible', .T.) 
  SetProperty(::cWnd, 'BTN_CANCEL', 'Visible', .T.) 
  SetProperty(::cWnd, ::oBr1:cBrw , 'Enabled', .F.) 
  CONTROLTABSTOP(::oBr1:hBrw, .F.) 
  
  IF ! empty(cFocus) 
     nF := GetControlIndex(cFocus, ::cWnd) 
  ENDIF 
  
  IF ! empty(nF); _SetFocus(nF)        // ставим на первый или указанный 
  ENDIF 
  
 RETURN 
  
 

 
 METHOD PressBtn( nBtn )   CLASS Child_Mdi_UMZ_KLI 
 LOCAL a,f,i,j,k,n,o, cN, cC, nC, oC, cF, uV, uF, aM := {} 
  
  IF ::lPressBtn; RETURN 
  ENDIF 
  
  ::lPressBtn   := .T.                   // начали PressBtn 
  
  k := len(::aKrt_Field) 
  
  IF nBtn == 1                              // button OK. save values 
  
     FOR i := 1 TO k 
         a := ::aKrt_Field[ i ] 
         IF ! a[ 5 ]; LOOP                  // { cNm, nNm, hNm, 'R_1' , .F., , , } 
         ENDIF 
         cC := a[ 1 ]                       // control name 
         nC := a[ 2 ]                       // control index 
         oC := _HMG_aControlHeadClick[ nC ] // control object GetBox 
         cF := a[ 4 ]                       // control FieldName 
         uF := mFieldGet(cF, ::cAlias)      // FieldName value 
         uV := oC:VarGet()                  // control value 
         IF hb_IsChar(uV) 
            IF ! trim(uF) == trim(uV)       // изменено значение 
               aAdd(aM, { cF, uV }) 
               cN := '' 
               IF cC == 'VALSTSK'           // код страны 
                  cN := left(cC, len(cC)-1)+'N' 
               ENDIF 
               IF ! empty(cN)               // данные наименований от кода 
                  n := ascan(::aKrt_Field, {|aX,nX| aX[1] == cN }) 
                  IF n > 0 
                     j := ::aKrt_Field[ n ][2]          // index 
                     o := _HMG_aControlHeadClick[ j ]   // object 
                     f := ::aKrt_Field[ n ][4]          // field 
                     aAdd(aM, { f, o:VarGet() })        // изменены 
                  ENDIF 
               ENDIF 
            ENDIF 
         ELSE 
            IF ! uF == uV                   // изменено значение 
               aAdd(aM, { cF, uV })   
            ENDIF 
         ENDIF 
     NEXT 
  
     IF ! empty(aM) 
        dbSelectArea(::cAlias) 
        IF mRLock()                               // save modify values 
  
           mFieldPut(aM, , , .F.) 
  
        ELSE                                      // Lock error 
  
           ::lPressBtn   := .F.                   // завершили PressBtn 
            
           MsgStop(upper(gTxt('#'+::cAlias+'_Kod'))+': '+R_1+' NOT SAVE !',  ; 
                                                        'Lock record error.') 
           RETURN 
  
        ENDIF 
     ENDIF 
  
  ENDIF 
  
  FOR i := 1 TO k 
      a := ::aKrt_Field[ i ] 
      IF a[ 5 ]                             // { cNm, nNm, hNm, 'R_1' , .F., , , } 
         cC := a[ 1 ] 
  
         CONTROLREADONLY(a[ 3 ], .T.)          // выключаем корректировку и 
         CONTROLTABSTOP (a[ 3 ], .F.)          // переход по TabStop 
  
         IF ! a[ 6 ] == NIL; _SetBackColor( cC, ::cWnd, a[ 6 ] ) 
         ENDIF 
         IF ! a[ 7 ] == NIL; _SetFontColor( cC, ::cWnd, a[ 7 ] ) 
         ENDIF 
      ENDIF 
  NEXT 
  
  SetProperty(::cWnd, 'BTN_OK'    , 'Visible', .F.) 
  SetProperty(::cWnd, 'BTN_CANCEL', 'Visible', .F.) 
  SetProperty(::cWnd, ::oBr1:cBrw , 'Enabled', .T.) 
  CONTROLTABSTOP(::oBr1:hBrw, .T.) 
  
  ::oBr1:Refresh() 
  ::OnChange()  
  _MdiWindowsActivate( ::hWnd )  
  ::oBr1:SetFocus() 
  
  ::lSetKrtEdit := .F.                   // вышли из редактирования 
  ::lPressBtn   := .F.                   // завершили PressBtn 
  
 RETURN 
 

/* 
   MINIGUI - Harbour Win32 GUI library Demo 
 */ 
  
 #include "minigui.ch" 
 #include "dbstruct.ch" 
  
 DECLARE WINDOW Form_PrgBar 
  
 PROCEDURE Main 
  
    filltable( 500 ) 
    GO TOP 
  
    DEFINE WINDOW Form1 ; 
 	AT 0 , 0 ; 
 	WIDTH 600 HEIGHT 400 ; 
 	TITLE "ProgressBar Demo" ; 
 	MAIN 
  
 	DEFINE BUTTON Button_1 
 		ROW 20 
 		COL 20 
 		WIDTH 80 
 		HEIGHT 28 
 		CAPTION "Process 1" 
 		ACTION NtxCreate( FIELD(2), FIELD(2) ) 
                 DEFAULT .T. 
 	END BUTTON 
  
 	ON KEY ESCAPE ACTION ThisWindow.Release 
  
    END WINDOW 
  
    CENTER WINDOW Form1 
    ACTIVATE WINDOW Form1 
  
 RETURN 
  
 /////////////////////////////////////////////////////////////////// 
 FUNCTION NtxCreate( cField, cNtxName ) 
  
    CreateProgressBar( "Create index " + cNtxName + "..." )   
  
    INDEX ON (cField) TO (cNtxName) EVAL NtxProgress() EVERY LASTREC()/10 
  
    Form_PrgBar.PrgBar_1.Value := 100 
    Form_PrgBar.Label_1.Value := "Completed 100%" 
    // final waiting 
    INKEYGUI(1000) 
  
    CloseProgressBar() 
  
 RETURN NIL 
  
 /////////////////////////////////////////////////////////////////// 
 FUNCTION NtxProgress() 
  
    LOCAL nComplete := INT((RECNO()/LASTREC()) * 100) 
  
    Form_PrgBar.PrgBar_1.Value := nComplete 
    Form_PrgBar.Label_1.Value := "Completed "+ +HB_NTOS(nComplete) + "%" 
    // refreshing 
    INKEYGUI(100) 
  
 RETURN .T. 
  
 ////////////////////////////////////////////////////////////////////// 
 FUNCTION CreateProgressBar( cTitle ) 
  
 DEFINE WINDOW Form_PrgBar ; 
       ROW 0 COL 0 ; 
       WIDTH 428 HEIGHT 200 ; 
       TITLE cTitle ; 
       WINDOWTYPE MODAL ; 
       NOSIZE ; 
       FONT 'Tahoma' SIZE 11 
  
   @ 10,80 ANIMATEBOX Avi_1 ; 
       WIDTH 260 HEIGHT 40 ; 
       FILE 'filecopy.avi' ; 
       AUTOPLAY TRANSPARENT NOBORDER 
  
   @ 75,10 LABEL Label_1   ; 
       WIDTH 400 HEIGHT 20 ; 
       VALUE ''            ; 
       CENTERALIGN VCENTERALIGN 
  
   @ 105,20 PROGRESSBAR PrgBar_1 ; 
       RANGE 0,100         ; 
       VALUE 0             ; 
       WIDTH 380 HEIGHT 34 
  
 END WINDOW 
  
 Form_PrgBar.Center 
 Activate Window Form_PrgBar NoWait 
  
 RETURN NIL 
  
 ////////////////////////////////////////////////////////////////////// 
 FUNCTION CloseProgressBar() 
  
    Form_PrgBar.Release 
  
    DO MESSAGE LOOP 
  
 RETURN NIL 
  
 ////////////////////////////////////////////////////////////////////// 
 PROCEDURE filltable ( nCount ) 
  
    LOCAL aDbf[11][4], i 
  
    if !file('test.dbf') 
         aDbf[1][ DBS_NAME ] := "First" 
         aDbf[1][ DBS_TYPE ] := "Character" 
         aDbf[1][ DBS_LEN ]  := 20 
         aDbf[1][ DBS_DEC ]  := 0 
         // 
         aDbf[2][ DBS_NAME ] := "Last" 
         aDbf[2][ DBS_TYPE ] := "Character" 
         aDbf[2][ DBS_LEN ]  := 20 
         aDbf[2][ DBS_DEC ]  := 0 
         // 
         aDbf[3][ DBS_NAME ] := "Street" 
         aDbf[3][ DBS_TYPE ] := "Character" 
         aDbf[3][ DBS_LEN ]  := 30 
         aDbf[3][ DBS_DEC ]  := 0 
         // 
         aDbf[4][ DBS_NAME ] := "City" 
         aDbf[4][ DBS_TYPE ] := "Character" 
         aDbf[4][ DBS_LEN ]  := 30 
         aDbf[4][ DBS_DEC ]  := 0 
         // 
         aDbf[5][ DBS_NAME ] := "State" 
         aDbf[5][ DBS_TYPE ] := "Character" 
         aDbf[5][ DBS_LEN ]  := 2 
         aDbf[5][ DBS_DEC ]  := 0 
         // 
         aDbf[6][ DBS_NAME ] := "Zip" 
         aDbf[6][ DBS_TYPE ] := "Character" 
         aDbf[6][ DBS_LEN ]  := 10 
         aDbf[6][ DBS_DEC ]  := 0 
         // 
         aDbf[7][ DBS_NAME ] := "Hiredate" 
         aDbf[7][ DBS_TYPE ] := "Date" 
         aDbf[7][ DBS_LEN ]  := 8 
         aDbf[7][ DBS_DEC ]  := 0 
         // 
         aDbf[8][ DBS_NAME ] := "Married" 
         aDbf[8][ DBS_TYPE ] := "Logical" 
         aDbf[8][ DBS_LEN ]  := 1 
         aDbf[8][ DBS_DEC ]  := 0 
         // 
         aDbf[9][ DBS_NAME ] := "Age" 
         aDbf[9][ DBS_TYPE ] := "Numeric" 
         aDbf[9][ DBS_LEN ]  := 2 
         aDbf[9][ DBS_DEC ]  := 0 
         // 
         aDbf[10][ DBS_NAME ] := "Salary" 
         aDbf[10][ DBS_TYPE ] := "Numeric" 
         aDbf[10][ DBS_LEN ]  := 6 
         aDbf[10][ DBS_DEC ]  := 0 
         // 
         aDbf[11][ DBS_NAME ] := "Notes" 
         aDbf[11][ DBS_TYPE ] := "Character" 
         aDbf[11][ DBS_LEN ]  := 70 
         aDbf[11][ DBS_DEC ]  := 0 
  
         DBCREATE("test", aDbf) 
    endif 
  
    if select('test') == 0 
       dbusearea(.t.,,'test') 
    endif 
  
    for i := 1 to nCount 
       append blank 
  
       replace   first      with   'first'   + str(i) 
       replace   last       with   'last'    + str(i) 
       replace   street     with   'street'  + str(i) 
       replace   city       with   'city'    + str(i) 
       replace   state      with   chr( HB_RANDOMINT( 65,90 ) ) + chr( HB_RANDOMINT( 65,90 ) ) 
       replace   zip        with   alltrim( str( HB_RANDOMINT( 9999 ) ) ) 
       replace   hiredate   with   date() - 20000 + i 
       replace   married    with   ( HB_RANDOMINT() == 1 ) 
       replace   age        with   HB_RANDOMINT( 99 ) 
       replace   salary     with   HB_RANDOMINT( 10000 ) 
       replace   notes      with   'notes' + str(i) 
    next i 
  
 RETURN