Отправлено: 19.12.13 18:16. Заголовок: TsBrowse в Минигуи (продолжение)

TsBrows определяется в виде строки ПАРМЕТРОВ объекта и их значений
К примеру

цитата:

DEFINE TBROWSE oBrw2 ; AT 60,450 ; ALIAS cAlias ; OF Form1 ; WIDTH 330 ; HEIGHT 340 ; FONT "Verdana" ; SIZE 9 ; ON DBLCLICK CopyRec(); ON GOTFOCUS fModelo_Hab(2) ; AUTOFILTER ; CELLED EDIT; VALUE nRec; GRID

Здесь я собрал параметры из разных tBrows
Можно или нет и какие парметры заменить
выражением ( и каким) ?
oBrw2:....
oBrw2:....

 Отправлено: 14.04.17 15:16. Заголовок: Andrey Рассчитывай ..

Andrey
Рассчитывай ширины столбцов так , что бы не было виртуального столбца , тогда и красить ни чего не придется.

PS
Или юзай nAdjColumn

 Отправлено: 14.04.17 15:33. Заголовок: Dima пишет: Рассчит..

Dima пишет:

цитата:

Рассчитывай ширины столбцов так , что бы не было виртуального столбца , тогда и красить ни чего не придется.

Есть справочники состоящие из 2 колонок всего.
Так что без виртуального столбца на экране никак не обойтись.

 Отправлено: 14.04.17 16:43. Заголовок: Andrey пишет: Так ..

Andrey пишет:

цитата:

Так что без виртуального

См obrw:hBrush в примерах

 Отправлено: 14.04.17 16:44. Заголовок: Andrey Где то была ..

Andrey
Где то была процедура заливки фантома (строки и столбца) , Has показывал , но с ходу
не найду
Еще можно попробовать поиграть с фантомным столбцом через объект oPhant (это я по быстрому на сырец глянул)

 Отправлено: 14.04.17 20:10. Заголовок: Haz пишет: См obrw:..

Haz пишет:

цитата:

См obrw:hBrush в примерах

Нашёл. Поставил себе - не работает !!!

Делаю у себя 10 колонку:

      ADD COLUMN TO oBrw1 HEADER "Lang"       ; 
       .......... 
          COLOR CLR_BLACK, CLR_WHITE          ; 
        .....       

Потом ставлю для блокировки цвета ещё 11 колонку:

     // для избавления от белого цвета конца таблицы 
     ADD COLUMN TO oBrw1 HEADER ""    ; 
          DATA {|| NIL }               ; 
          SIZE 0                       ; 
          COLOR nBackTable, nBackTable ; 
          NAME ZERO   

Только тогда цвет виртуального столбца становиться в цвет фона таблицы.
Но на экране некрасиво это выглядит, да и курсор туда убегает (становиться невидимым) - юзер теряться будет.....

 Отправлено: 14.04.17 21:28. Заголовок: Andrey пишет: Тольк..

Andrey пишет:

цитата:

Только тогда цвет виртуального столбца становиться в цвет фона таблицы. Но на экране некрасиво это выглядит, да и курсор туда убегает (становиться невидимым) - юзер теряться будет.....

Растягивай первую колонку что бы не было фантомной.

 Отправлено: 14.04.17 23:21. Заголовок: Andrey пишет: Нашёл..

Andrey пишет:

цитата:

Нашёл. Поставил себе -

Тогда до понедельника

 Отправлено: 15.04.17 12:23. Заголовок: Andrey пишет: Толь..

Andrey пишет:

цитата:

Только тогда цвет виртуального столбца становиться в цвет фона таблицы. Но на экране некрасиво это выглядит, да и курсор туда убегает (становиться невидимым) - юзер теряться будет.....

А в исходники посмотреть? Там же буквами написано, что фантомная колонка ВСЕГДА красится в цвет той, которая перед ней.
Другого указания цвета фантому в TS нет. Это было к вопросу почему фантом белый

Теперь как исправить. Так же посмотреть в исходники и увидеть что после назначения цвета фантому по последней колонке выполняется ::bOnDrawLine ( если он определен ) и тогда исправить цвет становится просто - в этом блоке вызываем функцию , которая все лечит
oBrw:bOnDrawLine := {|oBrw| SetPhantomBackcColor(oBrw) }

 
 FUNC SetPhantomBackcColor(oBrw) 
      IF oBrw:oPhant <> Nil 
         oBrw:oPhant:nClrBack :=  RGB( 111, 183, 155 ) // к примеру пусть будет грязно голубой 
      end 
 RETURN NIL 
 

 Отправлено: 15.04.17 13:16. Заголовок: Бонус трек

Ну и напоследок бонус трек
Самое простое и очевидное решение, просто поражающее простотой.
Сделать колонку 11 скрытой

 Отправлено: 15.04.17 13:23. Заголовок: Haz пишет: Сделать ..

Haz пишет:

цитата:

Сделать колонку 11 скрытой

Игорь крась яйца уже

 Отправлено: 15.04.17 13:35. Заголовок: Dima пишет: крась я..

Dima пишет:

цитата:

крась яйца

Все покрашено с утра
И яйца и фантом, хожу с кисточкой и думаю гдеб еще мазнуть

 Отправлено: 15.04.17 13:37. Заголовок: Haz :sm54: ..

Haz

 Отправлено: 15.04.17 23:30. Заголовок: Haz пишет: Самое пр..

Haz пишет:

цитата:

Самое простое и очевидное решение, просто поражающее простотой. Сделать колонку 11 скрытой

Да подумал я об этом, сразу не сделал так как посчитал SIZE 0 будет 0, а не 2-3 пиксела как на экране.
Спасибо за решение !

 Отправлено: 19.04.17 09:17. Заголовок: gfilatov2002 Добави..

gfilatov2002
Добавил, у себя, возмозможность уст. высоту Edit отличную от высоты Cell

 
 CLASS TSBrowse FROM TControl 
 ... 
    DATA   nHeightEdit   AS NUMERIC INIT 0            //   GetBox cell height 
 ... 
 METHOD Edit( uVar, nCell, nKey, nKeyFlags, cPicture, bValid, nClrFore, nClrBack )  CLASS TSBrowse 
 ... 
    IF ::nColSpecHd != 0 
       nRow    := ::nHeightHead + ::nHeightSuper + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := ::GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 1 ) 
       nHeight := ::nHeightSpecHd - If( oCol:l3DLook, 1, -1 ) 
    else 
       nRow    := ::nRowPos - 1 
       nRow    := ( nRow * ::nHeightCell ) + ::nHeightHead + ; 
                  ::nHeightSuper + ::nHeightSpecHd + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := ::GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 0 ) 
       nHeight := ::nHeightCell - If( oCol:l3DLook, 1, -1 )  
       If ::nHeightEdit > 0                           
          nI := nHeight - ::nHeightEdit 
          If nI > 4 
             nHeight := ::nHeightEdit 
             nRow    += int(nI / 2) 
          EndIf 
       EndIf  
    endif 
  
    If oCol:cResName != Nil .or. oCol:lBtnGet   
 ... 
 

Полезно при исп. тсб как аналог списка пар Label+GetBox без линий и с исп. image > 24

 Отправлено: 19.04.17 09:20. Заголовок: SergKis Так ее же м..

