STATIC lTrayTasks := .f. // нет показа скрытых окон   
  
    aDim := ListApps() 
     .... 
 /////////////////////////////////////////////////////////////////////////// 
 #define GW_HWNDFIRST	0 
 #define GW_HWNDLAST	1 
 #define GW_HWNDNEXT	2 
 #define GW_HWNDPREV	3 
 #define GW_OWNER	4 
 #define GW_CHILD	5 
  
 *--------------------------------------------------------* 
 Function ListApps() 
 *--------------------------------------------------------* 
 LOCAL aWindows := {}, cTitle := "", iWindow, cStr, i:=1 
 LOCAL hWnd := GetWindow( GetForegroundWindow(), GW_HWNDFIRST )  // Get the first window 
  
 	WHILE hWnd != 0  // Loop through all the windows 
 		cTitle := GetWindowText( hWnd ) 
 		IF GetWindow( hWnd, GW_OWNER ) = 0 .AND.;   // If it is an owner window 
 			IsWindowVisible( hWnd ) .AND. ;     // If it is a visible window 
 			!EMPTY( cTitle ) .AND.;             // If the window has a title 
 			!( "DOS Session" $ cTitle ) .AND.;  // If it is not DOS session 
 			!( cTitle == "Program Manager" )    // If it is not the Program Manager 
  
 			AADD( aWindows, { hWnd, cTitle, IsWindowVisible( hWnd ) } ) 
 		ENDIF 
  
 		hWnd := GetWindow( hWnd, GW_HWNDNEXT )  // Get the next window 
 	ENDDO 
  
 	if lTrayTasks 
 		hWnd := GetWindow( GetForegroundWindow(), GW_HWNDFIRST ) 
 		WHILE hWnd != 0  // Loop through all the windows 
 			cTitle := GetWindowText( hWnd ) 
 			IF GetWindow( hWnd, GW_OWNER ) = 0 .AND.; // If it is an owner window 
 				!IsWindowVisible( hWnd ) .AND.;     // If it is a visible window 
 				!EMPTY( cTitle ) .AND.;             // If the window has a title 
 				!( "MS_" $ cTitle ) .AND.;          // If it is not System apps 
 				!( "DDE" $ cTitle ) .AND.;          // If it is not System apps 
 				!( "SYSTEM" $ cTitle ) .AND.;       // If it is not System apps 
 				!( "SENS" $ cTitle ) .AND.;         // If it is not System apps 
 				!( "WIN95" $ cTitle ) .AND.;        // If it is not System apps 
 				!( "Spooler" $ cTitle ) .AND.;      // If it is not System apps 
 				!( "Thread" $ cTitle ) .AND.;       // If it is not System apps 
 				!( "DOS Session" $ cTitle ) .AND.;  // If it is not DOS session 
 				!( cTitle == "Program Manager" )    // If it is not the Program Manager 
  
 				AADD( aWindows, { hWnd, cTitle, IsWindowVisible( hWnd ) } ) 
 			ENDIF 
  
 			hWnd := GetWindow( hWnd, GW_HWNDNEXT )  // Get the next window 
 		ENDDO 
  
 	endif 
         // отладка в файл   
         cStr := "" 
         FOR iWindow := 1 TO LEN(aWindows) 
              cStr += STR(iWindow,3)+";"+STR(aWindows[iWindow,1])+"; "+aWindows[iWindow,2] + CRLF 
 	NEXT 
         hb_memowrit( ChangeFileExt( Application.ExeName, ".log" ), cStr )  
  
 Return aWindows 
 

 
 STATIC FUNCTION VlcHandle( lLog ) 
    LOCAL cVlc := oApp(1):cClassVlc // "Qt5QWindowIcon" 
    LOCAL cTxt := oApp(1):cTitleVlc // " VLC" 
    LOCAL aVlc := HandlesHbWin( , cVlc, !Empty(lLog) ) 
    LOCAL lVlc := .F., hVlc, nVlc 
    LOCAL hYes := 0 
    LOCAL nCnt := 0 
  
    FOR nVlc := 1 TO Len(aVlc) 
        hVlc := aVlc[ nVlc ] 
        cVlc := GetWindowText( hVlc ) 
        IF cTxt $ cVlc 
           hYes := hVlc 
           lVlc := .T. 
           nCnt += 1 
        ELSE 
           DO EVENTS ; PostMessage(hVlc, WM_CLOSE, 0, 0) 
           DO EVENTS ; InkeyGui(20) 
        ENDIF 
    NEXT 
  
 RETURN iif( lVlc, hYes, 0 ) 
  
 STATIC FUNCTION VlcIs( nMax ) 
    LOCAL nVlc := 0 
    LOCAL hVlc := VlcHandle() 
    LOCAL lVlc := .T. 
    Default nMax := 50 
  
    IF ! Empty( hVlc ) 
       WHILE ( ++nVlc ) <= nMax 
          InkeyGui(20) 
          hVlc := VlcHandle() 
          IF ( lVlc := Empty( hVlc ) ) ; EXIT 
          ENDIF 
       END 
    ENDIF 
  
 RETURN ( ! lVlc ) 
  
 STATIC FUNCTION VlcStart( lLog ) 
    LOCAL hVlc := VlcHandle( lLog ) 
    LOCAL cCtl := System.ProgramFilesFolder 
    LOCAL cVlc := "\VideoLAN\VLC" 
    LOCAL cExe := "vlc.exe" 
    LOCAL hRun := 0, cPth, nMax           // "C:\Program Files\VideoLAN\VLC" путь к VLC 
    LOCAL cRun := (App.Object):Cargo:cRun 
  
    IF Empty( cRun )                               // первый вход\старт VLC 
       cPth := cCtl + cVlc 
       cRun := cPth + "\" + cExe 
  
       IF ! hb_DirExists( cPth ) .and. "(x86)" $ cCtl 
          cCtl := trim( StrTran(cCtl, "(x86)") ) 
          cPth := cCtl + cVlc 
          IF ! hb_DirExists( cPth ) 
             MsgStop("Directory not found !"+CRLF+cPth, "ERROR") 
             RETURN hRun 
          ENDIF 
       ENDIF 
  
       cRun := cPth + "\" + cExe 
  
       IF ! hb_FileExists( cRun ) 
          MsgStop("VLC file not found !"+CRLF+cRun, "ERROR") 
          RETURN hRun 
       ENDIF 
  
       (App.Object):Cargo:cRun := cRun 
    ENDIF 
  
    IF ! empty( hVlc ) 
       DO EVENTS ; PostMessage(hVlc, WM_CLOSE, 0, 0) 
       DO EVENTS ; InkeyGui(20) 
       VlcIs()  ; hVlc := VlcHandle( lLog ) 
    ENDIF 
  
    IF Empty( hVlc ) .or. hVlc != hHandlesVLC 
       DO EVENTS ; hRun := _ExecuteEx( 0, "open", cRun, , cPth, 3 ) // SHellExecuteEx( 0, "open", cRun, , cPth, 3 ) 
       DO EVENTS ; InkeyGui(300) 
       hProcessVLC := hHandlesVLC := 0 
  
       IF ! Empty( hRun ) 
          nMax := 20 
          WHILE Empty(hVlc) .and. --nMax >= 0 
             hVlc := VlcHandle( lLog ) ; InKeyGui(100) 
          END 
          hProcessVLC := hRun 
          hHandlesVLC := hVlc 
          SetForeGroundWindow( hVlc ) ; InkeyGui(30) 
          IF GetForeGroundWindow() != hVlc 
             SetForeGroundWindow( hVlc ) ; InkeyGui(30) 
          ENDIF 
          IF Empty( (App.Object):Cargo:cCapt ) 
             (App.Object):Cargo:cCapt := GetWindowText( hVlc ) 
          ENDIF 
          InkeyGui(300) 
       ENDIF 
    ENDIF 
  
 RETURN hRun 
  
 STATIC FUNCTION VlcClose( lLog, lClose ) 
    LOCAL nVlc := 0, nProc, nThread 
    LOCAL hVlc := VlcHandle( lLog ) 
    Default lClose := .T. 
  
    IF lClose .and. ! Empty( hVlc ) 
       DO EVENTS ; PostMessage(hVlc, WM_CLOSE, 0, 0) 
       DO EVENTS ; InkeyGui(20) 
       VlcIs() 
       hVlc := VlcHandle( lLog ) 
    ENDIF 
  
    IF ! Empty( hProcessVLC ) .and. ! Empty( hVlc ) 
       GetWindowThreadProcessId( hVlc, @nThread, @nProc ) 
       TerminateProcess ( nProc ) ; InkeyGui(200) ; VlcIs() 
       DO EVENTS 
       hVlc := VlcHandle( lLog ) 
       IF ! Empty( hVlc ) 
          GetWindowThreadProcessId( hVlc, @nThread, @nProc ) 
          TerminateProcess ( nProc ) ; InkeyGui(200) ; VlcIs() 
          DO EVENTS 
       ENDIF 
       hProcessVLC := 0 
    ENDIF 
  
    IF ! Empty( hVlc := VlcHandle( lLog ) ) ; VlcIs() 
    ENDIF 
  
    hHandlesVLC := 0 
  
 RETURN Empty( VlcHandle( lLog ) ) 
  
 STATIC FUNCTION SetVlcKanal( nPos, uAdr ) 
    LOCAL hVlc := VlcHandle() 
    LOCAL cFoc := oApp(1):cBtnFocus 
    LOCAL nFoc := oApp(1):nBtnFocus 
    LOCAL aFoc := oApp(1):aBtnFocus 
    LOCAL aAdr := oApp(1):aAdrFocus 
    LOCAL nMax, cAdr, cGru, nBtn 
    LOCAL cCap, cNam, cTxt, lAdr 
    LOCAL lPos := nPos == Nil 
  
    Default nPos := 0 
  
    IF Empty( hVlc ) ; RETURN Nil 
    ENDIF 
  
    This.Minimize ; DO EVENTS 
  
    IF ISARRAY( uAdr ) ; aAdr := AClone( uAdr ) 
    ENDIF 
    lAdr := Empty( nPos ) .and. Empty( uAdr ) 
  
    IF IsIconic( hVlc ) 
       ShowWindow( hVlc, SW_MINIMIZE ) 
       ShowWindow( hVlc, SW_RESTORE ) 
    ENDIF 
  
    nMax := 100 
    WHILE GetForeGroundWindow() != hVlc .and. --nMax > 0 
       InkeyGui(20) ; SetForeGroundWindow( hVlc ) 
    END 
  
    ShowWindow( hVlc, SW_MAXIMIZE ) 
    InkeyGui(10) 
  
    //IF GetForeGroundWindow() != hVlc 
    //   BringWindowToTop( hVlc ) ; InkeyGui(20) 
    //ENDIF 
  
    hHandlesVLC := hVlc 
    aAdr := ASize(aAdr, 7) 
    cNam := aAdr[ 1 ] 
    cGru := aAdr[ 2 ] 
    cAdr := aAdr[ 3 ] 
    nBtn := aAdr[ 4 ] ; Default nBtn := 0 
  
    IF ! Empty( cAdr ) 
       oApp(1):nBtnFocus := iif( lPos, 1, nPos ) 
       oApp(1):cBtnFocus := iif( Empty(nPos), "", "o"+hb_ntos(nPos) ) 
       oApp(1):aBtnFocus := { cNam, cGru, cAdr, nBtn } 
       oApp(1):aAdrFocus := { cNam, cGru, cAdr, nBtn } 
       cCap := oApp(1):cCapt 
       cCap := cNam + " - " + cCap 
       cTxt := cCap 
       System.Clipboard := cAdr 
       SetWindowText( hVlc, cCap ) 
       HMG_PressKey(VK_CONTROL, VK_V) ; InkeyGui(20) 
       SetWindowText( hVlc, cCap )    ; nMax := 100 
       WHILE Len( HandlesHbWin( , oApp(1):cClassVlc ) ) < 2 .and. --nMax < 0 ; InkeyGui(10) 
       END 
       HMG_PressKey(VK_RETURN)     ; InkeyGui(20 ) 
       HMG_PressKey(VK_RETURN)     ; InkeyGui(20 ) 
       SetWindowText( hVlc, cCap ) ; InkeyGui(200) 
       nMax := 10 
       WHILE --nMax > 0 ; SetWindowText( hVlc, cCap ) ; InkeyGui(200) 
       END 
       SetWindowText( hVlc, cCap ) 
    ENDIF 
  
    nPos := iif( lAdr, nFoc, oApp(1):nBtnFocus ) 
    cNam := iif( Empty( nPos ), "oIPTV", "o"+hb_ntos(nPos) ) 
    This.&(cNam).SetFocus 
  
 RETURN Nil 
  
 // PostMessage( oBRM:hBrowse, WM_KEYDOWN, VK_F15, 0) 
 // PostMessage( oBRM:hBrowse, WM_KEYP  , VK_F15, 0) 
  
 *-----------------------------------------------------------------------------* 
 STATIC FUNCTION HandlesHbWin( cText, cClass, lLogOut ) 
 *-----------------------------------------------------------------------------* 
    LOCAL i, h, t 
    LOCAL aWnd := EnumWindows() 
    LOCAL aTmp := {} 
    LOCAL aRet := {} 
  
    IF Empty(cClass) 
       aTmp := aWnd 
    ELSE 
       FOR EACH h IN aWnd 
           IF IsWindowHandle( h ) .and. GetClassName( h ) == cClass 
              AAdd( aTmp, h ) 
           ENDIF 
       NEXT 
    ENDIF 
  
    IF ! empty(cText) .and. HB_ISCHAR(cText) .and. Len(aTmp) > 0 
       FOR EACH h IN aTmp 
           IF IsWindowHandle( h ) 
              t := GetWindowText( h ) 
              IF cText $ t ; AAdd( aRet, h ) 
              ENDIF 
           ENDIF 
       NEXT 
    ELSE 
       aRet := aTmp 
    ENDIF 
  
    IF ! Empty(lLogOut) 
       FOR i := 1 TO Len(aTmp) 
           IF IsWindowHandle( aTmp[ i ] ) 
              t := GetWindowText(aTmp[ i ]) 
              _LogFile( .T., str(i, 5), aTmp[ i ], GetClassName(aTmp[ i ]), t ) 
           ENDIF 
       NEXT 
    ENDIF 
  
 RETURN aRet 
  
 Применение 
 ... 
    SET DEFAULT ICON TO "1MAIN_ICO" 
    SET MENUSTYLE EXTENDED                             // switch menu style to advanced 
    SetMenuBitmapHeight( GetFontHeight("Font_1") )     // set image size ... 
  
    VlcHandle() 
  
    IF Empty( VlcStart() ) ; QUIT                      // First start VLC 
    ENDIF 
  
    nY := nX := 0 
    nW := System.DesktopWidth 
    nH := oApp(1):nBtnHeight 
  
    DEFINE WINDOW &cForm AT nY,nX WIDTH nW HEIGHT nH ; 
       TITLE SHOW_TITLE  ; 
       MAIN NOMAXIMIZE NOSIZE  NOSYSMENU NOCAPTION  ; 
       ON INIT     {|| This.Topmost := .F., This.Minimize, ; 
                       DoEvents(), _wPost(11, , Nil) } ; 
       ON RELEASE  {|| dbCloseAll(), VlcClose() } ; 
       ON GOTFOCUS {|| 
                    Local nf := oApp(1):nBtnFocus 
                    Local cf := "o"+hb_ntos(nf) 
                    If _IsControlDefined( cf, This.Name ) 
                       This.&(cf).SetFocus 
                       DO EVENTS 
                    EndIf 
                    Return Nil 
                    } 
       _BtnFafour( 1, 1 ) 
 ... 
       WITH OBJECT oWnd() 
       :Event( 1, {||                                        // context меню IPTV каналов 
                    Local y := This.oIPTV.Row+This.oIPTV.Height 
                    Local x := This.oIPTV.Col 
                    Local a := oApp(1):oGrp:GetAll(.T.) 
                    Local c := oApp(1):cBtnFocus 
                    Local f := {"Font_1", "Font_2"} 
                    If !Empty( c ) ; This.&(c).SetFocus ; DO EVENTS 
                    EndIf 
                    Context_Menu( y, x, 100, a, "IPTV каналы :", "Выход", f ) 
                    Return Nil 
                  } ) 
       :Event( 2, {||                                        // context меню режимов VLC 
                    Local y := This.oVlc.Row+This.oVlc.Height 
                    Local x := This.oVlc.Col 
                    Local c := oApp(1):cBtnFocus 
                    Local f := {"Font_1", "Font_2"} 
                    Local a := {"Перезапустить медиапроигрыватель VLC", ; 
                                "Refresh (обновить) перепоказ канала" , ; 
                                "Таймер выключения работы программы"    ; 
                               } 
                    If !Empty( c ) ; This.&(c).SetFocus ; DO EVENTS 
                    EndIf 
                    Context_Menu( y, x, 300, a, "Режимы работы :", "Выход", f ) 
                    Return Nil 
                  } ) 
       :Event( 3, {||                                        // работа TimerEnd, TimerCnt 
                    IF oApp(1):nTimerEnd > 0 
                       oApp(1):nTimerCnt += 1 
                       IF oApp(1):nTimerCnt >= oApp(1):nTimerEnd 
                          This.TimerEnd.Enabled := .F. 
                          _wSend(99) 
                       ENDIF 
                    ENDIF 
                    Return Nil 
                  } ) 
       :Event( 9, {||                                        // context меню действий с VLC 
                    Return Nil 
                  } ) 
       :Event(10, {|ow,ky,aa| ky := oApp(1):nBtnFocus, aa := oApp(1):aAdrFocus, ; 
                              VlcClose(), VlcStart(), DoEvents(), ; 
                              SetForeGroundWindow( ow:Handle ), DoEvents(), ; 
                              SetFocus( ow:Handle ), DoEvents(), SetVlcKanal(ky, aa) }) 
 ...