#include "minigui.ch" 
  
 #define PROGRAM 'Тест-Grid' 
 #define COPYRIGHT MiniGUIVersion()+","+Version()+","+hb_compiler() 
  
 REQUEST HB_CODEPAGE_RU1251 
  
 Function MAIN() 
    Local cResPicture, nWidth, nHeight 
    LOCAL fColor  := { | Val, CellRowIndex | IF ( CellRowIndex / 2 == Int( CellRowIndex / 2 ) , RGB( 0, 0, 255 ) , RGB( 0, 255, 0 ) ) } 
    LOCAL fColor2 := { | Val, CellRowIndex | IF ( CellRowIndex / 2 == Int( CellRowIndex / 2 ) , RGB( 159, 191, 236 ) , RGB( 159, 191, 236 ) ) } 
  
    SET LANGUAGE TO RUSSIAN 
    SET CODEPAGE TO RUSSIAN 
    SET DATE TO GERMAN 
  
        DEFINE WINDOW Form_1; 
 		AT 0,0 ; 
 		WIDTH 650 HEIGHT 500 ; 
                 ICON "ICO_AAA" ; 
 		TITLE PROGRAM ; 
                 NOMAXIMIZE NOSIZE ; 
                 MAIN  
  
  
       @ 0,10 LABEL Label_9 WIDTH 500 HEIGHT 40 ; 
         VALUE 'MiniGUI ТЕСТ объекта GRID !' TRANSPARENT FONT "ARIAL" ; 
         SIZE 18 BOLD FONTCOLOR BLACK BACKCOLOR YELLOW CENTERALIG 
  
       DEFINE GRID Grid_Report 
             Row     110 
             Col     15 
             WIDTH   590 
             HEIGHT  250 
             HEADERS {'№','Наименование отчета', 'Файл' } 
             WIDTHS  { 30,430, 120 } 
             ITEMS   LoadReport() 
             VALUE   1 
             HEADERIMAGES {} 
             BACKCOLOR { 159, 191, 236 } 
             FONTSIZE 16 
             FONTBOLD .T. 
             FONTCOLOR { 255, 0, 255 } 
             DYNAMICFORECOLOR { fColor , fColor, fColor } 
             DYNAMICBACKCOLOR { fColor2, fColor2, fColor2 } 
             TOOLTIP 'Выбор отчета/F4-Редактирование отчета' 
             ONHEADCLICK { {|| MsgInfo('Header 1 Clicked !')} , { || MsgInfo('Header 2 Clicked !')} } 
             ONDBLCLICK LoadViewFr3(1) 
       END GRID  
  
       DEFINE STATUSBAR FONT "MS Sans serif" SIZE 10 BOLD 
          STATUSITEM COPYRIGHT 
          DATE 
          CLOCK 
       END STATUSBAR 
  
       ON KEY F4 ACTION LoadViewFr3(2) 
  
    END WINDOW 
  
 SetProperty( "Form_1", "BackColor" , { 159, 191, 236 } ) 
  
 CENTER WINDOW Form_1 
  
 ACTIVATE WINDOW Form_1 
  
 Return Nil 
 ///////////////////////////////////////////////////////////// 
 FUNCTION LoadViewFr3(nK) 
  
 //MsgInfo( GetColValue( "Grid_Report", "Form_1", 3 ),"GetColValue ->" ) 
 //MsgInfo( GetColValue( "Grid_Report", "Form_1", 2 ),"GetColValue ->" ) 
 IF nK == 1 
    MsgInfo( Form_1.Grid_Report.Cell( this.value, 3 ) ,"this.value, 3 ->") 
    MsgInfo( Form_1.Grid_Report.Cell( this.value, 2 ),"this.value, 2 ->" )  
 ELSE 
    MsgInfo( Form_1.Grid_Report.Cell( GetProperty("Form_1", "Grid_Report", "value"), 3 ) ,"value, 3 ->") 
    MsgInfo( Form_1.Grid_Report.Cell( GetProperty("Form_1", "Grid_Report", "value"), 2 ),"value, 2 ->" )  
 ENDIF 
  
 RETURN NIL 
 //////////////////////////////////////////////////////////// 
 FUNCTION LoadReport() 
    LOCAL aRows := { } 
  
    AAdd( aRows, {"1.", "Свод по поступлению из банка", "prixod.fr3" } ) 
    AAdd( aRows, {"2.", "Свод по начислению из банка" , "nachis.fr3" } ) 
    AAdd( aRows, {"3.", " резерв..............3      ", "*3.fr3" }      ) 
    AAdd( aRows, {"4.", " резерв..............4      ", "*4.fr3" }      ) 
  
    RETURN aRows 
 *--------------------------------------------------------------* 
 Function GetColValue( xObj, xForm, nCol ) 
 *--------------------------------------------------------------* 
   Local nPos:= GetProperty(xForm, xObj, 'Value') 
   Local aRet:= GetProperty(xForm, xObj, 'Item', nPos) 
 Return aRet[nCol]  
 