SergKis
Так ее же можно установить в bPrevEdit с помощью SetGetAdjustBrw , нет ?

 Отправлено: 19.04.17 09:34. Заголовок: Dima если ты имеешь..

Dima
если ты имеешь ввиду aEditCellAdjust := {0,0,0,0}, то да, так можно управлять, но в моей версии этого нет и ...
тогда предложение снимаю.

 Отправлено: 19.04.17 09:56. Заголовок: SergKis я имел в ви..

SergKis
я имел в виду примерно такой код

 
 obrw3:GetColumn("cod"):bPrevEdit := { |a, b, lLock| SetGetAdjustBrw(b,{2,0,-2,-3}) ............. 
 

 Отправлено: 19.04.17 10:22. Заголовок: Дима, где есть SetG..

Дима, где есть SetGetAdjustBrw(...) ? Просканировал MiniGui, не получил результата.
Потом bPrevEdit исп. для простой ситуации (а если много колонок) ..., слишком сложно.
В целом имея высоту getbox мне хватает того, что у себя сделал. А ширина всегда по ширине cell,
этим манипулирует пользователь, а я - picture

 Отправлено: 19.04.17 10:34. Заголовок: Сергей я тупанул :s..

Сергей я тупанул
Это я свою функцию заюзал
Func SetGetAdjustBrw(o,amas)
o:aEditCellAdjust[1]:=amas[1]
o:aEditCellAdjust[2]:=amas[2]
o:aEditCellAdjust[3]:=amas[3]
o:aEditCellAdjust[4]:=amas[4]
return .t.

Ты был прав насчет aEditCellAdjust

 Отправлено: 19.04.17 10:48. Заголовок: Дима, зачем ты в это..

Дима, зачем ты в это делаешь в bPrevEdit, разве не достаточно простого на весь tsb
nHget := 22
nH := :nHeightCell - nHget
If nH > 4
:aEditCellAdjust[1] := int(nH / 2)
:aEditCellAdjust[4] := nHget
EndIf
для мультистрок будет своя высота пересчитана, а для др. ситуаций сделанного, достаточно

 Отправлено: 19.04.17 10:54. Заголовок: PS :aEditCellAdjust ..

PS
:aEditCellAdjust[4] := -nH

 Отправлено: 19.04.17 11:34. Заголовок: Похоже :aEditCellAdj..

Похоже :aEditCellAdjust - возможность задать отступы в Cell (:aEditCellAdjust := {-2,-1,-1,-2}),
а размеры редактирования это свойства колонки и должны быть в TColumns. Что то такое

 
    DATA nEditWidth   AS NUMERIC   INIT 0                // editing width 
    DATA nEditHeight  AS NUMERIC   INIT 0                // editing height 
 

с вытекающими из этого действиями ...

 Отправлено: 19.04.17 13:08. Заголовок: SergKis пишет: Дима..

SergKis пишет:

цитата:

Дима, зачем ты в это делаешь в bPrevEdit

Кто то подсказал в свое время , так и прижилось.

 Отправлено: 19.04.17 13:51. Заголовок: Dima пишет: Кто то ..

Dima пишет:

цитата:

Кто то подсказал в свое время , так и прижилось.

прижилось с каких-то давних версий , где еще не было корректирующего массива размеров.
В PrevEdit я ровнял окно редактирования , т.к. она раньше категорически не хотело выравниваться под ячейку.
Потом проблема была решена и с тех пор не тспользую

 Отправлено: 19.04.17 13:59. Заголовок: Haz У меня проблема..

Haz
У меня проблема была другого плана.
После выхода из режима редактирования ячейки , "сетка" по периметру ячейки исчезала , поэтому координаты GET пришлось
изменить что бы он не налазил на края ячейки.

 Отправлено: 19.04.17 14:09. Заголовок: Dima пишет координат..

Dima пишет

цитата:

координаты GET пришлось изменить что бы он не налазил на края ячейки.

Так это Григорий подправлял и сейчас все нормуль

 Отправлено: 19.04.17 14:15. Заголовок: SergKis пишет: Так ..

SergKis пишет:

цитата:

Так это Григорий подправлял и сейчас все нормуль

У меня версия еще от июня 2016 года , он правил позже ?

 Отправлено: 19.04.17 14:20. Заголовок: Дима, трудно сказать..

Дима, трудно сказать, надо искать (там было GoLeft() и что то еще)
Но уже давно, переносил изм. к себе помню ...

 Отправлено: 19.04.17 14:24. Заголовок: SergKis пишет: над..

SergKis пишет:

цитата:

надо искать (там было GoLeft() и что то еще)

Пороюсь.
А GoLeft() был в 2008 году

 Отправлено: 19.04.17 19:06. Заголовок: Dima пишет А GoLeft(..

Dima пишет

цитата:

А GoLeft() был в 2008 году

Позже было и GoRight и GoDown
Нашел http://clipper.borda.ru/?1-1-40-00000454-000-180-0
пост N 848 от 06.11.15 21:33.
gfilatov2002 пишет

цитата:

Вроде удалось поправить прорисовку разделительной линии в методах GoRight и GoDown

С тех пор прорисовка линий после edit нормальная.

 Отправлено: 19.04.17 21:39. Заголовок: SergKis пишет: Позж..

SergKis пишет:

цитата:

Позже было и GoRight и GoDown

Да я чисто шарил по C:\MiniGUI\Doc\ChangeLog.txt а там только 8 год всплыл , да и фиг с ним ))


SergKis пишет:

цитата:

пост N 848 от 06.11.15 21:33.

И да , версия Минигуи у меня была уже старше и точно не 15 год ))

SergKis пишет:

цитата:

С тех пор прорисовка линий после edit нормальная.

Не понятно зачем я тогда правил все это дело на свежем Минигуи 2016 года
Но глючило 100 %

 Отправлено: 19.04.17 22:10. Заголовок: Dima пишет: Но глю..

Dima пишет:

цитата:

Но глючило 100 %

И сейчас глючит. Без белых засветов вокруг закрытого гет обьекта, но линии гряды трет

 Отправлено: 20.04.17 08:33. Заголовок: Haz пишет но линии г..

Haz пишет

цитата:

но линии гряды трет

В какой ситуации ? Погонял примеры - не трет.
У меня версия, тоже не трет.

 Отправлено: 20.04.17 09:02. Заголовок: SergKis пишет: В к..

SergKis пишет:

цитата:

В какой ситуации ?

В ситуации обычного гетбокса. Сейчас точно сказать не могу т. к не на работе.
Стандартная библиотека, прошлая или позапрошлая. Без выравнивани границ гет обьекта.
После редактирования затирается одна из горизонтальных границ.
Из дополнительных условий- двойной курсор с градиентом и браш на бровсе в цвет фона строк.
Завтра погоняю, напишу подробнее. Но в принципе не напрягает, белых засветов нет и при желании легко исправляется выравниванием границ гет поля.

 Отправлено: 20.04.17 09:08. Заголовок: Haz пишет Но в принц..

Haz пишет

цитата:

Но в принципе не напрягает

Только не хотелось, что бы клиент носом ткнул в эту ситуёвину

 Отправлено: 20.04.17 09:33. Заголовок: SergKis пишет: Толь..

SergKis пишет:

