Изменения: 
 ========== 
 Функцию       _GetWindowObj( FormName )  
 переименовал в _WindowObj  ( FormName )  
 т.к. уже есть  _WindowCargo( FormName ), _GetWindowObj вынес на #translate. 
 Причина - в тек. версии есть функция _GetControlObject(...), чтобы не путаться. 
  
 #xtranslate _GetWindowObj( <cFormName> ) ; 
 => ; 
 _WindowObj( <cFormName> ) 
  
 Комплект базовых функций получился такой: 
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowObj( FormName, nIndex )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( Pcount() > 1, nIndex, iif( HB_ISNUMERIC( FormName ),  ;  
         AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
   
    IF i > 0 .and. HB_ISOBJECT( _HMG_aFormMiscData1 [ i ][ 1 ] ) 
       RETURN _HMG_aFormMiscData1 [ i ][ 1 ]  
    ENDIF  
   
 RETURN NIL  
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowCargo( FormName, xValue ) 
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISOBJECT ( FormName ), FormName:Index, ; 
               iif( HB_ISNUMERIC( FormName ),                 ;  
        AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
  
    If Pcount() > 1;        _HMG_aFormMiscData2 [ i ] := xValue 
    Else           ; RETURN _HMG_aFormMiscData2 [ i ] 
    Endif 
  
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowEvent( FormName, nKey, bEvent, p2, p3 ) 
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISOBJECT ( FormName ), FormName:Index, ; 
               iif( HB_ISNUMERIC( FormName ),                 ;  
        AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
    LOCAL o 
  
    IF i > 0 
       o := _HMG_aFormMiscData1 [ i ][ 1 ] 
       IF HB_ISOBJECT( o ) 
          If HB_ISBLOCK(bEvent); RETURN o:Event( nKey, bEvent ) 
          EndIf 
                                 RETURN o:Event( nKey, bEvent, p2, p3 ) 
       ENDIF  
    ENDIF  
  
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlObj( ControlName, FormName )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
   
    IF i > 0 .and. Len( _HMG_aControlMiscData0 [ i ] ) > 0 
       If HB_ISOBJECT ( _HMG_aControlMiscData0 [ i ][ 1 ] ) 
          RETURN        _HMG_aControlMiscData0 [ i ][ 1 ] 
       EndIf 
    ENDIF  
   
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlCargo( ControlName, FormName, xValue )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
   
     If Pcount() > 2;        _HMG_aControlMiscData2 [ i ] := xValue 
     Else           ; RETURN _HMG_aControlMiscData2 [ i ] 
     EndIf 
  
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlEvent( ControlName, FormName, nKey, bEvent, p2, p3 )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
    LOCAL o 
   
    IF i > 0 .and. Len( _HMG_aControlMiscData0 [ i ] ) > 0 
       o := _HMG_aControlMiscData0 [ i ][ 1 ] 
       If HB_ISOBJECT ( o ) 
          If HB_ISBLOCK(bEvent); RETURN o:Event( nKey, bEvent ) 
          EndIf 
                                 RETURN o:Event( nKey, bEvent, p2, p3 ) 
       EndIf 
    ENDIF  
   
 RETURN NIL 
  
  
 Классы и вспом. функции такие: 
 /////////////////////////////////////////////////////////////////////////////// 
 Зарезервированы для работы два сообщения: 
  
 #define WM_HMG_USER_MSG_W      (WM_USER+77)      
 #define WM_HMG_USER_MSG_C      (WM_USER+78)      
  
 /////////////////////////////////////////////////////////////////////////////// 
 *-----------------------------------------------------------------------------*  
 FUNCTION oWndData( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) 
 *-----------------------------------------------------------------------------*  
  
  Default nIndex  := 0,  ; 
          cName   := '', ; 
          nHandle := 0,  ; 
          nParent := 0,  ; 
          cType   := '', ; 
          cVar    := '' 
  
  If HB_ISOBJECT(oWin) 
     RETURN TCntData():New( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) 
  EndIf 
  
 RETURN TWndData():New( nIndex, cName, nHandle, nParent, cType, cVar ) 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TWndData 
  
      PROTECTED: 
  VAR cVar 
  VAR cName 
  VAR cType 
  VAR nIndex 
  VAR nHandle 
  VAR nParent 
  
  VAR oName 
  VAR oHand 
  
      EXPORTED: 
  VAR oCargo 
  VAR oUserKeys      
  VAR oEvent 
  VAR cChr             INIT ',' 
  
  METHOD New( nIndex, cName, nHandle, nParent, cType, cVar )     INLINE ( ; 
              ::nIndex := nIndex, ::cName := cName, ::nHandle := nHandle, ; 
              ::nParent := nParent, ::cType := cType, ::cVar := cVar,     ; 
              ::oName     := oKeyData(),                                  ; 
              ::oHand     := oKeyData(),                                  ; 
              ::oCargo    := oKeyData(),                                  ; 
              ::oUserKeys := oKeyData(),                                  ; 
              ::oEvent    := oKeyData( Self ),                            ; 
              Self )                                  CONSTRUCTOR 
  
  ACCESS Index         INLINE ::nIndex 
  ACCESS Name          INLINE ::cName 
  ACCESS Handle        INLINE ::nHandle 
  ACCESS Parent        INLINE ::nParent 
  ACCESS Type          INLINE ::cType 
  ACCESS VarName       INLINE ::cVar  
  ACCESS Row           INLINE  GetWindowRow   ( ::Handle ) 
  ACCESS Col           INLINE  GetWindowCol   ( ::Handle ) 
  ACCESS Width         INLINE  GetWindowWidth ( ::Handle ) 
  ACCESS Height        INLINE  GetWindowHeight( ::Handle ) 
  ACCESS ClientWidth   INLINE _GetClientRect  ( ::Handle )[ 3 ] 
  ACCESS ClientHeight  INLINE _GetClientRect  ( ::Handle )[ 4 ] 
  ACCESS Title         INLINE  GetWindowText  ( ::Handle ) 
  
  ACCESS Cargo         INLINE _WindowCargo( Self       ) 
  ASSIGN Cargo( xVal ) INLINE _WindowCargo( Self, xVal ) 
  METHOD Cargo( xVal ) INLINE _WindowCargo( Self, xVal ) 
  
  ACCESS WM_nMsgW      INLINE WM_HMG_USER_MSG_W 
  ACCESS WM_nMsgC      INLINE WM_HMG_USER_MSG_C 
  
  METHOD UsK     ( Key, Block, p2, p3 ) INLINE iif( HB_ISBLOCK( Block ),           ; 
                                          ::oUserKeys:Set( Key, Block ),           ; 
                                          ::oUserKeys:Do ( Key, Block, p2, p3 ) ) 
  
  METHOD UserKeys( Key, Block, p2, p3 ) INLINE ::UsK( Key, Block, p2, p3 ) 
  
  METHOD Event   ( Key, Block, p2, p3 ) INLINE iif( HB_ISBLOCK( Block ),           ; 
                                             ::oEvent:Set( Key, Block ),           ; 
                                             ::oEvent:Do ( Key, Block, p2, p3 ) ) 
  
  METHOD PostMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                  lMsgW := empty(nHandle) .or. lMsgW,       ; 
                      PostMessage( ::Handle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                           hb_defaultValue(nHandle, 0) ) ) 
       
  METHOD SendMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                  lMsgW := empty(nHandle) .or. lMsgW,       ; 
                      SendMessage( ::Handle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                           hb_defaultValue(nHandle, 0) ) ) 
  
  METHOD DoEvent(  Key, nHandle, nParam, cEvent ) 
  METHOD Controls( xType )                          
       
 ENDCLASS          
  
 METHOD DoEvent ( Key, nHandle, nParam, cEvent )  CLASS TWndData 
  LOCAL o, lW := .T. 
  
  nParam := iif( HB_ISNUMERIC(nParam), nParam, 0 ) 
  cEvent := cValToChar(cEvent) 
  
  If ! empty(nHandle)  
     o := _ControlObj(nHandle) 
     If HB_ISOBJECT(o) 
        lW := .F. 
     EndIf 
  EndIf 
  
  If ! HB_ISOBJECT(o) 
     o := Self 
  EndIf 
  
  If lW 
     _DoWindowEventProcedure ( ::oEvent:Get(Key), o:Index, cEvent, nParam ) 
  Else 
     _DoControlEventProcedure( ::oEvent:Get(Key), o:Index, cEvent, nParam ) 
  EndIf 
  
 RETURN Nil 
  
 METHOD Controls( xType )  CLASS TWndData 
  LOCAL aObj := {}, c, i, o, m := {} 
  
  If     HB_ISCHAR ( xType ) 
  
     c     := ::cChr 
     xType := hb_ATokens(xType, c) 
  
     AEval(xType, {|t| iif( Empty(t), Nil, aAdd( m, upper(alltrim( t )) ) ) }) 
  
  ElseIf HB_ISARRAY( xType ) 
  
     AEval(xType, {|t| iif( Empty(t), Nil, aAdd( m, upper(alltrim( t )) ) ) }) 
  
  Else 
  
     For i := 1 To ::oName:Len 
         o := ::oName:Value( i ) 
         If HB_ISOBJECT( o ); aAdd( m, o:Type ) 
         EndIf 
     Next 
  
  EndIf 
  
  For i := 1 To Len( m ) 
      o := ::oName:Value( i ) 
      If HB_ISOBJECT( o ) .and. m[ i ] == o:Type 
          aAdd( aObj, o ) 
      EndIf 
  Next 
  
 RETURN aObj 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TCntData   INHERIT TWndData 
  
      EXPORTED: 
  VAR oWin 
  
  METHOD New( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) INLINE ( ; 
              ::Super:New(nIndex, cName, nHandle, nParent, cType, cVar),    ; 
              ::oWin := oWin,                                               ; 
              Self )                              CONSTRUCTOR 
  
  ACCESS Title           INLINE ::oWin:Title 
  ACCESS Caption         INLINE _GetCaption( , , ::Index ) 
  
  METHOD PostMsg( nKey, nHandle )  INLINE PostMessage( ::oWin:Handle,       ; 
                             iif( empty(nHandle), ::WM_nMsgW, ::WM_nMsgC ), ; 
                                          nKey, hb_defaultValue(nHandle, 0) ) 
  
  METHOD SendMsg( nKey, nHandle )  INLINE SendMessage( ::oWin:Handle,       ; 
                             iif( empty(nHandle), ::WM_nMsgW, ::WM_nMsgC ), ; 
                                          nKey, hb_defaultValue(nHandle, 0) ) 
  
  METHOD Set()           INLINE ( ::oWin:oName:Set( upper(::Name ), Self ), ; 
                                  ::oWin:oHand:Set(       ::Handle, Self )  ) 
                         
  METHOD Del()           INLINE ( ::oWin:oName:Del( upper(::Name ), Self ), ; 
                                  ::oWin:oHand:Del(       ::Handle, Self )  ) 
  
 ENDCLASS          
  
 *-----------------------------------------------------------------------------*  
 FUNCTION oKeyData( o ) 
 *-----------------------------------------------------------------------------*  
 RETURN TKeyData():New(o) 
  
 ////////////////////////////////////////////////////////////////////////////////////////////// 
 CLASS TKeyData          
  
      PROTECTED: 
  VAR oObj 
  VAR aKey                      INIT hb_Hash() 
  VAR bBlk 
  
      EXPORTED: 
  VAR Cargo 
  
  METHOD New( o )               INLINE ( ::Obj := o, Self )         CONSTRUCTOR 
  
  METHOD Value( nPos )          INLINE hb_HValueAt( ::aKey, nPos ) 
  METHOD Set( Key, Block )      INLINE hb_HSet( ::aKey, Key, Block ) 
  METHOD Get( Key, Def )        INLINE hb_HGetDef( ::aKey, Key, Def ) 
  METHOD Del( Key )             INLINE iif( hb_hHasKey( ::aKey, Key ), hb_HDel( Key ), ) 
  METHOD Do ( Key, p1, p2, p3 ) INLINE ( ::bBlk := ::Get(Key), iif( HB_ISBLOCK(::bBlk),  ; 
                                             EVal(::bBlk, ::Obj, Key, p1, p2, p3), Nil ) ) 
  
  ACCESS Obj                    INLINE ::oObj 
  ASSIGN Obj( o )               INLINE ::oObj := iif( HB_ISOBJECT(o), o, Self ) 
  
  ACCESS Len                    INLINE Len( ::aKey ) 
  
 ENDCLASS          
  
 ////////////////////////////////////////////////////////////////////////////// 
  
 Подправил для совместимости и быстрого доступа через индекс контрола: 
  
 h_controlmisc.prg 
 *-----------------------------------------------------------------------------* 
 STATIC FUNCTION _GetCaption ( ControlName , ParentForm, nIndex ) 
 *-----------------------------------------------------------------------------* 
    LOCAL cRetVal 
    LOCAL i := iif( Pcount() > 2, nIndex, GetControlIndex ( ControlName , ParentForm ) ) 
  
    IF _HMG_aControlType [ i ] == 'TOOLBUTTON' 
       cRetVal := _HMG_aControlCaption [ i ] 
    ELSE 
       cRetVal := GetWindowText ( _HMG_aControlHandles [ i ] ) 
    ENDIF 
  
 RETURN cRetVal 
  
  
 h_windows.prg 
  
 Function _DoControlEventProcedure ( bBlock , i , cEventType , nParam ) 
 ... 
    if valtype( bBlock ) == 'B' .and. i > 0 
 ... 
 Function _DoWindowEventProcedure ( bBlock , i , cEventType, nParam ) 
 ... 
    if valtype( bBlock ) == 'B' .and. i > 0 
 ... 
  
 Посмотрел, что править связанное с _HMG_aControlMiscData1, для расширения  
 возможностей, трудоемко (много где) и стремно, то ввел новую переменную 
 _HMG_aControlMiscData0 
  
 i_var.ch 
   
  #define _HMG_SYSDATA_SIZE			448  // было 445  
  ...  
  #xtranslate _HMG_aScrollStep				=> _HMG_SYSDATA\[445\]  
  #xtranslate _HMG_aFormMiscData1                        => _HMG_SYSDATA\[446\]  
  #xtranslate _HMG_aFormMiscData2                        => _HMG_SYSDATA\[447\]  
  #xtranslate _HMG_aFormMiscData0                        => _HMG_SYSDATA\[448\]  
  
 i_windows.ch 
  
    #xtranslate <w>   . \<c\> . \<p:Object\>       => _ControlObj      ( \<"c"\> , <"w"> ) ;;   
  
  
 i_this.ch 
  
 #xtranslate This . <p:Object> => iif ( _HMG_ThisType == 'C' , _ControlObj ( _HMG_THISCONTROLNAME , _HMG_THISFORMNAME ) , _WindowObj  ( _HMG_THISFORMNAME ) ) 
  
 #xtranslate This . <c> . <p:Object>       => _ControlObj      ( <"c"> , _HMG_THISFORMNAME )  
  
    
  h_init.prg  
  ...  
     _HMG_aFormMiscData1                 := {}    
     _HMG_aFormMiscData2                 := {} 
     _HMG_aFormMiscData0                 := {} 
  
 h_events.prg  
  
 добавил обработку сообщений 
 *********************************************************************** 
    case WM_HMG_USER_MSG_W 
 *********************************************************************** 
    a := _WindowObj( hWnd ) 
    If HB_ISOBJECT(a) 
       a:DoEvent( wParam, lParam, nMsg - WM_HMG_USER_MSG_W + 1 ) 
    EndIf 
    exit 
 *********************************************************************** 
    case WM_HMG_USER_MSG_C 
 *********************************************************************** 
    a := iif( empty(lParam), _WindowObj( hWnd ), _ControlObj( lParam ) ) 
    If HB_ISOBJECT(a) 
       a:DoEvent( wParam, lParam, nMsg - WM_HMG_USER_MSG_W + 1 ) 
    EndIf 
    exit 
 *********************************************************************** 
  
  line 3271  
     _HMG_aFormMiscData1  [ i ]            := {}    
     _HMG_aFormMiscData2  [ i ]            := ''     
     _HMG_aFormMiscData0  [ i ]            := {} 
  
 Добавление переменной _HMG_aControlMiscData0 делал так. 
 Во всех файлах h_*.prg искал _HMG_aControlMiscData2 и добавлял 
    _HMG_aControlMiscData2 [k] := '' 
    _HMG_aControlMiscData0 [k] := {}  
    или 
    _HMG_aControlMiscData0 [k] := { oWndData(                             k ,    ; 
                                              _HMG_aControlNames         [k],    ; 
                                              _HMG_aControlHandles       [k],    ; 
                                              _HMG_aControlParenthandles [k],    ; 
                                              _HMG_aControlType          [k],    ; 
                                              mVar,                              ; 
                                  _WindowObj( _HMG_aControlParenthandles [k] ) ) ; 
                                  } 
  
 ставил значение на _HMG_aControlMiscData0 [k] там, где есть смысл от значений  
 параметров, иначе ставил 
    _HMG_aControlMiscData0 [k] := {} 
  
 Можно заполнить значением переменную у распространенных контролов, а в остальные 
 пустышку и постепенно заполнять по возможности и нал. времени. 
 Функции учитывают наличие пустышки в контролах. 
  
 В окнах поменял прямое создание объекта, на созд. через функцию, т.е. 
 там где было TWndData():New(...) надо заменить с 
   aAdd( _HMG_aFormMiscData1 [k], TWndData():New( k,                          ;  
                                                  _HMG_aFormNames        [k], ;  
                                                  _HMG_aFormHandles      [k], ;  
                                                  _HMG_aFormParentHandle [k], ;  
                                                  _HMG_aFormType         [k], ;  
                                                  &mVar. ) )  
 на    
    aAdd( _HMG_aFormMiscData1 [k], oWndData(                         k , ; 
                                             _HMG_aFormNames        [k], ; 
                                             _HMG_aFormHandles      [k], ; 
                                             _HMG_aFormParentHandle [k], ; 
                                             _HMG_aFormType         [k], ; 
                                             mVar ) ) 
  
 В TWndData и TsBrowse добавил (у себя) методы, аналоги :UserKeys(...) с кортким 
 названием :UsK(...), это на любителя. 
  
 Пример для тестирования будет приложен. 
 

 
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowCargo( FormName, xValue ) 
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISOBJECT ( FormName ), FormName:Index, ; 
               iif( HB_ISNUMERIC( FormName ),                 ;  
        AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
  
    If Pcount() > 1;        _HMG_aFormMiscData2 [ i ] := xValue 
    Else           ; RETURN _HMG_aFormMiscData2 [ i ] 
    Endif 
  
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowEvent( FormName, nKey, bEvent, p2, p3 ) 
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISOBJECT ( FormName ), FormName:Index, ; 
               iif( HB_ISNUMERIC( FormName ),                 ;  
        AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
    LOCAL o 
  
    IF i > 0 
       o := _HMG_aFormMiscData1 [ i ][ 1 ] 
       IF HB_ISOBJECT( o ) 
          If HB_ISBLOCK(bEvent); RETURN o:Event( nKey, bEvent ) 
          EndIf 
                                 RETURN o:Event( nKey, bEvent, p2, p3 ) 
       ENDIF  
    ENDIF  
  
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _WindowObj( FormName, nIndex )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( Pcount() > 1, nIndex, iif( HB_ISNUMERIC( FormName ),  ;  
         AScan( _HMG_aFormHandles, FormName ), GetFormIndex( FormName ) ) ) 
   
    IF i > 0 .and. HB_ISOBJECT( _HMG_aFormMiscData1 [ i ][ 1 ] ) 
       RETURN _HMG_aFormMiscData1 [ i ][ 1 ]  
    ENDIF  
   
 RETURN NIL  
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlObj( ControlName, FormName )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
   
    IF i > 0 .and. Len( _HMG_aControlMiscData0 [ i ] ) > 0 
       If HB_ISOBJECT ( _HMG_aControlMiscData0 [ i ][ 1 ] ) 
          RETURN        _HMG_aControlMiscData0 [ i ][ 1 ] 
       EndIf 
    ENDIF  
   
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlEvent( ControlName, FormName, nKey, bEvent, p2, p3 )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
    LOCAL o 
   
    IF i > 0 .and. Len( _HMG_aControlMiscData0 [ i ] ) > 0 
       o := _HMG_aControlMiscData0 [ i ][ 1 ] 
       If HB_ISOBJECT ( o ) 
          If HB_ISBLOCK(bEvent); RETURN o:Event( nKey, bEvent ) 
          EndIf 
                                 RETURN o:Event( nKey, bEvent, p2, p3 ) 
       EndIf 
    ENDIF  
   
 RETURN NIL 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION _ControlCargo( ControlName, FormName, xValue )  
 *-----------------------------------------------------------------------------*  
    LOCAL i := iif( HB_ISNUMERIC( FormName    ), FormName,           ;  
               iif( HB_ISOBJECT ( ControlName ), ControlName:Index,  ;  
               iif( HB_ISNUMERIC( ControlName ),                     ;  
     AScan( _HMG_aControlHandles, ControlName ),                     ; 
                 GetControlIndex( ControlName  , FormName ) ) ) ) 
   
     If Pcount() > 2;        _HMG_aControlMiscData2 [ i ] := xValue 
     Else           ; RETURN _HMG_aControlMiscData2 [ i ] 
     EndIf 
  
 RETURN NIL 
  
 ================================================================================ 
  
 Классы и вспом. функции : 
 ================================================================================ 
  
 /////////////////////////////////////////////////////////////////////////////// 
 Зарезервированы для работы два сообщения: 
  
 #define WM_HMG_USER_MSG_W      (WM_USER+77)      
 #define WM_HMG_USER_MSG_C      (WM_USER+78)      
 /////////////////////////////////////////////////////////////////////////////// 
  
 *-----------------------------------------------------------------------------*  
 FUNCTION oWndData( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) 
 *-----------------------------------------------------------------------------*  
  LOCAL o 
  
  Default nIndex  := 0,  ; 
          cName   := '', ; 
          nHandle := 0,  ; 
          nParent := 0,  ; 
          cType   := '', ; 
          cVar    := '' 
  
  If HB_ISOBJECT(oWin) 
     o := TCntData():New( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) 
     If ! Empty(o:Name) .and. ! Empty(o:Handle) 
        If     o:Type == 'TBROWSE' 
           o:TBrowse := _HMG_aControlIds [ o:Index ] 
        ElseIf o:Type == 'MESSAGEBAR' 
           o:StatusBar := o 
        EndIf 
        o:Set() 
     EndIf 
     RETURN o 
  EndIf 
  
 RETURN TWndData():New( nIndex, cName, nHandle, nParent, cType, cVar ) 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TWndData 
      PROTECTED: 
  VAR cVar 
  VAR cName 
  VAR cType 
  VAR nIndex 
  VAR nHandle 
  VAR nParent 
  
  VAR oMenu 
  VAR oToolBar       
  VAR oStatusBar       
  
  VAR cChr             INIT ',' 
  VAR uTmp 
  
      EXPORTED: 
  CLASSDATA oName      INIT oKeyData() 
  CLASSDATA oHand      INIT oKeyData() 
  
  VAR oCargo 
  VAR oUserKeys      
  VAR oEvent 
  
  METHOD New( nIndex, cName, nHandle, nParent, cType, cVar )     INLINE ( ; 
              ::nIndex := nIndex, ::cName := cName, ::nHandle := nHandle, ; 
              ::nParent := nParent, ::cType := cType, ::cVar := cVar,     ; 
              ::oCargo    := oKeyData(),                                  ; 
              ::oUserKeys := oKeyData(),                                  ; 
              ::oEvent    := oKeyData( Self ),                            ; 
              Self )                                  CONSTRUCTOR 
  
  ACCESS Index          INLINE ::nIndex 
  ACCESS Name           INLINE ::cName 
  ACCESS Handle         INLINE ::nHandle 
  ACCESS Parent         INLINE ::nParent 
  ACCESS Type           INLINE ::cType 
  ACCESS VarName        INLINE ::cVar  
  ACCESS Row            INLINE  GetWindowRow   ( ::Handle ) 
  ACCESS Col            INLINE  GetWindowCol   ( ::Handle ) 
  ACCESS Width          INLINE  GetWindowWidth ( ::Handle ) 
  ACCESS Height         INLINE  GetWindowHeight( ::Handle ) 
  ACCESS ClientWidth    INLINE _GetClientRect  ( ::Handle )[ 3 ] 
  ACCESS ClientHeight   INLINE _GetClientRect  ( ::Handle )[ 4 ] 
  ACCESS Title          INLINE  GetWindowText  ( ::Handle ) 
                        
  ACCESS Cargo          INLINE _WindowCargo( Self       ) 
  ASSIGN Cargo( xVal )  INLINE _WindowCargo( Self, xVal ) 
                        
  ACCESS IsWindow       INLINE .T. 
  ACCESS IsControl      INLINE .F. 
  ACCESS Chr            INLINE ::cChr 
  ASSIGN Chr( cChr )    INLINE ::cChr := iif( HB_ISCHAR(cChr), cChr, ::cChr ) 
  ACCESS StatusBar        INLINE ::oStatusBar 
  ASSIGN StatusBar( o )   INLINE ::oStatusBar := o  
                        
  ACCESS WM_nMsgW       INLINE WM_HMG_USER_MSG_W 
  ACCESS WM_nMsgC       INLINE WM_HMG_USER_MSG_C 
  
  METHOD UsK     ( Key, Block, p2, p3 )  INLINE iif( HB_ISBLOCK( Block ),           ; 
                                           ::oUserKeys:Set( Key, Block ),           ; 
                                           ::oUserKeys:Do ( Key, Block, p2, p3 ) ) 
  
  METHOD UserKeys( Key, Block, p2, p3 )  INLINE ::UsK( Key, Block, p2, p3 ) 
  
  METHOD Event   ( Key, Block, p2, p3 )  INLINE iif( HB_ISBLOCK( Block ),           ; 
                                              ::oEvent:Set( Key, Block ),           ; 
                                              ::oEvent:Do ( Key, Block, p2, p3 ) ) 
  
  METHOD PostMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                  lMsgW := empty(nHandle) .or. lMsgW,       ; 
                      PostMessage( ::Handle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                           hb_defaultValue(nHandle, 0) ) ) 
       
  METHOD SendMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                  lMsgW := empty(nHandle) .or. lMsgW,       ; 
                      SendMessage( ::Handle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                           hb_defaultValue(nHandle, 0) ) ) 
  
  METHOD DoEvent(  Key, nHandle, nParam, cEvent ) 
  METHOD GetListType() 
  METHOD GetObj4Type( cType )  
  METHOD GetObj4Name( cName ) 
  METHOD GetObj( xName )                 INLINE iif( HB_ISCHAR(xName), ::oName:Get(xName),  ; 
                                                                       ::oHand:Get(xName) ) 
 ENDCLASS          
  
 METHOD GetListType()  CLASS TWndData 
  LOCAL oType := oKeyData() 
  LOCAL aType := {} 
  
  ::oName:Eval({|k,o,i| k := i, oType:Set(o:Type, o:Type) }) 
    oType:Eval({|k,v,i| k := i, aAdd(aType, v) }) 
    oType := Nil 
  
 RETURN aType 
  
 METHOD GetObj4Type( cType, lEque )  CLASS TWndData 
  LOCAL aObj := {}, a, i, o 
  
  If ! empty(cType) 
     lEque := hb_defaultValue(lEque, .T.) 
     If ::Chr $ cType; lEque := .F. 
     EndIf 
     a := hb_ATokens(upper(cType), ::Chr) 
     FOR EACH cType IN a 
         For i := 1 To ::oName:Len 
             o := ::oName:Value( i ) 
             If     lEque 
                If cType == o:cType; aAdd( aObj, o ) 
                EndIf 
             ElseIf cType $ o:cType; aAdd( aObj, o ) 
             EndIf 
         Next 
     NEXT 
  EndIF 
  
 RETURN aObj 
  
 METHOD GetObj4Name( cName )  CLASS TWndData 
  LOCAL aObj := {}, a, i, o 
  
  If ! empty(cName) 
     a := hb_ATokens(cName, ::Chr) 
     FOR EACH cName IN a 
         For i := 1 To ::oName:Len 
             o := ::oName:Value( i ) 
             If cName $ o:cName; aAdd( aObj, o ) 
             EndIf 
         Next 
     NEXT 
  EndIF 
  
 RETURN aObj 
  
 METHOD DoEvent ( Key, nHandle, nParam, cEvent )  CLASS TWndData 
  LOCAL o, lW := .T. 
  
  nParam := iif( HB_ISNUMERIC(nParam), nParam, 0 ) 
  cEvent := hb_defaultValue(cEvent, '') 
  
  If ! empty(nHandle)  
     o := _ControlObj(nHandle) 
     If HB_ISOBJECT(o); lW := .F. 
     EndIf 
  EndIf 
  
  If ! HB_ISOBJECT(o); o := Self 
  EndIf 
  
  If lW; _DoWindowEventProcedure ( ::oEvent:Get(Key), o:Index, cEvent, nParam, o ) 
  Else ; _DoControlEventProcedure( ::oEvent:Get(Key), o:Index, cEvent, nParam, o ) 
  EndIf 
  
 RETURN Nil 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TCntData   INHERIT TWndData 
      PROTECTED: 
  VAR oWin 
  VAR oTBrowse         
  
      EXPORTED: 
  METHOD New( nIndex, cName, nHandle, nParent, cType, cVar, oWin ) INLINE ( ; 
              ::Super:New(nIndex, cName, nHandle, nParent, cType, cVar),    ; 
              ::oWin := oWin,                                               ; 
              Self )                              CONSTRUCTOR 
  ACCESS Title            INLINE ::oWin:Title 
  ACCESS Caption          INLINE iif( ::Type == 'TBROWSE',                  ; 
                                      ::oWin:Name + "." + ::Name,           ; 
                                      _GetCaption( ::Name, ::oWin:Name ) ) 
  ACCESS Cargo            INLINE _ControlCargo( , ::Index       ) 
  ASSIGN Cargo( xVal )    INLINE _ControlCargo( , ::Index, xVal ) 
  
  ACCESS Window           INLINE ::oWin 
  ACCESS IsWindow         INLINE .F. 
  ACCESS IsControl        INLINE .T. 
  
  METHOD PostMsg( nKey )  INLINE PostMessage( ::oWin:Handle, ::WM_nMsgC, nKey, ::nHandle ) 
  METHOD SendMsg( nKey )  INLINE SendMessage( ::oWin:Handle, ::WM_nMsgC, nKey, ::nHandle ) 
  
  METHOD Set()            INLINE ( ::oName:Set( ::Name  , Self ), ; 
                                   ::oHand:Set( ::Handle, Self )  ) 
  METHOD Del()            INLINE ( ::oName:Del( ::Name         ), ; 
                                   ::oHand:Del( ::Handle       )  ) 
  
  ACCESS StatusBar        INLINE ::oWin:oStatusBar 
  ASSIGN StatusBar( o )   INLINE ::oWin:oStatusBar := o  
  ACCESS TBrowse          INLINE ::oTBrowse 
  ASSIGN TBrowse( oBrw )  INLINE ::oTBrowse := oBrw 
  ACCESS Value            INLINE _GetValue( , ,       ::Index ) 
  ASSIGN Value( xVal )    INLINE _SetValue( , , xVal, ::Index, .T. ) 
  METHOD SetFocus()       INLINE _SetFocus      ( ::Name, ::oWin:Name ) 
  METHOD Disable( nPos )  INLINE _DisableControl( ::Name, ::oWin:Name, nPos ) 
  METHOD Enable ( nPos )  INLINE _EnableControl ( ::Name, ::oWin:Name, nPos ) 
  METHOD Show()           INLINE _ShowControl   ( ::Name, ::oWin:Name ) 
  METHOD Hide()           INLINE _HideControl   ( ::Name, ::oWin:Name ) 
  
 ENDCLASS          
  
 *-----------------------------------------------------------------------------*  
 FUNCTION oKeyData( o ) 
 *-----------------------------------------------------------------------------*  
 RETURN TKeyData():New(o) 
  
 ////////////////////////////////////////////////////////////////////////////////////////////// 
 CLASS TKeyData          
      PROTECTED: 
  VAR oObj 
  VAR aKey                      INIT hb_Hash() 
  VAR bBlk 
  
      EXPORTED: 
  VAR Cargo 
  
  METHOD New( o )               INLINE ( ::Obj := o, Self )         CONSTRUCTOR 
  METHOD Value( nPos )          INLINE hb_HValueAt( ::aKey, nPos ) 
  METHOD Set( Key, Block )      INLINE hb_HSet( ::aKey, Key, Block ) 
  METHOD Get( Key, Def )        INLINE hb_HGetDef( ::aKey, Key, Def ) 
  METHOD Del( Key )             INLINE iif( hb_hHasKey( ::aKey, Key ), hb_HDel( Key ), ) 
  METHOD Do ( Key, p1, p2, p3 ) INLINE ( ::bBlk := ::Get(Key), iif( HB_ISBLOCK(::bBlk),   ; 
                                              EVal(::bBlk, ::Obj, Key, p1, p2, p3), Nil ) ) 
  ACCESS Obj                    INLINE ::oObj 
  ASSIGN Obj( o )               INLINE ::oObj := iif( HB_ISOBJECT(o), o, Self ) 
  ACCESS Len                    INLINE Len( ::aKey ) 
  METHOD Eval( Block ) 
 ENDCLASS          
  
 METHOD Eval( Block ) CLASS TKeyData 
  LOCAL i, b := HB_ISBLOCK(Block) 
  LOCAL a := iif( b, Nil, array(0) ) 
  
  For i := 1 To ::Len 
      If b; Eval( Block, hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i ) 
      Else; aAdd( a,   { hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i } ) 
      EndIf 
  Next 
  
 RETURN a 
 

 
 h_controlmisc.prg 
 *-----------------------------------------------------------------------------* 
 FUNCTION _SetValue ( ControlName, ParentForm, Value, index, lSetGet ) 
 *-----------------------------------------------------------------------------* 
 ... 
 RETURN iif( empty(lSetGet), Nil, _GetValue( ControlName, ParentForm, Index ) ) 
 *-----------------------------------------------------------------------------* 
 FUNCTION _EraseControl ( i, p ) 
 *-----------------------------------------------------------------------------* 
    LOCAL mVar, t, hWnd, x 
  
    If HB_ISOBJECT( _HMG_aControlMiscData0 [ i ] ) 
       _HMG_aControlMiscData0 [ i ]:Del() 
    EndIf 
  
    DeleteObject ( _HMG_aControlFontHandle [ i ] ) 
 ... 
  
  
 h_events.prg  
  
 добавил обработку сообщений 
 *********************************************************************** 
    case WM_HMG_USER_MSG_W 
 *********************************************************************** 
    a := _WindowObj( hWnd ) 
    If HB_ISOBJECT(a) 
       a:DoEvent( wParam, lParam, wParam )  
    EndIf 
    exit 
 *********************************************************************** 
    case WM_HMG_USER_MSG_C 
 *********************************************************************** 
    a := iif( empty(lParam), _WindowObj( hWnd ), _ControlObj( lParam ) ) 
    If HB_ISOBJECT(a) 
       a:DoEvent( wParam, lParam, wParam )   
    EndIf 
    exit 
 *********************************************************************** 
  
 h_windows.prg 
  
 *-----------------------------------------------------------------------------* 
 Function _DoControlEventProcedure ( bBlock , i , cEventType , nParam, p2, p3 ) 
 *-----------------------------------------------------------------------------* 
 ... 
    if valtype( bBlock ) == 'B' .and. i > 0 
 ... 
       If _HMG_BeginWindowActive == .F. .or. !( cEventType == 'CONTROL_ONCHANGE' ) .or. _HMG_MainClientMDIHandle != 0 
          Eval( bBlock, nParam, p2, p3 ) 
       EndIf 
 ... 
 *-----------------------------------------------------------------------------* 
 Function _DoWindowEventProcedure ( bBlock , i , cEventType, nParam, p2, p3 ) 
 *-----------------------------------------------------------------------------* 
 ... 
    if valtype( bBlock ) == 'B' .and. i > 0 
 ... 
       _HMG_ThisControlName :=  "" 
       lRetVal := Eval( bBlock, nParam, p2, p3 ) 
       _PopEventInfo() 
 ... 
 Посмотрел, что править связанное с _HMG_aControlMiscData1, для расширения  
 возможностей, трудоемко (много где) и стремно, то ввел новую переменную 
 _HMG_aControlMiscData0 
  
 i_var.ch 
   
  #define _HMG_SYSDATA_SIZE			448  // было 445  
  ...  
  #xtranslate _HMG_aScrollStep				=> _HMG_SYSDATA\[445\]  
  #xtranslate _HMG_aFormMiscData1                        => _HMG_SYSDATA\[446\]  
  #xtranslate _HMG_aFormMiscData2                        => _HMG_SYSDATA\[447\]  
  #xtranslate _HMG_aControlMiscData0                     => _HMG_SYSDATA\[448\]  
  
 i_windows.ch 
  
    #xtranslate <w>   . \<c\> . \<p:Object\>       => _ControlObj      ( \<"c"\> , <"w"> ) ;;   
  
  
 i_this.ch 
  
 #xtranslate This . <p:Object> => iif ( _HMG_ThisType == 'C' , _ControlObj ( _HMG_THISCONTROLNAME , _HMG_THISFORMNAME ) , _WindowObj  ( _HMG_THISFORMNAME ) ) 
  
 #xtranslate This . <c> . <p:Object>       => _ControlObj      ( <"c"> , _HMG_THISFORMNAME )  
  
    
  h_init.prg  
  ...  
     _HMG_aFormMiscData1                 := {}    
     _HMG_aFormMiscData2                 := {} 
     _HMG_aControlMiscData0              := {} 
  
  
 Добавление переменной _HMG_aControlMiscData0 делал так. 
 Во всех файлах h_*.prg искал _HMG_aControlMiscData2 и добавлял 
    _HMG_aControlMiscData2 [k] := '' 
    _HMG_aControlMiscData0 [k] := {}  
    или 
    _HMG_aControlMiscData0 [k] := { oWndData(                             k ,    ; 
                                              _HMG_aControlNames         [k],    ; 
                                              _HMG_aControlHandles       [k],    ; 
                                              _HMG_aControlParenthandles [k],    ; 
                                              _HMG_aControlType          [k],    ; 
                                              mVar,                              ; 
                                  _WindowObj( _HMG_aControlParenthandles [k] ) ) ; 
                                  } 
  
 ставил значение на _HMG_aControlMiscData0 [k] там, где есть смысл от значений  
 параметров, иначе ставил 
    _HMG_aControlMiscData0 [k] := {} 
  
 Можно заполнить значением переменную у распространенных контролов, а в остальные 
 пустышку и постепенно заполнять по возможности и нал. времени. 
 Функции учитывают наличие пустышки в контролах. 
  
 В окнах поменял прямое создание объекта, на созд. через функцию, т.е. 
 там где было TWndData():New(...) надо заменить с 
   aAdd( _HMG_aFormMiscData1 [k], TWndData():New( k,                          ;  
                                                  _HMG_aFormNames        [k], ;  
                                                  _HMG_aFormHandles      [k], ;  
                                                  _HMG_aFormParentHandle [k], ;  
                                                  _HMG_aFormType         [k], ;  
                                                  &mVar. ) )  
 на    
    aAdd( _HMG_aFormMiscData1 [k], oWndData(                         k , ; 
                                             _HMG_aFormNames        [k], ; 
                                             _HMG_aFormHandles      [k], ; 
                                             _HMG_aFormParentHandle [k], ; 
                                             _HMG_aFormType         [k], ; 
                                             mVar ) ) 
  
 В TWndData и TsBrowse добавил (у себя) методы, аналоги :UserKeys(...) с кортким 
 названием :UsK(...), это на любителя. 
 

 
 *-----------------------------------------------------------------------------* 
 Function GetProperty ( Arg1 , Arg2 , Arg3 , Arg4 , Arg5 , Arg6 , Arg7 ) 
 *-----------------------------------------------------------------------------* 
 ... 
    ElseIf Pcount() == 3 // CONTROL 
 ... 
       ElseIf Arg3 == "AUTOFONT"  // Kevin Carmody <i@kevincarmody.com> 2007.04.23 
  
          RetVal := _SetGetAutoFont ( Arg2 , Arg1 ) 
  
       ElseIf Arg3 == "OBJECT" 
  
          RetVal := _ControlObj( Arg2, Arg1 ) 
  
       EndIf 
  
    ElseIf Pcount() == 4 // CONTROL WITH ARGUMENT OR TOOLBAR BUTTON OR (JK) HMG 1.0 Experimental Buid 6 GRID/BROWSE COLUMN - ColumnWidth 
 ... 
 Неточность в 
 *-----------------------------------------------------------------------------* 
 FUNCTION _EraseControl ( i, p ) 
 *-----------------------------------------------------------------------------* 
    LOCAL mVar, t, hWnd, x 
  
    If HB_ISOBJECT( _HMG_aControlMiscData0 [ i ][1] ) 
       _HMG_aControlMiscData0 [ i ][1]:Del() 
    EndIf 
 ... 
 пропустил [1]  
  
  
 

 
  *-----------------------------------------------------------------------------*  
  FUNCTION GetControlIndex ( ControlName, ParentForm )  
  *-----------------------------------------------------------------------------*  
     LOCAL mVar  
    
     IF     HB_ISNUMERIC(ParentForm ); RETURN ParentForm  
     ELSEIF HB_ISOBJECT (ControlName); RETURN ControlName:Index  
     ELSEIF HB_ISNUMERIC(ControlName); RETURN Ascan( _HMG_aControlHandles, ControlName )  
     ENDIF    
  
     IF empty(ControlName); ControlName := _HMG_ThisControlName 
     ENDIF 
  
     IF empty(ParentForm);  ParantForm := _HMG_ThisFormName 
     ENDIF 
    
     mVar := '_' + ParentForm + '_' + ControlName  
    
     IF __mvExist ( mVar )  
        RETURN __mvGet ( mVar )  
     ENDIF  
    
  RETURN 0