#include "minigui.ch" 
 #include "tsbrowse.ch" 
  
 REQUEST HB_CODEPAGE_RU1251, HB_CODEPAGE_RU866 
  
 STATIC aFont := {} 
  
 MEMVAR oBrw_1 
  
 FUNCTION Main() 
    LOCAL cIndex, cFilter 
    LOCAL cDbf := GetStartupFolder() + '\test_2.dbf' 
    LOCAL cFileIndex := GetStartupFolder() + '\test_200.cdx' 
  
    REQUEST DBFCDX , DBFFPT 
    SET LANGUAGE TO RUSSIAN // язык 
    SET CODEPAGE TO RUSSIAN // кодовая страница 
    RDDSETDEFAULT('DBFCDX') 
  
    SET CENTURY ON 
    SET DELETED ON 
  
    DEFINE FONT Font_1  FONTNAME "Times New Roman" SIZE 12 
    DEFINE FONT Font_2  FONTNAME "Times New Roman" SIZE 11 
    DEFINE FONT Font_3  FONTNAME "Times New Roman" SIZE 10 BOLD 
  
    AAdd( aFont, GetFontHandle( "Font_1" ) ) 
    AAdd( aFont, GetFontHandle( "Font_2" ) ) 
    AAdd( aFont, GetFontHandle( "Font_3" ) ) 
  
    DEFINE WINDOW Form_0 ; 
           At 0, 0 ; 
           WIDTH 790 ; 
           HEIGHT 450 ; 
           TITLE 'TsBrowse sample: Incremental search' ; 
           ICON 'lupa.ico' ; 
           MAIN ; 
           NOMAXIMIZE ; 
           NOSIZE 
  
       DEFINE LABEL Message 
          ROW        7 
          COL       10 
          WIDTH     80 
          HEIGHT    16 
          VALUE  'Поиск:' 
          FONTBOLD .T. 
       END LABEL 
  
       DEFINE TEXTBOX Text_1 
          ROW       5 
          COL      90 
          WIDTH   345 
          HEIGHT   21 
          ON CHANGE {|| RefreshBrowse()} 
       END TEXTBOX 
  
       ON KEY ESCAPE ACTION ThisWindow.Release 
  
     END WINDOW 
  
     DEFINE WINDOW Form_1 ; 
          AT   0,0   ; 
          WIDTH  600 ; 
          HEIGHT  40 ; 
          CHILD      ; 
          NOSYSMENU  ; 
          NOCAPTION 
  
       DEFINE LABEL Label_1 
          ROW     iif( IsVista().or.IsSeven(), 5, 10 ) 
          COL     10 
          WIDTH  580 
          HEIGHT  24 
          VALUE   '' 
          CENTERALIGN .T. 
       END LABEL 
  
     END WINDOW 
  
    //ScanSoft( cDbf ) 
  
    USE (cDbf) ALIAS 'B1' SHARED NEW CODEPAGE("RU866") 
    cIndex  := "UPPER(FIELD->Name_UK)" 
    cFilter := "FIELD->Kod_UK > 0 .AND. DELETED()==.F." 
    INDEX ON &cIndex TAG KODVIEW TO (cFileIndex)  ; 
    FOR &cFilter ADDITIVE 
    ORDLISTADD( cFileIndex ) 
    DBSETORDER(1) 
    GOTO TOP 
  
    CreateBrowse( "oBrw_1", 'Form_0', 30, 2, Form_0.Width-10, Form_0.Height-60, 'B1' ) 
  
       oBrw_1:aColumns[1]:cHeading := "Код" + CRLF + "Упр.Комп." 
       oBrw_1:SetColSize(1, 60) 
       oBrw_1:aColumns[1]:nAlign   := DT_CENTER 
  
       oBrw_1:aColumns[2]:cHeading := "Наименование Упр.Комп." 
       oBrw_1:SetColSize(2, 350) 
       oBrw_1:aColumns[2]:nAlign   := DT_LEFT 
  
       oBrw_1:aColumns[3]:cHeading := "Код" + CRLF + "показа" 
       oBrw_1:SetColSize(3, 60) 
       oBrw_1:aColumns[3]:nAlign   := DT_CENTER 
  
       oBrw_1:aColumns[4]:cHeading := "Код" + CRLF + "ЕИРЦ" 
       oBrw_1:SetColSize(4, 60) 
       oBrw_1:aColumns[4]:nAlign   := DT_RIGHT 
  
       oBrw_1:aColumns[5]:cHeading := "Наименование ЕИРЦ г.Москвы" 
       oBrw_1:SetColSize(5, 250) 
       oBrw_1:aColumns[5]:nAlign   := DT_LEFT 
  
    Form_0.Text_1.Setfocus 
  
    CENTER WINDOW Form_0 
    ACTIVATE WINDOW ALL 
  
 RETURN Nil 
  
  
 FUNCTION CreateBrowse( cBrw, cParent, nRow, nCol, nWidth, nHeight, cAlias ) 
    LOCAL i 
  
    PUBLIC &cBrw 
  
    DEFINE TBROWSE &cBrw ; 
              AT nRow, nCol ; 
              ALIAS cAlias ; 
              OF &cParent ; 
              WIDTH  nWidth ; 
              HEIGHT nHeight ; 
              COLORS { CLR_BLACK, CLR_BLUE } ; 
              FONT "MS Sans Serif" ; 
              SIZE 8 ; 
              SELECTOR .T. 
    END TBROWSE 
  
    &cBrw:LoadFields( .F. ) 
 //   &cBrw:LoadFields( .T. ) - все поля редактируемые 
    &cBrw:HideColumns( {6,7,8}, .T.) 
  
    &cBrw:lNoHScroll := .T. 
    &cBrw:lCellBrw := .T. 
    &cBrw:aColumns[3]:lEdit := .T. 
    &cBrw:aColumns[4]:lEdit := .t. 
    &cBrw:aColumns[5]:lEdit := .T. 
  
    &cBrw:nSelWidth := 16 
  
    &cBrw:ChangeFont( aFont[ 1 ],   , 1 ) 
    &cBrw:ChangeFont( aFont[ 3 ], 1 , 1 ) 
    &cBrw:ChangeFont( aFont[ 3 ],   , 2 ) 
  
    &cBrw:nHeightCell += 6 
    &cBrw:nHeightHead += 14 
    &cBrw:nWheelLines := 1 
  
    &cBrw:SetColor( { 16 },  {        Rgb(  43, 149, 168 )})                             //  Цвет фона в суперхидере 
    &cBrw:SetColor( {  3 },  {        Rgb( 255, 255, 255 )})                             //  шрифт в шапке 
    &cBrw:SetColor( {  4 },  { { || { Rgb(  43, 149, 168 ), Rgb(   0,  54,  94 )}}})     //  Шапка 
    &cBrw:SetColor( { 17 },  {        Rgb( 255, 255, 255 )})                             //  Цвет шрифта в суперхидере 
    &cBrw:SetColor( {  6 },  { { || { Rgb( 255, 255,  74 ), Rgb( 240, 240,   0 )}}})     //  фон курсора 
    &cBrw:SetColor( { 12 },  { { || { Rgb( 128, 128, 128 ), Rgb( 250, 250, 250 )}}})     //  фон курсора неактивного 
    &cBrw:SetColor( {  2 },  { { ||   Rgb( 230, 240, 255 )}})                            //  фон не в курсоре 
    &cBrw:SetColor( {  1 },  { { ||   Rgb(   0,   0,   0 )}})                            //  текст в ячейках 
    &cBrw:SetColor( {  5 },  { { ||   Rgb(   0,   0, 255 )}})                            //  текст в ячейках с фокусом 
    &cBrw:SetColor( { 11 },  { { ||   Rgb(   0,   0,   0 )}})                            //  цвет текста в курсоре неактивном 
  
    &cBrw:nClrLine := COLOR_GRID 
  
    &cBrw:SetAppendMode( .F. ) 
    &cBrw:SetDeleteMode( .F. ) 
  
    &cBrw:ResetVScroll() 
  
 RETURN Nil 
  
  
 STATIC FUNCTION RefreshBrowse() 
 LOCAL cSeek := Alltrim( Form_0.Text_1.Value ) 
 LOCAL cExp := "'" + UPPER(cSeek) + "' $ UPPER(B1->Name_Uk)" 
  
    IF !Empty(cSeek) 
       B1->( DbSetFilter( &("{||" + cExp + "}"), cExp ) ) 
    ELSE 
       B1->( DbClearFilter() ) 
    END 
  
    oBrw_1:Reset() 
  
 RETURN Nil