цитата:

Только не хотелось, что бы клиент носом

Перед сдачей клиенту всех мелких тараканов обычно принято давить.
Но иногда и не до них бывает т. к есть и не мелкие)
К примеру иногда наблюдаю традиционное залипание нижней строки.
Понятно что исправимо, и не на всех рабочих местах у клиента проявляется.
Такие вещи полирую уже при тестовой эксплуатации, т. к. с вероятностью больше 50%
будут изменения в интерфейсе когда люди начнут работать.

 Отправлено: 20.04.17 10:24. Заголовок: Haz пишет: Но иногд..

Haz пишет:

цитата:

Но иногда и не до них бывает т. к есть и не мелкие

Подтверждаю
Вот набрел на ошибку, возникающую при использовании SPINNER внутри GetBox поля (при использовании метода oBrw:SetSpinner()).
Проблема заключается в том, что при нажатии на ползунки этого Spinnerа начинает убегать указатель с текущей записи

Haz
Может, поможите побороть эту бяку

 Отправлено: 20.04.17 12:06. Заголовок: gfilatov2002 пишет: ..

gfilatov2002 пишет:

цитата:

Может, поможите побороть эту бяку

Григорий завтра посмотрю. Сейчас сижу болею дома

 Отправлено: 20.04.17 14:14. Заголовок: Haz пишет: Сейчас с..

Haz пишет:

цитата:

Сейчас сижу болею дома

Выздоравливай !!!

 Отправлено: 21.04.17 14:34. Заголовок: gfilatov2002 пишет: ..

gfilatov2002 пишет:

цитата:

Проблема заключается в том, что при нажатии на ползунки этого Spinnerа начинает убегать указатель с текущей записи

Это следствие , причина в том, что бровс получает команду сдвинуть этот указатель ползунками или кнопками не важно.
Если в METHOD Command( nWParam, nLParam ) CLASS TControl закоментировать убиение фокуса

 
          case nNotifyCode == EN_KILLFOCUS  
            ::LostFocus() 
 

сразу видно как управляется бровс , а убиение фокуса просто делает это невидимым
Пол дня проковырялся - безрезультатно. Не могу понять кто и где эту команду бровсу посылает
Позже еще продолжу.

 Отправлено: 21.04.17 14:43. Заголовок: Поправлюсь не закоме..

Поправлюсь
не закоментить KillFoсus а нооборот показать добавив ниже
case nNotifyCode == EN_SETFOCUS
::SetFocus()

Пока все что выяснил - При нажатии какой-либо стрелки спина он посылает родительскому окну сообщение WM_VSCROLL. а родительским заявлено окно бровса и это заставляет бровс бегать по записям. Можно попробовать использовать флаг ::lDontChange , который учитывать при обработке событий в TSBrowse:HandleEvent() , можно попробовать в событиях просто фильтрануть lParam в котором будет передан дескриптор спина ( он определяется как ::hWndChild в METHOD TBtnBox:New() но в нем и хоронится и никуда не передается )
На скорую руку попробовал , частично помогает , но при выходе из режима редактирования чтото уперто сдвигает указатель на ::GoTop()

 Отправлено: 25.04.17 15:04. Заголовок: Григорий По поводу..

Григорий
По поводу спиннера и дергания записей
это частично решает проблему ( просто фильтруем в бровсе сообщения от спеннера)

 
 * ============================================================================ 
 * METHOD TSBrowse:HandleEvent() Version 9.0 Nov/30/2009 
 * ============================================================================ 
  
 METHOD HandleEvent( nMsg, nWParam, nLParam ) CLASS TSBrowse 
  
    #ifdef __HARBOUR__ 
    ElseIf nMsg == WM_KEYUP 
       Return ::KeyUp( nWParam, nLParam ) 
    ElseIf nMsg == WM_VSCROLL 
       If ::lDontchange 
          Return Nil 
       EndIf 
       if nLParam == 0 
 	 Return ::VScroll( Loword( nWParam ), HiWord( nWParam ) ) 
       endif 
    #EndIf 
  
 

т.е. исключаем из обработки бровсом сооющения от спенера, но пока частично решает
при первом клике в колонке со спином и выходе из редактирования запись улетает на GoTop() потом сколько не редактируй и не кликай по спину - все ОК
скорее всего после первого редактирования выставляется какой нить внутренний флаг и потом его обрабатывает правильно
что переводит запись в GoTop - так и не нашел, тк не смог поймать пока это единственное первое событие

 Отправлено: 25.04.17 15:29. Заголовок: Haz Благодарю за ре..

Haz
Благодарю за реальную помощь в этом вопросе!

Haz пишет:

цитата:

исключаем из обработки бровсом сообщения от спайнера

Принимается

 Отправлено: 28.04.17 12:14. Заголовок: gfilatov2002 METHO..

gfilatov2002

 
 METHOD LDblClick( nRowPix, nColPix, nKeyFlags ) CLASS TSBrowse 
 ... 
    If ( nClickRow == ::nRowPos .and. nClickRow > 0 ) .or. ( nClickRow == ::nRowPos .and. ! ::lDrawHeaders ) 
  
       If ::lCellBrw .and. ::IsEditable( nCol ) 
  
          ::nColSpecHd := 0 
          If ValType( Eval( ::aColumns[ nCol ]:bData ) ) == "L" .and. ; 
             ::aColumns[ nCol ]:lCheckBox  // virtual checkbox 
             ::PostMsg( WM_CHAR, VK_SPACE, 0 )  
          ElseIf ::aColumns[ nCol ]:oEdit != Nil 
             ::PostMsg( WM_KEYDOWN, VK_RETURN, 0 ) 
          ElseIf ::bLDblClick != Nil 
             Eval( ::bLDblClick, uPar1, uPar2, nKeyFlags, Self )  
          Else 
             ::PostMsg( WM_KEYDOWN, VK_RETURN, 0 ) 
          EndIf 
 ... 
 

по мне, так правильнее будет.
bLDblClick задан, но не срабатывает в этой ситуации (так было)

 Отправлено: 28.04.17 13:02. Заголовок: SergKis пишет: bLDb..

SergKis пишет:

цитата:

bLDblClick задан, но не срабатывает в этой ситуации

Понимаю Вашу логику, но у автора библиотеки этот кодовый блок используется только для НЕ редактируемых TSBrowse
Это явно следует из кода метода LDblClick

 Отправлено: 28.04.17 13:40. Заголовок: gfilatov2002 пишет ..

gfilatov2002 пишет

цитата:

но у автора библиотеки этот кодовый блок используется только для НЕ редактируемых

Мне кажется, у автора не до конца продумано.
При наличии :nFireKey посылать надо oBr:PostMsg( WM_KEYDOWN, VK_F4, 0 ) а не VK_RETURN
К примеру edit включаем VK_F4 ( :nFireKey := VK_F4 ), а VK_RTUEN назначить надо выбор строки.
При работе со справочниками это сплошь и рядом - на окне где ТОЛЬКО справочник VK_RETURN может включать edit,
а в вызове справочника (GrtBox) для выбора из списка (все операции по ведению спр. присутствуют) - VK_ENTER\bDblClick - это выбор строки для занесения данных в документ. В сегодняшней версии это затруднительно сделать простым способом

 Отправлено: 28.04.17 13:41. Заголовок: PS правильно посылат..

