#include "minigui.ch" 
  
 Procedure MAIN 
 LOCAL nDesktopWidth  := GetDesktopWidth() 
 LOCAL nDesktopHeight := GetDesktopHeight() - GetTaskBarHeight() 
  
 SET MULTIPLE OFF WARNING 
  
 SET FONT TO "Tahoma", 9 
  
 DEFINE WINDOW Form_1 ; 
 	VIRTUAL WIDTH nDesktopWidth+10 VIRTUAL HEIGHT nDesktopHeight*1.5 ; 
 	TITLE "Icons from shell32.dll" ; 
 	MAIN ; 
 	ON INIT MyDrawIcons() 
  
 END WINDOW 
 Form_1.Sizable   := .F.  // NOSIZE 
 Form_1.MinButton := .F.  // NOMINIMIZE 
 Form_1.MaxButton := .F.  // NOMAXIMIZE 
 Form_1.Activate 
  
 Return 
  
 ///////////////////////////////////////////////////////////////////////////////// 
 Function MyDrawIcons() 
    LOCAL nJ := 0, nI, cStr, cObj, nRow := 10, nCol 
    LOCAL nWidth  := Form_1.Width 
    LOCAL nHeight := Form_1.Height 
    LOCAL cIcon := System.SystemFolder + "\shell32.dll" 
    LOCAL count := ExtractIcon( cIcon, -1, 0, 0, 0 ) 
  
    FOR nI := 0 TO count 
  
        nJ++ 
        nCol := 10 + 70*(nJ-1) 
        IF nCol > nWidth - 80 
           nRow += 70  
           nJ := 1 
           nCol := 10  
        ENDIF  
  
        cObj := "Btn_"+LTRIM(STR(nI)) 
        @ nRow, nCol  BUTTON &cObj    ; 
          OF Form_1                   ; 
          WIDTH 38  HEIGHT 38         ; 
          ICON cIcon                  ; 
          EXTRACT nI FLAT 
  
        cObj := "Lbl_"+LTRIM(STR(nI)) 
        cStr := "nI="+LTRIM(STR(nI)) 
        @ nRow + 40, nCol LABEL &cObj ; 
          OF Form_1 VALUE cStr        ; 
          WIDTH 60 HEIGHT 12          ; 
          TRANSPARENT FONTCOLOR BLUE   
    NEXT 
  
 Return NIL 
 

#include <minigui.ch> 
  
  
 Procedure MAIN 
 local aIcons := ExtractIconEx( GetStartUpFolder() + "\demo.exe", 0, 0, 0, 1 )  
  
 priv hIcon := aIcons[2] 
  
 SET FONT TO "Ms Sans Serif", 8 
  
 DEFINE WINDOW Main ; 
 	AT 0,0 WIDTH 120 HEIGHT 119 ; 
 	TITLE "Information" ; 
 	MAIN ; 
 	ON PAINT fgDraw() ; 
 	ON RELEASE DestroyIcon( hIcon ) 
  
 	DEFINE LABEL hello 
 		ROW 43 - GetTitleHeight() - GetBorderHeight() 
 		COL 62 
 		VALUE 'Hello' 
 		AUTOSIZE .T. 
 	END LABEL 
  
 	DEFINE BUTTON ok 
 		ROW 83 - GetTitleHeight() - GetBorderHeight() 
 		COL 12 
 		WIDTH 90 
 		HEIGHT 21 
 		CAPTION 'OK' 
 		ACTION ThisWindow.Release 
 		DEFAULT .T. 
 	END BUTTON 
  
 END WINDOW 
 Main.Sizable   := .F.  // NOSIZE 
 Main.MinButton := .F.  // NOMINIMIZE 
 Main.MaxButton := .F.  // NOMAXIMIZE 
 Main.Center 
 Main.Activate 
 Return 
  
  
 Function fgDraw() 
 Drawicon( Application.Handle, 12, 12, hIcon ) 
 Return NIL 
  
  
 #pragma BEGINDUMP 
  
 #include <windows.h> 
 #include "hbapi.h" 
  
 #define SMALL_ICON 16 
  
 HB_FUNC( DRAWICON ) 
 { 
 	HWND hwnd = (HWND) hb_parnl( 1 ); 
 	HDC hdc; 
  
 	hdc   = GetDC( hwnd ); 
   
 	hb_retl( DrawIconEx( (HDC) hdc, hb_parni( 2 ), hb_parni( 3 ), (HICON) hb_parnl( 4 ), SMALL_ICON, SMALL_ICON, 0, 0, DI_NORMAL ) ); 
  
 	ReleaseDC( hwnd, hdc ); 
 } 
  
 HB_FUNC( DESTROYICON ) 
 { 
 	DestroyIcon( (HICON) hb_parnl( 1 ) ); 
 } 
  
 HB_FUNC ( EXTRACTICONEX ) 
 { 
 	HICON iLarge; 
 	HICON iSmall; 
 	UINT  nIcons=hb_parni(5); 
  
 	ExtractIconEx( (LPCSTR) hb_parc( 1 ), 
 					hb_parni( 2 )     , 
 					&iLarge           , 
 					&iSmall           , 
 					nIcons	); 
          hb_reta( 2 ); 
          hb_storvnl( ( LONG ) iLarge, -1, 1 ); 
          hb_storvnl( ( LONG ) iSmall, -1, 2 ); 
 } 
  
 #pragma ENDDUMP