Пример 1: 
 ... 
   @ y, x  BUTTON ... ACTION ( MyBorder(cWnd, cLbl) )  
 ... 
 Function MyBorder( cWnd, cLbl ) 
 Local lB,h := GetControlHandle(cLbl, cWnd) 
  lB := ! IsWindowStyle(h, WS_BORDER) 
  SetWindowStyle(h, WS_BORDER, lB) 
  DoMethod(cWnd, cLbl, "Refresh") 
 Return 
  
 Пример 2: 
 STATIC lEdge := .T. 
 ... 
   @ y, x  BUTTON ... ACTION ( MyEdge(cWnd, cLbl) )  
 ... 
 Function MyEdge( cWnd, cLbl ) 
 Local lB,h := GetControlHandle(cLbl, cWnd) 
  lEdge := ! lEdge 
  If lEdge 
     ChangeStyle(h, WS_EX_CLIENTEDGE, 0, .T.) 
  Else 
     ChangeStyle(h, 0, WS_EX_CLIENTEDGE, .T.) 
  EndIf 
  DoMethod(cWnd, cLbl, "Refresh") 
 Return 
 

 
 #include "minigui.ch"  
 #include "i_winuser.ch" 
  
 #define PROGRAM '3-color form and resize the window'  
 #define VERSION ' version 1.0'  
  
 #define _Y   1 
 #define _X   2 
 #define _W   3 
 #define _H   4 
 #define _N   5 
 #define _T   6 
  
 STATIC lEdge := .T.  
  
 STATIC aLbl 
 STATIC aClr 
  
 Function Main()  
 Local hWnd,nCliW,nCliH,nH1, cWnd := "MyWnd"  
  
 DEFINE WINDOW &cWnd ;  
 AT 40, 50 ;  
 WIDTH 480 ;  
 HEIGHT 410 ;  
 MINWIDTH 480 MINHEIGHT 410 ;  
 TITLE PROGRAM ;  
 MAIN ;  
 ON SIZE ReSize() ;  
 ON MAXIMIZE ReSize() ;  
 ON INIT ReSize()  
  
 Test_This(cWnd) 
  
 aLblClrInit() 
  
 aEval(aLbl, {|a,n| MySayColorLabel( n, n ) }) 
  
 hWnd  := GetFormHandle  (cWnd)  
 nCliW := GetClientWidth (hWnd)  
 nCliH := GetClientHeight(hWnd)  
  
 @ 40 , nCliW - 120 BUTTON Button_1 CAPTION 'Message_1' ;  
 ACTION MsgInfo("ACTION - Message Button_1 !")  
  
 @ 180 , nCliW - 120 BUTTON Button_2 CAPTION 'Message_2' ;  
 ACTION MsgInfo("ACTION - Message Button_2 !")  
  
 @ nCliH - 40 , nCliW - 120 BUTTON Button_3 CAPTION 'Cancel' ;  
 ACTION ThisWindow.Release  
  
 // мен ть стиль/change style  
 @ 20, 70 BUTTON Button_Style CAPTION 'Label Style' ;  
 ACTION ( MyBorder(cWnd, aLbl[1][ _N ]),      ; 
          MyBorder(cWnd, aLbl[2][ _N ]),      ; 
          MyBorder(cWnd, aLbl[3][ _N ]) )  
  
 @ 40, 70 BUTTON Button_Edge CAPTION 'Label Edge' ;  
 ACTION ( MyEdge(cWnd, aLbl[1][ _N ]),   ; 
          MyEdge(cWnd, aLbl[2][ _N ]),   ; 
          MyEdge(cWnd, aLbl[3][ _N ]) )  
  
 END WINDOW  
  
 ACTIVATE WINDOW &cWnd  
  
 Return  
  
 Static Function  aLblClrInit() 
 Local cWnd,hWnd,nCliW,nCliH,nH1 
  
  cWnd  := _HMG_ThisFormName  
  hWnd  := GetFormHandle  (cWnd)  
  nCliW := GetClientWidth (hWnd)  
  nCliH := GetClientHeight(hWnd)  
  nH1   := nCliH/3  
  If aLbl == NIL 
     aLbl  := {} 
     aAdd( aLbl, {   0  , 0, nCliW, nH1  , "LabelColor_1", cWnd+"_Frame_Text1" } ) 
     aAdd( aLbl, { nH1  , 0, nCliW, nH1*2, "LabelColor_2", cWnd+"_Frame_Text2" } ) 
     aAdd( aLbl, { nH1*2, 0, nCliW, nCliH, "LabelColor_3", cWnd+"_Frame_Text3" } ) 
  Else 
     aLbl[ 1] [ _W ] := nCliW;  aLbl[ 1] [ _H ] := nH1 
     aLbl[ 2] [ _W ] := nCliW;  aLbl[ 2] [ _H ] := nH1 * 2 
     aLbl[ 3] [ _W ] := nCliW;  aLbl[ 3] [ _H ] := nCliH 
  Endif 
  If aClr == NIL 
     aClr := {} 
     aAdd( aClr, {178, 227, 137} ) 
     aAdd( aClr, {255,   0, 255} )  
     aAdd( aClr, {251, 250, 174} )  
  Endif 
  
 Return  
  
 Function Test_This( cWnd ) 
  
  If     empty(_HMG_ThisFormName) 
     _HMG_ThisFormName  := cWnd 
     _HMG_ThisFormIndex := GetFormIndex(cWnd) 
  ElseIf _HMG_ThisFormName != cWnd 
     _HMG_ThisFormName  := cWnd 
     _HMG_ThisFormIndex := GetFormIndex(cWnd) 
  Endif 
  
 Return 
  
 Function MySayColorLabel( nLabel, nColor )  
 LOCAL cLabelName, cLabelTitle, aColor  
 LOCAL cWnd,i,j,y,x,w,h,t  
  
 Default nColor To nLabel 
  
 cWnd        := _HMG_ThisFormName  
 aColor      := aClr[ nColor ] 
 cLabelName  := aLbl[ nLabel ][ _N ] 
 cLabelTitle := aLbl[ nLabel ][ _T ] 
 @ aLbl[ nLabel ][ _Y ], aLbl[ nLabel ][ _X ] LABEL &cLabelName  VALUE "" OF &cWnd ;  
 WIDTH aLbl[ nLabel ][ _W ] HEIGHT aLbl[ nLabel ][ _H ] ;  
 BACKCOLOR aColor BORDER CLIENTEDGE  
  
 i := GetControlIndex(cLabelName, cWnd)  
 j := cWnd + cLabelTitle  
 t := "Hello - " + cLabelName + " { "+STR(aColor[ 1 ], 3)+","  
 t += STR(aColor[ 2 ], 3) + "," + STR(aColor[ 3 ], 3)+" }"  
 y := _HMG_aControlRow [ i ] + 10  
 x := _HMG_aControlCol [ i ] + 10  
 w := 100  
 h := 24  
  
 @ y, x LABEL &cLabelTitle VALUE t WIDTH w HEIGHT h BACKCOLOR aColor  
  
 RETURN NIL  
  
 Function ReSize()  
 Local i,j,k 
 Local cWnd,hWnd,nCliW,nCliH ,nH1 
  
 cWnd := _HMG_ThisFormName  
 hWnd  := GetFormHandle  (cWnd)  
 nCliW := GetClientWidth (hWnd)  
 nCliH := GetClientHeight(hWnd)  
 nH1   := nCliH/3  
  
 aLblClrInit() 
  
 // change the position of the Label-Color  
 k := len(aLbl) 
 For i := 1 To k 
     SetProperty(cWnd, aLbl[ i ][ _N ], "Width" , aLbl[ i ][ _W ])  
     SetProperty(cWnd, aLbl[ i ][ _N ], "Height", aLbl[ i ][ _H ])  
 Next 
  
 // change the position of the buttons  
 SetProperty(cWnd, "Button_1", "Row" , 40 )  
 SetProperty(cWnd, "Button_1", "Col" , nCliW - 120 )  
  
 SetProperty(cWnd, "Button_2", "Row" , 180 )  
 SetProperty(cWnd, "Button_2", "Col" , nCliW - 120 )  
  
 SetProperty(cWnd, "Button_3", "Row" , nCliH - 40 )  
 SetProperty(cWnd, "Button_3", "Col" , nCliW - 120 )  
  
 SETFOCUS Button_3 OF &cWnd  
  
 Return  
  
 Function MyBorder( cWnd, cLbl )  
 Local lB,h := GetControlHandle(cLbl, cWnd)  
 lB := ! IsWindowStyle(h, WS_BORDER)  
 SetWindowStyle(h, WS_BORDER, lB)  
 DoMethod(cWnd, cLbl, "Refresh")  
 Return Nil  
  
 Function MyEdge( cWnd, cLbl )  
 Local lB,h := GetControlHandle(cLbl, cWnd)  
 lEdge := ! lEdge  
 If lEdge  
 ChangeStyle(h, WS_EX_CLIENTEDGE, 0, .T.)  
 Else  
 ChangeStyle(h, 0, WS_EX_CLIENTEDGE, .T.)  
 EndIf  
 DoMethod(cWnd, cLbl, "Refresh")  
 Return Nil  
  
 #pragma BEGINDUMP  
  
 #include <windows.h>  
 #include "hbapi.h"  
  
 HB_FUNC( GETCLIENTWIDTH )  
 {  
 RECT rect;  
  
 GetClientRect( ( HWND ) hb_parnl(1), &rect );  
 hb_retni( ( INT ) rect.right - rect.left );  
 }  
  
 HB_FUNC( GETCLIENTHEIGHT )  
 {  
 RECT rect;  
  
 GetClientRect( ( HWND ) hb_parnl(1), &rect );  
 hb_retni( ( INT ) rect.bottom - rect.top );  
 }  
  
 #pragma ENDDUMP