PS
правильно посылать надо oBr:PostMsg( WM_KEYDOWN, oBr:nFireKey, 0 )

 Отправлено: 28.04.17 14:18. Заголовок: SergKis пишет: При ..

SergKis пишет:

цитата:

При работе со справочниками это сплошь и рядом

Тогда принимается - Вам виднее
Благодарю за дополнительное разъяснение

 Отправлено: 07.05.17 18:00. Заголовок: Что то перестал отоб..

Что то перестал отображаться чекбокс в Tsbrowse.
Версия MiniGUI Extended Edition 16.11 - работает отлично !
Версия MiniGUI Extended Edition 17.04 - не отображает....

Вот скрин экрана:


Мышкой по чекбоксу кликаешь - нет отображения...

Что там нужно доп. сделать у себя в коде чтобы отображалась ?

В коде создаю колонку так:

 // создать 3-ю колонку  
      ADD COLUMN TO oBrw2 HEADER "Печать"+CRLF+"в таблице" ; 
          DATA FieldWBlock( "VIEW", Select() ) ; 
          ...... 
          oBrw2:aColumns[3]:bPrevEdit := {|| HeadCheckField(), FALSE }  // проверка до ввода

В функции HeadCheckField() в конце обработки ставлю:

   oBrw1:Reset()  
    oBrw1:Refresh(.T.) 
    oBrw2:Refresh(.T.) 
    RETURN NIL

Больше никаких функций не использую...

 Отправлено: 07.05.17 18:05. Заголовок: Andrey пишет: Верси..

Andrey пишет:

цитата:

Версия MiniGUI Extended Edition 17.04 - не отображает....

Чеканул пример C:\MiniGUI\SAMPLES\Advanced\Tsb_array_2\
Все кажет норм !

 Отправлено: 07.05.17 18:19. Заголовок: Dima пишет: Чеканул..

Dima пишет:

цитата:

Чеканул пример C:\MiniGUI\SAMPLES\Advanced\Tsb_array_2\ Все кажет норм !

Там по другому создаётся бровс.
У меня конкретно в версии 16.11 работает, а в 17.04 - не отображает чекбокс.
Что там сделали в исходниках я не знаю, но правка была же, если перестало работать !
По пробелу или по клику мышке ПЕРЕСТАЛ работать чекбокс после версии 16.11 !
Может быть из-за того что использую сразу ДВА бровса ?

Как можно перерисовать конкретно 3 колонку после ввода ?
Поможет ли это ?
Попробовал поставить -
oBrw2:aColumns[3]:bPostEdit := {|| oBrw2:DrawSelect(), FALSE } // проверка после ввода
НЕ ПОМОГАЕТ !!!

 Отправлено: 07.05.17 18:45. Заголовок: Andrey пишет: По пр..

Andrey пишет:

цитата:

По пробелу или по клику мышке ПЕРЕСТАЛ работать чекбокс после версии 16.11 !

Долго же ты ждал пока понял что не пашет :)

 Отправлено: 07.05.17 18:56. Заголовок: Dima пишет: Долго ж..

Dima пишет:

цитата:

Долго же ты ждал пока понял что не пашет :)

Да это не главное меню в программе. Редко кто пользуется. Вот и обнаружил с таким промежутком времени.
Попробую проверить другие версии...

 Отправлено: 07.05.17 19:14. Заголовок: Проверил. В версии 1..

Проверил. В версии 17.02 работает, а в 17.03 - уже не отображает чекбокс.
Т.е. - по пробелу или по клику мышке ПЕРЕСТАЛ работать чекбокс после версии 17.02 !
Что нужно мне добавить в свой код чтобы по клику мышки стал отображаться чекбокс ?
Использую сразу ДВА бровса на одном окне.

 Отправлено: 07.05.17 19:46. Заголовок: Andrey пишет: Т.е. ..

Andrey пишет:

цитата:

Т.е. - по пробелу или по клику мышке ПЕРЕСТАЛ работать чекбокс после версии 17.02

Так это не чекбокс по ходу а просто BMP как и на другом бровсе в твоем скрине

 Отправлено: 07.05.17 20:02. Заголовок: Andrey пишет: oBrw2..

Andrey пишет:

цитата:

oBrw2:aColumns[3]:bPrevEdit := {|| HeadCheckField(), FALSE } // проверка до ввода

Попробуй изменить это кодовый блок таким образом

цитата:

oBrw2:aColumns[3]:bPrevEdit := {|| HeadCheckField(), TRUE }

 Отправлено: 07.05.17 21:13. Заголовок: gfilatov2002 пишет: ..

gfilatov2002 пишет:

цитата:

Попробуй изменить это кодовый блок таким образом

Так заработало ! Спасибо большое !

Хотя если только ОДИН бровс, то работает и со старым синтаксисом.
Смотри пример Tsb_composite_(1.2).7z который я высылал...
Там в 3х местах используется:

         oBrw1:aColumns[3]:bPrevEdit := {|| FieldCheckBoxEdit(), FALSE }   
          oBrw1:aColumns[4]:bPrevEdit := {|| FieldCheckBoxEdit(), FALSE }   
          oBrw1:aColumns[5]:bPrevEdit := {|| FieldCheckBoxEdit(), FALSE }  

 Отправлено: 07.05.17 21:45. Заголовок: Ха, в версии 17.04 п..

Ха, в версии 17.03 и выше перестал работать пример Tsb_composite_(1.2).7z - там где выбор флагов производиться...
Один раз выбрать можно, на втором - программа НАГЛУХО ВИСНЕТ !!!
Вот сам проект - https://cloud.mail.ru/public/2SXc/UtNfso4gf
Что-то в коде нужно добавить ?

 Отправлено: 09.05.17 19:56. Заголовок: Опять непонятка в ра..

Опять непонятка в работе функций....
Григорий, проект у тебя есть - Send2Mail.hbp
Там вызов функции в модуле Tsb_send.prg строка:

    oBrw:Excel2(cFile, lActivate, NIL, "_"+Space(70)+Form_0.Title, lSave )

Версия 17.02 - работает, а в других уже НЕТ !!!
Что там докрутить/исправить нужно, чтобы заработало ?

 Отправлено: 09.05.17 21:39. Заголовок: Разобрался сам... Ок..

Разобрался сам... Оказывается если нет такого пути к файлу, то Ексель и не создаёт и не открывает его !

Григорий, там можно в исходниках поставить проверку на создания по пути файла ?

 Отправлено: 09.05.17 21:44. Заголовок: Andrey пишет: Разоб..

Andrey пишет:

цитата:

Разобрался сам... Оказывается если нет такого пути к файлу, то Ексель и не создаёт и не открывает его

Про это уже писалось и не раз !
Бывает :)

 Отправлено: 10.05.17 13:57. Заголовок: Haz Редактирование ..

Haz
Редактирование Ключевого поля в TsBrows. Я писал, что после выхода из редактирования курсор не поднимается на нужную строку
Игорь, как-то выкладывал пример редактирования ключевого поля, но в примере были особенности- вторая форма для редактирования,
программное построение Бровса и т.д.
Посмотрите пример построенный в основном в Дизайнере - click here,
может удастся заставить курсор подниматься ?
И еще , при входе в редактирование сетка пропадает.

 Отправлено: 10.05.17 14:08. Заголовок: Vlad04 пишет: И еще..

