/* 
  * Создание объекта класса TKeyData, если задан параметр Obj, то в блоки кода 
  * метода Do(...) передается значение Obj, иначе Self. 
  */ 
 *-----------------------------------------------------------------------------*  
 FUNCTION oKeyData( Obj ) 
 *-----------------------------------------------------------------------------*  
 RETURN TKeyData():New(Obj) 
  
 ////////////////////////////////////////////////////////////////////////////////////////////// 
 CLASS TKeyData   
 ////////////////////////////////////////////////////////////////////////////////////////////// 
  
        PROTECTED: 
    VAR oObj 
    VAR aKey                      INIT hb_Hash() 
    
        EXPORTED: 
    VAR Cargo 
    
    METHOD New( o )               INLINE ( ::oObj := iif( HB_ISOBJECT(o), o, Self ), Self )  CONSTRUCTOR 
    METHOD Set( Key, Block )      INLINE hb_HSet( ::aKey, Key, Block ) 
    METHOD Get( Key, Def )        INLINE hb_HGetDef( ::aKey, Key, Def ) 
    METHOD Del( Key )             INLINE iif( hb_hHasKey( ::aKey, Key ), hb_HDel( ::aKey, Key ), ) 
    METHOD Do ( Key, p1, p2, p3 ) BLOCK  {|Self,Key,p1,p2,p3,b| b := ::Get(Key),                 ; 
                                  iif( HB_ISBLOCK(b), EVal(b, ::oObj, Key, p1, p2, p3), Nil ) } 
    ACCESS Obj                    INLINE ::oObj 
    ASSIGN Obj( o )               INLINE ::oObj := iif( HB_ISOBJECT(o), o, Self ) 
    ACCESS Len                    INLINE Len( ::aKey ) 
    METHOD IsBLock( Key )         INLINE HB_ISBLOCK( ::Get(Key) ) 
   _METHOD Eval( Block ) 
   _METHOD Sum( Key, xSum ) 
   _METHOD Destroy()  
  
 #ifndef __XHARBOUR__ 
    DESTRUCTOR Destroy() 
 #endif 
  
 ENDCLASS          
 ////////////////////////////////////////////////////////////////////////////////////////////// 
  
 /* 
  * Выполнение блока кода Block над всеми элементами контейнера данных ::aKey. 
  * Кодоблоку передаются ключ, значение и индекс.  
  * Если параметр Block, не блок кода, возвращается массив значений, где 
  * каждый элемент массив { ключ, значение, индекс } 
  * Примеры использования в классе TWndData: 
  *         METHOD GetListType()  
  *         METHOD GetObj4Type( cType, lEque ) 
  *         METHOD GetObj4Name( cName ) 
  */ 
 METHOD Eval( Block ) CLASS TKeyData 
    LOCAL i, b := HB_ISBLOCK(Block) 
    LOCAL a := iif( b, Nil, array(0) ) 
    
    For i := 1 To ::Len 
        If b; Eval( Block, hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i ) 
        Else; aAdd( a,   { hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i } ) 
        EndIf 
    Next 
  
 RETURN a 
  
 /* 
  * Выполнение операции суммирования над элементом контейнера данных с ключем Key.  
  * xSum может быть числом или массивом, тогда суммируются только числовые элементы. 
  * В качестве ключа можно использовать имена контролов, тогда возникает связка, при 
  * событийном программировании, с событием заполнения Value контрола из контейнера. 
  * Пример: Local o   := oKeyData() 
  *         Local Als := oBrw1:cAlias 
  *         o:Sum("PRIHOD", { 0, 0, 0 }) 
  *         o:Sum("RASHOD", { 0, 0, 0 }) 
  *         DO WHILE ! Eof() 
  *            o:Sum("COUNT" , 1) 
  *            o:Sum("KOLVO" , (Als)->KOLVO) 
  *            o:Sum("SUMMA" , (Als)->SUMMA) 
  *            If     (Als)->OPER == "PRI" 
  *               o:Sum("PRIHOD", { 1, (Als)->KOL_PRI, (Als)->SUM_PRI }) 
  *            ElseIf (Als)->OPER == "RAS" 
  *               o:Sum("RASHOD", { 1, (Als)->KOL_RAS, (Als)->SUM_RAS }) 
  *            EndIf 
  *            SKIP 
  *        ENDDO 
  *        ? o:Get("COUNT"), o:Get("KOLVO"), o:Get("SUMMA") 
  *        ? hb_valtoexp(o:Get("PRIHOD")) 
  *        ? hb_valtoexp(o:Get("RASHOD")) 
  */ 
 METHOD Sum( Key, xSum ) CLASS TKeyData 
  
    LOCAL sum := ::Get( Key, 0 )    
    
    If     HB_ISNUMERIC( xSum ) 
       If HB_ISNUMERIC( sum ); sum += xSum 
       Else                  ; sum := xSum 
       EndIf 
       ::Put( Key, sum ) 
    ElseIf HB_ISARRAY( xSum ) 
       If HB_ISARRAY(sum) .and. Len(sum) == Len(xSum) 
          AEval(xSum, {|s,i| sum[ i ]:= iif( HB_ISNUMERIC( s ), sum[ i ] + s, s ) } ) 
       Else 
          sum := xSum 
       EndIf 
       ::Put( Key, sum ) 
    EndIf 
  
 RETURN Nil 
  
 /* 
  * Освобождение собственных переменных объекта, устанавливаем в Nil. 
  */ 
 METHOD Destroy() CLASS TKeyData 
  
    LOCAL i, k, o 
    
    If HB_ISHASH( ::aKey ) 
       For i := 1 To Len( ::aKey ) 
           k := hb_HKeyAt( ::aKey, i ) 
           hb_HSet( ::aKey, k, Nil ) 
           hb_HDel( ::aKey, k ) 
       Next 
    EndIf 
    
    If HB_ISOBJECT(::Cargo) .and. ::Cargo:ClassName == ::ClassName 
       o := ::Cargo 
       If HB_ISHASH( o:aKey ) 
          For i := 1 To Len( o:aKey ) 
              k := hb_HKeyAt( o:aKey, i ) 
              hb_HSet( o:aKey, k, Nil ) 
              hb_HDel( o:aKey, k ) 
          Next 
       EndIf 
    EndIf 
    
    ::oObj := ::aKey := ::Cargo := Nil 
  
 RETURN Nil 
 

 
 *-----------------------------------------------------------------------------*  
 FUNCTION oWndData( nIndex, cName, nHandle, nParent, cType, cVar, oWin, lVmMt ) 
 *-----------------------------------------------------------------------------*  
  LOCAL o 
  
  Default nIndex  := 0,      ; 
          cName   := '',     ; 
          nHandle := 0,      ; 
          nParent := 0,      ; 
          cType   := '',     ; 
          cVar    := '',     ; 
          lVmMt   := hb_mtvm() 
  
  If ! HB_ISOBJECT( oWin )                                                     // window 
     o := TWndData():New():Def( nIndex, cName, nHandle, nParent, cType, cVar, lVmMt ) 
  Else                                                                         // control 
     o := TCnlData():New():Def( nIndex, cName, nHandle, nParent, cType, cVar, oWin, lVmMt ) 
     If ! Empty(o:Name) .and. ! Empty(o:Handle) 
        If o:Type == 'TBROWSE' 
           o:TBrowse := _HMG_aControlIds [ o:Index ] 
        EndIf 
        o:Set() 
     EndIf 
  EndIf 
  
 RETURN o 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TWndData 
 /////////////////////////////////////////////////////////////////////////////// 
  
        PROTECTED: 
    VAR cVar 
    VAR cName 
    VAR cType 
    VAR nIndex 
    VAR nHandle 
    VAR nParent 
    VAR cChr             INIT ',' 
    VAR lMT              INIT .F. 
    
    CLASSDATA oName      INIT oKeyData() 
    CLASSDATA oHand      INIT oKeyData() 
    
        EXPORTED: 
    VAR oCargo 
    VAR oUserKeys      
    VAR oEvent 
    
    METHOD New() INLINE Self   CONSTRUCTOR 
  
    METHOD Def( nIndex, cName, nHandle, nParent, cType, cVar, lVmMt ) INLINE (      ; 
                ::nIndex  := nIndex , ::cName := cName, ::nHandle := nHandle,       ; 
                ::nParent := nParent, ::cType := cType, ::cVar    := cVar,          ; 
                ::oCargo  := oKeyData(), ::oUserKeys := oKeyData(),                 ; 
                ::oEvent  := oKeyData( Self ), ::MT  := lVmMt,                      ; 
                  Self )                                   
    ACCESS MT             INLINE   ::lMT 
    ASSIGN MT( lVmMt )    INLINE ( ::lMT := iif( HB_ISLOGICAL(lVmMt), lVmMt, .F. ), ; 
                                   ::oName:MT     := ::lMT, ::oHand:MT  := ::lMT,   ; 
                                   ::oCargo:MT    := ::lMT, ::oEvent:MT := ::lMT,   ; 
                                   ::oUserKeys:MT := ::lMT ) 
    ACCESS Index          INLINE ::nIndex 
    ACCESS Name           INLINE ::cName 
    ACCESS Handle         INLINE ::nHandle 
    ACCESS Parent         INLINE ::nParent 
    ACCESS Type           INLINE ::cType 
    ACCESS VarName        INLINE ::cVar  
    ACCESS Row            INLINE  GetWindowRow   ( ::nHandle ) 
    ACCESS Col            INLINE  GetWindowCol   ( ::nHandle ) 
    ACCESS Width          INLINE  GetWindowWidth ( ::nHandle ) 
    ACCESS Height         INLINE  GetWindowHeight( ::nHandle ) 
    ACCESS ClientWidth    INLINE _GetClientRect  ( ::nHandle )[ 3 ] 
    ACCESS ClientHeight   INLINE _GetClientRect  ( ::nHandle )[ 4 ] 
    ACCESS Title          INLINE  GetWindowText  ( ::nHandle ) 
                          
    ACCESS Cargo          INLINE _WindowCargo( Self       ) 
    ASSIGN Cargo( xVal )  INLINE _WindowCargo( Self, xVal ) 
                          
    ACCESS IsWindow       INLINE .T. 
    ACCESS IsControl      INLINE .F. 
    ACCESS Chr            INLINE ::cChr 
    ASSIGN Chr( cChr )    INLINE ::cChr := iif( HB_ISCHAR(cChr), cChr, ::cChr ) 
                          
    ACCESS WM_nMsgW       INLINE WM_HMG_USER_MSG_W 
    ACCESS WM_nMsgC       INLINE WM_HMG_USER_MSG_C 
    
    METHOD UserKeys( Key, Block, p2, p3 )  INLINE iif( HB_ISBLOCK( Block ),           ; 
                                             ::oUserKeys:Set( Key, Block ),           ; 
                                             ::oUserKeys:Do ( Key, Block, p2, p3 ) ) 
    
    METHOD Event   ( Key, Block, p2, p3 )  INLINE iif( HB_ISBLOCK( Block ),           ; 
                                                ::oEvent:Set( Key, Block ),           ; 
                                                ::oEvent:Do ( Key, Block, p2, p3 ) ) 
    
    METHOD PostMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                    lMsgW := empty(nHandle) .or. lMsgW,       ; 
                       PostMessage( ::nHandle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                             hb_defaultValue(nHandle, 0) ) ) 
         
    METHOD SendMsg( nKey, nHandle, lMsgW ) INLINE ( lMsgW := lMsgW == Nil .or. !Empty(lMsgW), ; 
                                                    lMsgW := empty(nHandle) .or. lMsgW,       ; 
                       SendMessage( ::nHandle, iif( lMsgW, ::WM_nMsgW, ::WM_nMsgC ), nKey,    ; 
                                                             hb_defaultValue(nHandle, 0) ) ) 
    
   _METHOD DoEvent(  Key, nHandle, nParam, cEvent ) 
   _METHOD GetListType() 
   _METHOD GetObj4Type( cType )  
   _METHOD GetObj4Name( cName ) 
    METHOD GetObj( xName )                 INLINE iif( HB_ISCHAR(xName), ::oName:Get(xName),  ; 
                                                                         ::oHand:Get(xName) ) 
   _METHOD DelProperty( cName ) 
   _METHOD AddProperty( cName, xVal ) 
   _METHOD DelMethod( cMethod ) 
   _METHOD AddMethod( cMethod, pFunct ) 
    
    METHOD Destroy()  INLINE ( ::oCargo:Destroy(), ::oUserKeys:Destroy(),                ; 
                               ::oHand:Destroy(), ::oName:Destroy(), ::oEvent:Destroy(), ; 
                               ::cChr := ::cName := ::oName := ::oHand := ::cVar := Nil, ; 
                               ::oUserKeys := ::oEvent := ::cType := ::oCargo := Nil,    ; 
                               ::nIndex := Nil, ::nHandle := Nil, ::nParent := Nil ) 
  
 ENDCLASS                                               
 /////////////////////////////////////////////////////////////////////////////// 
  
 METHOD AddMethod( cMethod, pFunct ) CLASS TWndData 
  
    LOCAL o := Self 
    
    If HB_ISCHAR( cMethod ) .and. ! __ObjHasMsg( o, cMethod ) 
       RETURN ! Empty( __objAddMethod( o, cMethod, pFunct ) ) 
    ENDIF  
  
 RETURN .F. 
  
 METHOD DelMethod( cMethod ) CLASS TWndData 
  
    LOCAL o := Self 
    
    If HB_ISCHAR( cMethod ) .and. __ObjHasMsg( o, cMethod ) 
       RETURN Empty( __objDelMethod( o, cMethod ) ) 
    ENDIF  
  
 RETURN .F. 
  
 METHOD AddProperty( cName, xVal )  CLASS TWndData 
  
     LOCAL o := Self 
  
     If HB_ISCHAR( cName ) .and. ! __objHasData( o, cName ) 
        If ! Empty( __objAddData( o, cName ) ) 
           RETURN ! Empty( __ObjSetValueList( o, { cName, xVal } ) ) 
        EndIf 
     EndIf 
  
 RETURN .F. 
  
 METHOD DelProperty( cName )  CLASS TWndData 
  
     LOCAL o := Self 
     
     If HB_ISCHAR( cName ) .and. __objHasData( o, cName ) 
        RETURN Empty( __objDelData( o, cName ) ) 
     EndIf 
  
 RETURN .F. 
  
 METHOD GetListType()  CLASS TWndData 
  
    LOCAL oType := oKeyData() 
    LOCAL aType := {} 
    
    ::oName:Eval({|k,o,i| k := i, oType:Set(o:cType, o:cType) }) 
      oType:Eval({|k,v,i| k := i, aAdd(aType, v) }) 
      oType:Destroy() 
      oType := Nil 
  
 RETURN aType 
  
 METHOD GetObj4Type( cType, lEque )  CLASS TWndData 
  
    LOCAL aObj := {} 
    
    If ! empty(cType) 
       lEque := hb_defaultValue(lEque, .T.) 
       If ::cChr $ cType; lEque := .F. 
       EndIf 
       FOR EACH cType IN hb_ATokens(upper(cType), ::cChr) 
           ::oName:Eval({|ky,oc,ni| ky := ni, iif( lEque, iif( cType == oc:cType, aAdd(aObj, oc), ),   ; 
                                                          iif( cType $  oc:cType, aAdd(aObj, oc), ) ) }) 
       NEXT 
    EndIf 
  
 RETURN aObj 
  
 METHOD GetObj4Name( cName )  CLASS TWndData 
  
    LOCAL aObj := {} 
    
    If ! empty(cName) 
       FOR EACH cName IN hb_ATokens(cName, ::cChr) 
           ::oName:Eval({|ky,oc,ni| ky := ni, iif( cName $ oc:cName, aAdd(aObj, oc), Nil ) }) 
       NEXT 
    EndIF 
  
 RETURN aObj 
  
 METHOD DoEvent ( Key, nHandle, nParam, cEvent )  CLASS TWndData 
  
    LOCAL o, lW := .T. 
    
    nParam := iif( HB_ISNUMERIC(nParam), nParam, 0 ) 
    cEvent := hb_defaultValue(cEvent, '') 
    
    If ! empty(nHandle)  
       o := _ControlObj(nHandle) 
       If HB_ISOBJECT(o); lW := .F. 
       EndIf 
    EndIf 
    
    If ! HB_ISOBJECT(o); o := Self 
    EndIf 
    
    If lW; _DoWindowEventProcedure ( ::oEvent:Get(Key), o:Index, cEvent, nParam, o ) 
    Else ; _DoControlEventProcedure( ::oEvent:Get(Key), o:Index, cEvent, nParam, o ) 
    EndIf 
  
 RETURN Nil 
  
 /////////////////////////////////////////////////////////////////////////////// 
 CLASS TCnlData   INHERIT TWndData 
 /////////////////////////////////////////////////////////////////////////////// 
  
        PROTECTED: 
    VAR oWin 
    VAR oTBrowse         
    
        EXPORTED: 
    METHOD New() INLINE Self   CONSTRUCTOR 
  
    METHOD Def( nIndex, cName, nHandle, nParent, cType, cVar, oWin, lVmMt ) INLINE ( ; 
                ::Super:Def(nIndex, cName, nHandle, nParent, cType, cVar, lVmMt),    ; 
                ::oWin := oWin,                                                      ; 
                  Self )                              CONSTRUCTOR 
    ACCESS Title            INLINE ::oWin:cTitle 
    ACCESS Caption          INLINE iif( ::cType == 'TBROWSE',                 ; 
                                        ::oWin:cName + "." + ::cName,         ; 
                                        _GetCaption( ::cName, ::oWin:cName ) ) 
    ACCESS Cargo            INLINE _ControlCargo( , ::nIndex       ) 
    ASSIGN Cargo( xVal )    INLINE _ControlCargo( , ::nIndex, xVal ) 
    
    ACCESS Window           INLINE ::oWin 
    ACCESS IsWindow         INLINE .F. 
    ACCESS IsControl        INLINE .T. 
    
    METHOD PostMsg( nKey )  INLINE PostMessage( ::oWin:nHandle, ::WM_nMsgC, nKey, ::nHandle ) 
    METHOD SendMsg( nKey )  INLINE SendMessage( ::oWin:nHandle, ::WM_nMsgC, nKey, ::nHandle ) 
    
    METHOD Set()            INLINE ( ::oName:Set( ::cName  , Self ), ; 
                                     ::oHand:Set( ::nHandle, Self )  ) 
    METHOD Del()            INLINE ( ::oName:Del( ::cName         ), ; 
                                     ::oHand:Del( ::nHandle       )  ) 
    
    ACCESS TBrowse          INLINE ::oTBrowse 
    ASSIGN TBrowse( oBrw )  INLINE ::oTBrowse := oBrw 
    ACCESS Value            INLINE _GetValue( , ,       ::nIndex ) 
    ASSIGN Value( xVal )    INLINE _SetValue( , , xVal, ::nIndex, .T. ) 
    ACCESS SetFocus         INLINE _SetFocus      ( ::cName, ::oWin:cName ) 
    METHOD SetFocus()       INLINE _SetFocus      ( ::cName, ::oWin:cName ) 
    METHOD Disable( nPos )  INLINE _DisableControl( ::cName, ::oWin:cName, nPos ) 
    METHOD Enable ( nPos )  INLINE _EnableControl ( ::cName, ::oWin:cName, nPos ) 
    ACCESS Show             INLINE _ShowControl   ( ::cName, ::oWin:cName ) 
    METHOD Show()           INLINE _ShowControl   ( ::cName, ::oWin:cName ) 
    ACCESS Hide             INLINE _HideControl   ( ::cName, ::oWin:cName ) 
    METHOD Hide()           INLINE _HideControl   ( ::cName, ::oWin:cName ) 
    METHOD Destroy()        INLINE ( ::oCargo:Destroy()   , ::oEvent:Destroy(), ; 
                                     ::oUserKeys:Destroy(), ::oUserKeys := Nil, ; 
                                     ::oCargo  := ::oEvent  := ::cChr   := Nil, ; 
                                     ::nIndex  := ::cName   := ::cType  := Nil, ; 
                                     ::nHandle := ::nParent := ::cVar   := Nil  ) 
  
 ENDCLASS          
  
 /* 
  * Создание объекта класса TKeyData, если задан параметр Obj, то в блоки кода 
  * метода Do(...) передается значение Obj, иначе Self. 
  * Для использования в потоках, задаем значение параметра lVmMt := hb_mtvm(). 
  */ 
 *-----------------------------------------------------------------------------*  
 FUNCTION oKeyData( Obj, lVmMt ) 
 *-----------------------------------------------------------------------------*  
 RETURN TKeyData():New():Def(Obj, lVmMt) 
  
 ////////////////////////////////////////////////////////////////////////////////////////////// 
 CLASS TKeyData   
 ////////////////////////////////////////////////////////////////////////////////////////////// 
  
        PROTECTED: 
    VAR oObj 
    VAR aKey                      INIT hb_Hash() 
    VAR lMT                       INIT .F. 
  
    SYNC METHOD SGD( n, k, v ) 
  
        EXPORTED: 
    VAR Cargo 
    
    METHOD New()                  INLINE ( Self )              CONSTRUCTOR 
  
    METHOD Def( o, lVmMt )        INLINE ( ::Obj := o, ::MT := lVmMt, Self )  
  
    METHOD Set( Key, Block )      INLINE iif( ::lMT, ::SGD( 1, Key, Block ), hb_HSet   ( ::aKey, Key, Block ) ) 
    METHOD Get( Key, Def )        INLINE iif( ::lMT, ::SGD( 2, Key, Def   ), hb_HGetDef( ::aKey, Key, Def   ) ) 
    METHOD Del( Key )             INLINE iif( ::lMT, ::SGD( 3, Key        ),                                  ; 
                                             iif( hb_hHasKey( ::aKey, Key ), hb_HDel   ( ::aKey, Key ), Nil ) ) 
  
    METHOD Do ( Key, p1, p2, p3 ) BLOCK  {|Self,Key,p1,p2,p3,b| b := ::Get(Key),           ; 
                                             iif( HB_ISBLOCK(b), EVal(b, ::oObj, Key, p1, p2, p3), Nil ) } 
    ACCESS MT                     INLINE ::lMT 
    ASSIGN MT( lVmMt )            INLINE ::lMT  := iif( HB_ISLOGICAL(lVmMt), lVmMt, .F. ) 
    ACCESS Obj                    INLINE ::oObj 
    ASSIGN Obj( o )               INLINE ::oObj := iif( HB_ISOBJECT(o), o, Self ) 
    ACCESS Len                    INLINE Len( ::aKey ) 
    METHOD IsBLock( Key )         INLINE HB_ISBLOCK( ::Get(Key) ) 
   _METHOD Eval( Block ) 
   _METHOD Sum( Key, xSum ) 
   _METHOD Destroy()  
  
 #ifndef __XHARBOUR__ 
    DESTRUCTOR Destroy() 
 #endif 
  
 ENDCLASS          
 ////////////////////////////////////////////////////////////////////////////////////////////// 
  
 /* 
  * Для работы в потоках, синхронизируется доступ к контейнеру ::aKey 
  */ 
 METHOD SGD( n, k, v ) CLASS TKeyData 
  
    SWITCH n 
    CASE 1 
       hb_HSet( ::aKey, k, v ) 
       EXIT 
    CASE 2 
       RETURN hb_HGetDef( ::aKey, k, v ) 
       EXIT 
    CASE 3 
       If hb_hHasKey( ::aKey, k ) 
          hb_HDel   ( ::aKey, k ) 
       EndIf 
       EXIT 
    CASE 4 
       RETURN { hb_HKeyAt( ::aKey, k ), hb_HValueAt( ::aKey, k ) } 
       EXIT 
    END 
  
 RETURN Nil 
  
 /* 
  * Выполнение блока кода Block над всеми элементами контейнера данных ::aKey. 
  * Кодоблоку передаются ключ, значение и индекс.  
  * Если параметр Block, не блок кода, возвращается массив значений, где 
  * каждый элемент массив { ключ, значение, индекс } 
  * Примеры использования в классе TWndData: 
  *         METHOD GetListType()  
  *         METHOD GetObj4Type( cType, lEque ) 
  *         METHOD GetObj4Name( cName ) 
  */ 
 METHOD Eval( Block ) CLASS TKeyData 
    LOCAL m, i, b := HB_ISBLOCK(Block) 
    LOCAL a := iif( b, Nil, array(0) ) 
    
    For i := 1 To ::Len 
        If ::lMT 
           m := ::SGD( 4, i ) 
           If b; Eval( Block, m[ 1 ], m[ 2 ], i ) 
           Else; aAdd( a,   { m[ 1 ], m[ 2 ], i } )   
           EndIf 
        Else 
           If b; Eval( Block, hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i ) 
           Else; aAdd( a,   { hb_HKeyAt( ::aKey, i ), hb_HValueAt( ::aKey, i ), i } ) 
           EndIf 
        EndIf 
    Next 
  
 RETURN a 
  
 /* 
  * Выполнение операции суммирования над элементом контейнера данных с ключем Key.  
  * xSum может быть числом или массивом, тогда суммируются только числовые элементы. 
  * В качестве ключа можно использовать имена контролов, тогда возникает связка, при 
  * событийном программировании, с событием заполнения Value контрола из контейнера. 
  * Пример: Local o   := oKeyData() 
  *         Local Als := oBrw1:cAlias 
  *         o:Sum("PRIHOD", { 0, 0, 0 }) 
  *         o:Sum("RASHOD", { 0, 0, 0 }) 
  *         DO WHILE ! Eof() 
  *            o:Sum("COUNT" , 1) 
  *            o:Sum("KOLVO" , (Als)->KOLVO) 
  *            o:Sum("SUMMA" , (Als)->SUMMA) 
  *            If     (Als)->OPER == "PRI" 
  *               o:Sum("PRIHOD", { 1, (Als)->KOL_PRI, (Als)->SUM_PRI }) 
  *            ElseIf (Als)->OPER == "RAS" 
  *               o:Sum("RASHOD", { 1, (Als)->KOL_RAS, (Als)->SUM_RAS }) 
  *            EndIf 
  *            SKIP 
  *        ENDDO 
  *        ? o:Get("COUNT"), o:Get("KOLVO"), o:Get("SUMMA") 
  *        ? hb_valtoexp(o:Get("PRIHOD")) 
  *        ? hb_valtoexp(o:Get("RASHOD")) 
  */ 
 METHOD Sum( Key, xSum ) CLASS TKeyData 
  
    LOCAL sum := ::Get( Key, 0 )    
    
    If     HB_ISNUMERIC( xSum ) 
       If HB_ISNUMERIC( sum ); sum += xSum 
       Else                  ; sum := xSum 
       EndIf 
       ::Put( Key, sum ) 
    ElseIf HB_ISARRAY( xSum ) 
       If HB_ISARRAY(sum) .and. Len(sum) == Len(xSum) 
          AEval(xSum, {|s,i| sum[ i ]:= iif( HB_ISNUMERIC( s ), sum[ i ] + s, s ) } ) 
       Else 
          sum := xSum 
       EndIf 
       ::Put( Key, sum ) 
    EndIf 
  
 RETURN Nil 
  
 /* 
  * Освобождение собственных переменных объекта, устанавливаем в Nil. 
  */ 
 METHOD Destroy() CLASS TKeyData 
  
    LOCAL i, k, o 
    
    If HB_ISHASH( ::aKey ) 
       For i := 1 To Len( ::aKey ) 
           k := hb_HKeyAt( ::aKey, i ) 
           hb_HSet( ::aKey, k, Nil ) 
           hb_HDel( ::aKey, k ) 
       Next 
    EndIf 
    
    If HB_ISOBJECT(::Cargo) .and. ::Cargo:ClassName == ::ClassName 
       o := ::Cargo 
       If HB_ISHASH( o:aKey ) 
          For i := 1 To Len( o:aKey ) 
              k := hb_HKeyAt( o:aKey, i ) 
              hb_HSet( o:aKey, k, Nil ) 
              hb_HDel( o:aKey, k ) 
          Next 
       EndIf 
    EndIf 
    
    ::oObj := ::aKey := ::Cargo := Nil 
  
 RETURN Nil