Vlad04 пишет:

цитата:

И еще , при входе в редактирование сетка пропадает.

Почитай начиная с поста 6376 этой темы

 Отправлено: 10.05.17 14:25. Заголовок: Dima Все темы читаю..

Dima
Все темы читаю. В примере кода практически нет, все должно работать по- умолчанию ( или почти всё)
без танцев с бубном.

 Отправлено: 10.05.17 16:11. Заголовок: Vlad04 пишет В прим..

Vlad04 пишет

цитата:

В примере кода практически нет, все должно работать по- умолчанию ( или почти всё) без танцев с бубном.

Танцы вы сами придумали себе кодом:
oBrw_1:aColumns[1]:bPrevEdit := { || oBrw_1:Upstable() , oBrw_1:Refresh(.T.) , oBrw_1:ResetVScroll() , .t. }
запустив перед edit кучу процедур по прорисовке тсб, при этом совершенно забыв про очередь сообщений, по которой и происходят действия прорисовки.

цитата:

Все темы читаю

но чуть чуть по диагонали. В примере Tsb_addrecord_3 ситуация с обработкой очереди для прорисовки показана была:

 
  STATIC FUNC Add_Rec( oBrw )  
 ... 
   If ! Empty(aResult)  
      dbSelectArea(cAls)  
      dbAppend()  
      If ! NetErr() .and. RLock()  
         nRec := RecNo()  
         REPL KODS with aResult[1], ;  
              NAME with aResult[2]  
         If oBrw:nLen == oBrw:nRowCount()  
            oBrw:oHScroll:SetRange(0,0)  
         EndIf  
         oBrw:GotoRec(nRec)  
         nCol := oBrw:nColumn("NAME")  
         If nCol != oBrw:nCell  
            oBrw:nCell := nCol  
            oBrw:DrawSelect()  
         EndIf  
         oBrw:lChanged := .T.  
         oBrw:PostEdit(aResult[2], nCol, Nil)  
         DO EVENTS  
         oBrw:PostMsg(WM_KEYDOWN, VK_F4, 0)  
      EndIf   
   EndIf  
 ... 
 

т.е. если убрать DO EVENTS много разного увидите

 Отправлено: 10.05.17 16:34. Заголовок: Dima пишет: может у..

Vlad04 пишет:

цитата:

может удастся заставить курсор подниматься ? И еще , при входе в редактирование сетка пропадает.

Нет ничего проще

1) в Form_0.fmg удалить это ON INIT Init_Form_0() и соответственно саму функцию в програмном модуле tsb.prg
2) в tsb.prg сделать так

LOAD WINDOW Form_0

oBrw_1:SetIndexCols( 1 )
oBrw_1:SetOrder( 1 )

Form_0.Center
Form_0.Activate

PS Сергей прав по поводу танцев, но уверен со временем все уляжется в голове и танцы будут не нужны

 Отправлено: 10.05.17 17:45. Заголовок: SergKis примере Tsb..

SergKis

цитата:

примере Tsb_addrecord_3

Конечно,смотрел и этот пример. Многое не понял. Для такого простого результата - на форме одна таблица с 4-мя кнопками, код
очень сложный. А если на форме несколько таблиц, а в программе десяток форм....

Haz

цитата:

oBrw_1:SetIndexCols( 1 ) oBrw_1:SetOrder( 1 )

просто и работает

 Отправлено: 10.05.17 17:57. Заголовок: Курсор поднимается ,..

Курсор поднимается , но на одно строку промахивается.
При движении вниз так же ошибка на одну строку.

 Отправлено: 10.05.17 18:08. Заголовок: Vlad04 пишет А если ..

Vlad04 пишет

цитата:

А если на форме несколько таблиц

Код в примере практически не изменится для всех таблиц, используемых на окне(ах). Изменятся параметры задания колонок, валидности и др. не стандартных действий. И в примере есть ввод, едит и удаление (все сводится к примерно tsb_array_2 для таблиц). В вашем нет (якобы кода) ничего,кроме едит, но будет куча fmg для справочников в чилд\модал окнах, привязанных к железным алиасам. Не уверен, что это проще.

цитата:

Многое не понял

Так лучше спросить, чем оставаться в не понятках.

цитата:

просто и работает

Так это работало со времен примера Tsb_addrecord_2

 
        oBrw:SetIndexCols( oBrw:nColumn("ID"),  ; 
                           oBrw:nColumn("INFO") ) 
        oBrw:SetOrder( oBrw:nColumn("ID") ) 
 

 Отправлено: 10.05.17 18:46. Заголовок: Vlad04 пишет но на о..

Vlad04 пишет

цитата:

но на одно строку промахивается.

После редактирования у колонки есть свойство, куда деть курсор после, по умолчанию переместиться дальше ...
Потому такой результат. Поставьте

 
    oBrw_1:aColumns[1]:nAlign      := DT_LEFT  
    oBrw_1:aColumns[ 1 ]:nEditMove := DT_DONT_MOVE 
     
    oBrw_1:SetIndexCols(1) 
    oBrw_1:SetOrder(1) 
    oBrw_1:SetFocus() 
  
    Form_0.Center 
    Form_0.Activate 
 

 Отправлено: 10.05.17 18:53. Заголовок: SergKis куча fmg дл..

SergKis

цитата:

куча fmg для справочников в чилд\модал окнах, привязанных к железным алиасам. Не уверен, что это проще.

Это и хорошо , что есть варианты.У меня есть одна универсальная форма для типовых справочников и отдельные формы для остальных случаев.

цитата:

Так это работало со времен примера Tsb_addrecord_2

Не понял сразу, в Делфи для Бровса( там это грид) несколько другая идеология - отображать данные, а не управлять ими.Да и консольный Харбор
ведет себя по-другому.

 Отправлено: 10.05.17 18:58. Заголовок: Уф!! Теперь все норм..

Уф!!
Теперь все нормально ! Спасибо всем !

 Отправлено: 10.05.17 19:07. Заголовок: Vlad04 пишет У меня ..

Vlad04 пишет

цитата:

У меня есть одна универсальная форма для типовых справочников и отдельные формы для остальных случаев.

т.е. из меню главного окна у вас нельзя вызвать несколько окон справочников одновременно, только по очереди, т.к. в fmg прописан конкретный алиас в одной унив. форме ?

 Отправлено: 10.05.17 19:55. Заголовок: SergKis пишет: т.е...

SergKis пишет:

цитата:

т.е. из меню главного окна у вас нельзя вызвать несколько окон справочников одновременно

А зачем юзеру редактировать/смотреть сразу несколько справочников ?
Я тоже сделал одно модальное окно для справочника и туда передаю параметры из ини-файла (алиасы, поля базы и т.д.) для различных справочников.
Иначе юзера начинают путаться с большим количеством справочников на экране.

 Отправлено: 10.05.17 20:42. Заголовок: Andrey пишет А зачем..

Andrey пишет

цитата:

А зачем юзеру редактировать/смотреть сразу несколько справочников ?

Загнать в рамки дос пользователя - это вариант.
А при работе с док. и спр. номенклатуры, разве не может возникнуть вопрос (по тел., от др. службы) по клиентскому спр., по автотранспорту (свой\чужой), по адресам погрузки\разгрузки, по ценнику клиента ...Что бросать (выходить) из того с чем работал или откладывать ответы на потом ...

цитата:

Иначе юзера начинают путаться с большим количеством справочников на экране

Так это твое дело организация, что бы не путался, не дублировался, не используемый убирался.
Ведь excel с sheetами не запрещают одновременно работать (типа можно но только последовательно). А ты выходит запрещаешь. Не демократично как то.

 Отправлено: 10.05.17 20:54. Заголовок: SergKis пишет: Не д..

SergKis пишет:

цитата:

Не демократично как то.

Не... с юзерами демократию разводить не надо ! Сказали бурундук птичка и никаких зверьков и все !

С другой стороны, действительно можно дать возможность юзеру вернуться к отложенному справочнику.

Интересно а как в 1С это реализовано или в других системах ?
Но это наверное уже для другой ветки обсуждения, а не здесь.

 Отправлено: 10.05.17 21:14. Заголовок: Andrey пишет: Интер..

Andrey пишет:

цитата:

Интересно а как в 1С это реализовано или в других системах ?

Демократично)

 Отправлено: 11.05.17 08:13. Заголовок: SergKis у главного ..

SergKis

цитата:

у главного окна у вас нельзя вызвать несколько окон справочников одновременно

Можно, форма универсальная для простых справочников, типа - код, наименование и т.д. В такой Форме алиасы , поля не прописаны и у меня считываются из файла
при открытии формы.Эта форма описана полностью в виде кода, т.е. без дизайнера ( в нем в этом случае точно нет смысла) .

 Отправлено: 14.05.17 22:05. Заголовок: Есть мой тестировочн..

Есть мой тестировочный проект. Раньше работал, сейчас нет. С какой версии перестал работать, даже не знаю.
Сейчас вешается ВЕСЬ проект вот с таким сообщением:


Вот сам проект - https://cloud.mail.ru/public/2SXc/UtNfso4gf

Виснет - там где выбор флагов производиться...
Один раз выбрать можно, на втором - программа НАГЛУХО ВИСНЕТ !!!
Там даже второй выбор не нужно производить.
Первый раз выбираем меню с флагами, потом мышкой кликаем на другой колонке (или стрелкой вверх/вниз) и тоже программа НАГЛУХО виснет !!

Методом отладки определил, что перестают работать вот эти функции ПОСЛЕ выбора из модуля Form_Lang.prg:

_SetMenuItemBitmap ( "MYTABLERECNOMARK" , cForm , "CheckF28" )	 
 _SetMenuItemBitmap ( "MYTABLERECNOPRINT", cForm , "CheckF28" )	 
 _SetMenuItemBitmap ( "MYTABLERECNOSAVE" , cForm , "CheckF28" )	 
 _SetMenuItemBitmap ( "MYTABLERECNOMAIL" , cForm , "CheckF28" )	

Модуль demo.prg - строка 534

Помогите пожалуйста разобраться....

 Отправлено: 15.05.17 09:28. Заголовок: Выбор правой мышкой ..

Выбор правой мышкой из контекстного меню ?

Все работает !

 Отправлено: 15.05.17 11:24. Заголовок: Vlad04 пишет: Выбор..

Vlad04 пишет:

цитата:

Выбор правой мышкой из контекстного меню ?

НЕТ !
Vlad04 пишет:

цитата:

Все работает !

Виснет - там где выбор флагов производиться...
Один раз выбрать можно, на втором - программа НАГЛУХО ВИСНЕТ !!!
Там даже второй выбор не нужно производить.
Первый раз выбираем меню с флагами, потом мышкой кликаем на другой колонке (или стрелкой вверх/вниз) и тоже программа НАГЛУХО виснет !!

 Отправлено: 23.05.17 19:32. Заголовок: Привет всем ! Забыл ..

Привет всем !
Забыл как сделать чтобы после выбора из tsbrowse оставалась серая линия на выбранной строке таблицы.
Подскажите пожалуйста ?

 Отправлено: 24.05.17 09:25. Заголовок: Andrey пишет Забыл к..

Andrey пишет

цитата:

Забыл как сделать чтобы после выбора из tsbrowse оставалась серая линия на выбранной строке таблицы.

См. Tsb_addrecord_3
Del_Rec(...)
:lNoGrayBar

 Отправлено: 25.05.17 19:21. Заголовок: Надоело везде писать..

Надоело везде писать (как бы лишнее, по мне)
:bUserKeys := {|nKy,nFl,oBr| OnKeyDown(nKy, nFl, oBr) }
и
STATIC FUNC OnKeyDown( nKey, nFlg, oBrw ) // обработка KeyDown
...
IF nKey == VK_RETURN
...
ELSEIF nKey == VK_F2
...
ENDIF

RETURN uRet

Немного добавил в TsBrowse

 
 CLASS TSBrowse FROM TControl 
 ... 
    DATA   aUserKeys     INIT hb_Hash()                
    DATA   lUserKeys     INIT .F.                      
 ... 
  METHOD UserKeys( nKey, bKey, lCtrl, lShift )  
 ... 
 ENDCLASS 
  
 METHOD UserKeys( nKey, bKey, lCtrl, lShift )                     CLASS TSBrowse   
    Local cKey := 'other', uVal 
  
    If HB_ISBLOCK(bKey)                               // установить блок на ключ в hash 
       If ! empty(nKey) 
          If HB_ISNUMERIC(nKey) 
             cKey := hb_ntos(nKey) 
             cKey += iif( empty(lCtrl ), '', '#' ) 
             cKey += iif( empty(lShift), '', '^' )    
          ElseIf HB_ISCHAR(nKey) 
             cKey := nKey 
          EndIf 
       EndIf 
       hb_HSet( ::aUserKeys, cKey, bKey ) 
       ::lUserKeys := len(::aUserKeys) > 0 
    Else                                              // выполнить блок по ключу из hash 
       If HB_ISNUMERIC(nKey) 
          cKey := hb_ntos(nKey) 
       ElseIf HB_ISCHAR(nKey) 
          cKey := nKey 
       EndIf 
       If ::lUserKeys                                 // есть уст. блоки кода 
          uVal := hb_HGetDef( ::aUserKeys, cKey, NIL ) 
          If HB_ISBLOCK(uVal) 
             cKey := Eval( uVal, Self, nKey, cKey, bKey, lCtrl, lChift ) 
          EndIf 
       EndIf          
    EndIf 
  
 RETURN cKey 
  
 METHOD KeyDown( nKey, nFlags )                                         CLASS TSBrowse 
 ... 
    ::lNoPaint := .F. 
    ::oWnd:nLastKey := ::nLastKey := ::nUserKey := nKey 
  
    If ::lUserKeys                                
       uTemp := hb_ntos(nKey) 
       uTemp += iif( _GetKeyState( VK_CONTROL ), "#", "" ) 
       uTemp += iif( _GetKeyState( VK_SHIFT   ), "^", "" ) 
       uVal := hb_HGetDef( ::aUserKeys, uTemp, NIL ) 
       If ! HB_ISBLOCK(uVal) 
          uTemp := 'other' 
          uVal  := hb_HGetDef( ::aUserKeys, uTemp, NIL ) 
       Endif 
       If HB_ISBLOCK(uVal) 
          uReturn := Eval( uVal, Self, nKey, uTemp ) 
          If uTemp == 'other' .and. ! HB_ISLOGICAL(uReturn) 
             uReturn := .T. 
          EndIf 
          If uReturn == Nil .or. ( HB_ISLOGICAL(uReturn) .and. ! uReturn ) 
             ::nLastKey := 255 
             Return 0 
          EndIf 
          uReturn := NIL 
       EndIf 
       uTemp := uVal := NIL 
    EndIf                         
  
    If ::bUserKeys != Nil 
 ... 
  
 теперь в проге можно писать так 
  
        :nFireKey     := VK_F4                       // default Edit 
  
    If lRec_Select                                   // режим выбор записи 
        :bLDblClick   := {|uP1,uP2,nFl,oBr| Get_Rec(oBr, uP1, uP2, nFl) } 
        :UserKeys(VK_RETURN, {|oBr        | Get_Rec(oBr) })  
    Else                                             // режим Edit записи 
        :bLDblClick   := {|uP1,uP2,nFl,oBr| uP1 := uP2 := nFl := Nil, ; 
                                       oBr:PostMsg( WM_KEYDOWN, oBr:nFireKey, 0 ) } 
        :UserKeys(VK_RETURN, {|oBr        | oBr:PostMsg( WM_KEYDOWN, oBr:nFireKey, 0 ) })  
    EndIf 
  
        :UserKeys(VK_F2    , {|oBr,nKy,cKy| Add_Rec(oBr, nKy, cKy) })  
        :UserKeys(VK_F3    , {|oBr,nKy,cKy| Del_Rec(oBr, nKy, cKy) })  
        :UserKeys(VK_F3    , {|oBr,nKy,cKy| MsgBox(cKy, 'Ctrl  + F3') }, .T.)  
        :UserKeys(VK_F3    , {|oBr,nKy,cKy| MsgBox(cKy, 'Shift + F3') },    , .T.)  
        :UserKeys(VK_F3    , {|oBr,nKy,cKy| MsgBox(cKy, 'C + S + F3') }, .T., .T.)  
 //     :UserKeys(         , {|oBr,nKy,cKy| _LogFile(.T.,cKy, 'other', nKy ) })  
 //                   это обработка др. нажатий, уст. на ключ 'other' default 
  
 Если уст. блок кода возвращает Nil или .F. Method KeyDown завершается (все выполнено), 
 при возврате .T. Method KeyDown работает дальше. 
 Может будет полезно, a c :bUserKeys осталось, как раньше 
 

 Отправлено: 26.05.17 08:27. Заголовок: Поясню назначение ко..

Поясню назначение кода
Else // выполнить блок по ключу из hash
...
Установив на тсб
:UserKeys(1.1, {|o|...})
:UserKeys(1.2, {|o|...})
:UserKeys('rpt1', {|o|...})
:UserKeys('rpt2', {|o|...})
...
на кнопках, пунктах, меню и т.д. ( для этого тсб) можно вызывать
oBrw1:UserKeys(1.1, Param1, Param2, Param3)
oBrw1:UserKeys('rpt2', Param1, Param2, Param3)
...
если несколько тсб на окне, то для каждого делаем такие манипуляции

 Отправлено: 26.05.17 11:03. Заголовок: SergKis пишет: Може..

SergKis пишет:

цитата:

Может будет полезно, a c :bUserKeys осталось, как раньше

Благодарю за Ваше предложение и примеры использования этого расширения!
Очень интересное дополнение, которое будет доступно, если в коде библиотеки будет определена константа
// #define __EXT_USERKEYS__

 Отправлено: 28.05.17 12:20. Заголовок: gfilatov2002 пишет ..

gfilatov2002 пишет

цитата:

будет доступно, если в коде библиотеки будет определена константа // #define __EXT_USERKEYS__

А смысл пересобирать либу ?
Изменения минимальны, старые алгоритмы не затронуты.
Я забыл, когда последний раз пересобирал либу, пользуюсь (для примеров и проб) родной сборкой.
Думается так многие делают.

 Отправлено: 28.05.17 15:00. Заголовок: SergKis пишет: Изме..

SergKis пишет:

цитата:

Изменения минимальны, старые алгоритмы не затронуты.

Все правильно, но, вероятно, потребуется определить

цитата:

#ifndef __XHARBOUR__ #define __EXT_USERKEYS__ #endif

поскольку, например, функция hb_HGetDef() недоступна в xHarbour

 Отправлено: 28.05.17 18:48. Заголовок: gfilatov2002 Пример..

gfilatov2002
Пример для Harbour (на моей lib):

и надо подправить (ошибочка)

 
 METHOD UserKeys( nKey, bKey, lCtrl, lShift )                     CLASS TSBrowse  
 ... 
        If ::lUserKeys                                 // есть уст. блоки кода  
           uVal := hb_HGetDef( ::aUserKeys, cKey, NIL )  
           If HB_ISBLOCK(uVal)  
              cKey := Eval( uVal, Self, nKey, cKey, bKey, lCtrl, lShift )  
           EndIf  
        EndIf 
 

 Отправлено: 28.05.17 18:53. Заголовок: PS Забыл в примере в..

PS
Забыл в примере вывести в StatusBar сообщение о наличии меню на правую кнопку мыши (на тсб)

 Отправлено: 28.05.17 19:08. Заголовок: PS в моей lib не раб..

PS
в моей lib не работает (надо исп. вариант без DEFINE ...)
DEFINE SPLITBOX HANDLE hSplit
поэтому в примере StatusBar закрыт (на родной MiniGui.lib должно быть Ok!)

 Отправлено: 28.05.17 20:24. Заголовок: SergKis пишет: Прим..

SergKis пишет:

цитата:

Пример для Harbour

Благодарю за наглядный пример!

SergKis пишет:

цитата:

Забыл в примере вывести в StatusBar сообщение о наличии меню на правую кнопку мыши

Поправил - пример работает нормально

 Отправлено: 28.05.17 20:57. Заголовок: Конечно - это полез..

Конечно - это полезное дополнение.

Только мне кажется, что UserKeys не совсем подходящее название метода и того, что этот метод делает.

Не помешало бы и добавить что-то вроде SetUserKeys/GetUserKeys

 Отправлено: 28.05.17 21:27. Заголовок: Петр пишет Не помеша..

Петр пишет

цитата:

Не помешало бы и добавить что-то вроде SetUserKeys/GetUserKeys

Тогда + DoUserKeys (выполнение), т.е. еще несколько доп. методов.
Но в МиниГуи уклон к функциям с параметрами и пляской от них, потому пошел таким путем ("что бы не выделяться" (с))

 Отправлено: 28.05.17 22:24. Заголовок: SergKis пишет: Но в..

SergKis пишет:

цитата:

Но в МиниГуи уклон к функциям с параметрами и пляской от них, потому пошел таким путем ("что бы не выделяться" (с))

Понятно, но название неподходящее: bUserKeys/UserKeys - клавиша/ключ, дезориентировать будет.

 Отправлено: 28.05.17 23:01. Заголовок: Петр пишет но назван..

Петр пишет

цитата:

но название неподходящее: bUserKeys/UserKeys - клавиша/ключ, дезориентировать будет.

Т.к. действия bUserKeys с новым методом схожи, то не должно дезориентировать.
Что там обработка пользовательских клавиш\ключей, что тут, от этого и брал название.
Но если есть подходящее название - нет возражений.

 Отправлено: 28.05.17 23:04. Заголовок: gfilatov2002 В прим..

gfilatov2002
В примере надо заменить _HMG_ThisControlName на This.Name - это будет правильнее.

 Отправлено: 28.05.17 23:54. Заголовок: SergKis пишет: Что ..

SergKis пишет:

цитата:

Что там обработка пользовательских клавиш\ключей, что тут

Там обработка клавиш, тут - клавиши\ключа
Причем у вас обработка события по ключу может быть и не связанной с нажатием какой-либо клавиши.

Название должно отображать суть того, что происходит. А что здесь происходит я лично определиться не могу

 Отправлено: 29.05.17 00:06. Заголовок: Петр пишет я лично о..

Петр пишет

цитата:

я лично определиться не могу

Тогда, отдадим на откуп Григорию ( типа, наша хата с краю )

 Отправлено: 29.05.17 00:20. Заголовок: Петр пишет Причем у ..

Петр пишет

цитата:

Причем у вас обработка события по ключу может быть и не связанной с нажатием какой-либо клавиши.

В связи с отсутствием на окне механизма работы через очередь (городить свой обработчик не хочется к каждому окну), к примеру WM_USER + 55 и через Post\SendMessage(hWnd, WM_USER + 55, nIndex\hControl, 0) и на окно вешать подобный механизм UserKeys, приходится вешать клавиши в :UserKeys VK_F21, VK_F22, ... и делать oBrw:PostMsg(...) + oBrw:Cargo с данными. Нажатия клавиш существуют всегда, причем клиент ТРЕБУЕТ дублирование кнопок клавишами КАТЕГОРИЧЕСКИ

 Отправлено: 29.05.17 09:30. Заголовок: Петр Может смущает ..

Петр
Может смущает наличие многих параметров в блоках и функциях (это в основном для информации в MsgBox(...)), так в реальности, можно, практически, обойтись без них (oBrw1 Public\Private):

 
     oBrw:bLDblClick       := {|| oBrw1:PostMsg( WM_KEYDOWN, oBrw1:nFireKey, 0 ) } 
     oBrw:UserKeys(VK_RETURN, {|| oBrw1:PostMsg( WM_KEYDOWN, oBrw1:nFireKey, 0 ) }) или 
     oBrw:UserKeys(VK_RETURN, {|obr| obr:PostMsg( WM_KEYDOWN,  obr:nFireKey, 0 ) })  
     :UserKeys('SetMode_1'  , {|obr| Set_Mode(obr, 1)}) 
     :UserKeys('SetMode_2'  , {|obr| Set_Mode(obr, 2)}) или 
     :UserKeys('SetMode_1'  , {|| Set_Mode(oBrw1, 1)}) 
     :UserKeys('SetMode_2'  , {|| Set_Mode(oBrw1, 2)}) или 
     :UserKeys('SetMode_1'  , {|| Set_Mod1()})  // внутри функций 
     :UserKeys('SetMode_2'  , {|| Set_Mod2()})  // используем oBrw1 
 ... 
 

 Отправлено: 29.05.17 10:26. Заголовок: gfilatov2002 пишет ф..

gfilatov2002 пишет

цитата:

функция hb_HGetDef() недоступна в xHarbour

Может вместо

цитата:

#ifndef __XHARBOUR__ #define __EXT_USERKEYS__ #endif

сделать

 
 #ifndef __XHARBOUR__  
  FUNC hb_HGetDef( hHash, xKey, xDef ) 
  Local nPos := HGetPos( hHash, xKey ) 
  Return iif( nPos > 0, HGetValuePos( hHash, nPos ), xDef ) 
 #endif 
 

 Отправлено: 29.05.17 10:31. Заголовок: PS вернее #ifdef __X..

PS
вернее #ifdef __XHARBOUR__
...

 Отправлено: 29.05.17 11:45. Заголовок: SergKis пишет: верн..

SergKis пишет:

цитата:

вернее #ifdef __XHARBOUR__

Заменил вызов HGetValuePos() на HGetValueAt() и добавил переопределение еще для двух функций

цитата:

#ifdef __XHARBOUR__ /* Hash item functions */ #xtranslate hb_Hash( [<x,...>] ) => Hash( <x> ) #xtranslate hb_HSet( [<x,...>] ) => HSet( <x> ) #endif

теперь UserKeys работает и под xHarbour

Благодарю за помощь

 Отправлено: 29.05.17 12:53. Заголовок: SergKis пишет: Може..

SergKis пишет:

цитата:

Может смущает наличие многих параметров в блоках и функциях

Вот как раз это меня не смущает
И даже наоборот, смущает то, что, например, в Events параметры не передаются в оконные события.

 Отправлено: 30.05.17 07:49. Заголовок: gfilatov2002 Дополн..

gfilatov2002
Дополнительно, что бы было
#ifdef __XHARBOUR__
#xtranslate hb_HHasKey( h, k ) => HHasKey( h, k )
#xtranslate hb_HDel( h, k ) => HDel( h, k )

 Отправлено: 30.05.17 08:20. Заголовок: SergKis пишет: Допо..

SergKis пишет:

цитата:

Дополнительно, что бы было

Включите hbcompat.ch из contrib/hbxhb

 Отправлено: 10.06.17 12:50. Заголовок: Вопрос по индексам в..

Вопрос по индексам в Tsbrowse.

К базе подключёны индексы. 3 индекс создан с ключом = "DESCEND(STR(KView))+UPPER(NAME)"
Добавляю запись в базу.

            nOrderTek := INDEXORD() 
             DBSetOrder( 1 ) 
             ....   
             DBAppend() 
             nTekRec := (oBrw:cAlias)->(RecNo())         
             lAppend := .T. 
             DBSetOrder( nOrderTek ) 
  .... 
    IF  lAppend // была добавлена запись 
       oBrw:Refresh(.T.) 
       oBrw:GoToRec(nTekRec) 
    ENDIF 
    Form_1.oBrw.Setfocus 
    RETURN Nil 

После добавления курсор НЕ становиться на добавленной записи, а становиться на первую запись по индексу.

Как нужно правильно сделать установку на добавленную запись ?

 Отправлено: 10.06.17 13:05. Заголовок: Andrey пишет: nOrd..

Andrey пишет:

цитата:

nOrderTek := INDEXORD() DBSetOrder( 1 ) .... DBAppend() nTekRec := (oBrw:cAlias)->(RecNo()) lAppend := .T. DBSetOrder( nOrderTek )

А так ?

 
 nOrderTek := (oBrw:cAlias)->(INDEXORD())  
              (oBrw:cAlias)->(DBSetOrder( 1 ))  
              ....    
              (oBrw:cAlias)->(DBAppend())  
              nTekRec := (oBrw:cAlias)->(RecNo())          
              lAppend := .T.  
              (oBrw:cAlias)->(DBSetOrder( nOrderTek )) 
 

PS
Вместо INDEXORD() лучше юзать ordsetfocus() ежели это CDX