/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  * 
  * Copyright 2002-2008 Roberto Lopez <harbourminigui@gmail.com> 
  * http://harbourminigui.googlepages.com/ 
 */ 
  
 #include "minigui.ch" 
  
 Function Main 
 Local aRows := {} 
  
  AEval({ ; 
 		 {'Simpson','Homer','555-5555'}        , ; 
 		 {'Mulder','Fox','324-6432'}           , ; 
 		 {'Smart','Max','432-5892'}            , ; 
 		 {'Grillo','Pepe','894-2332'}          , ; 
 		 {'Kirk','James','346-9873'}           , ; 
 		 {'Barriga','Carlos','394-9654'}       , ; 
 		 {'Flanders','Ned','435-3211'}         , ; 
 		 {'Smith','John','123-1234'}           , ; 
 		 {'Pedemonti','Flavio','000-0000'}     , ; 
 		 {'Gomez','Juan','583-4832'}           , ; 
 		 {'Fernandez','Raul','321-4332'}       , ; 
 		 {'Borges','Javier','326-9430'}        , ; 
 		 {'Alvarez','Alberto','543-7898'}      , ; 
 		 {'Gonzalez','Ambo','437-8473'}        , ; 
 		 {'Batistuta','Gol','485-2843'}        , ; 
 		 {'Vinazzi','Amigo','394-5983'}        , ; 
 		 {'Pedemonti','Flavio','534-7984'}     , ; 
 		 {'Samarbide','Armando','854-7873'}    , ; 
 		 {'Pradon','Alejandra','???-????'}     , ; 
 		 {'Reyes','Monica','432-5836'}           ; 
        } , {|a| AAdd(aRows, { a[1], a[2] }) }) 
  
 	DEFINE WINDOW Form_1 ; 
 		AT 0,0 ; 
 		WIDTH 640 HEIGHT 480 ; 
 		TITLE 'MiniGUI ToolBar Demo' ; 
 		ICON 'DEMO.ICO' ; 
 		MAIN ; 
 		FONT 'Arial' SIZE 10  
  
 		DEFINE STATUSBAR 
 			STATUSITEM 'HMG Power Ready!'  
 		END STATUSBAR 
  
 		DEFINE MAIN MENU  
 			POPUP '&File' 
 				ITEM 'Get ToolBar_3 Button_1'	    ACTION MsgInfo ( if ( Form_1.Button_1c.Value , '.T.' , '.F.' ) , 'Button_1c' ) 
 				ITEM 'Get ToolBar_3 Button_2'	    ACTION MsgInfo ( if ( Form_1.Button_2c.Value , '.T.' , '.F.' ) , 'Button_2c' ) 
 				ITEM 'Get ToolBar_3 Button_3'	    ACTION MsgInfo ( if ( Form_1.Button_3c.Value , '.T.' , '.F.' ) , 'Button_3c' ) 
 				ITEM 'Get ToolBar_3 Button_4'	    ACTION MsgInfo ( if ( Form_1.Button_4c.Value , '.T.' , '.F.' ) , 'Button_4c' ) 
 	    			SEPARATOR	 
 				ITEM 'Set ToolBar_3 Button_1'	    ACTION Form_1.Button_1c.Value := .T.  
 				ITEM 'Set ToolBar_3 Button_2'	    ACTION Form_1.Button_2c.Value := .T.  
 				ITEM 'Set ToolBar_3 Button_3'	    ACTION Form_1.Button_3c.Value := .T.  
 				ITEM 'Set ToolBar_3 Button_4'	    ACTION Form_1.Button_4c.Value := .T.  
 			    	SEPARATOR	 
 				ITEM '&Exit'			ACTION Form_1.Release 
 			END POPUP 
 			POPUP '&Help' 
 				ITEM '&About'		ACTION MsgInfo ("MiniGUI ToolBar demo")  
 			END POPUP 
 		END MENU 
  
 		DEFINE SPLITBOX  
 			 
          GRID Grid_2 ; 
 			WIDTH  400 ; 
 			HEIGHT  70 ; 
 			HEADERS {'Last Name','First Name'} ; 
 			WIDTHS { 90, 90}; 
 			ITEMS aRows ; 
 			VALUE 1 ; 
 			JUSTIFY { BROWSE_JTFY_LEFT,BROWSE_JTFY_CENTER }  
  
 			DEFINE TOOLBAR ToolBar_a BUTTONSIZE 45,40 FONT 'Arial' SIZE 8  FLAT 
  
 				BUTTON Button_1a ; 
 					CAPTION '&Undo' ; 
 					PICTURE 'button4.bmp' ; 
 					ACTION MsgInfo('Click! 1') 
  
 				BUTTON Button_2a ; 
 					CAPTION '&Save' ; 
 					PICTURE 'button5.bmp' ; 
 					WHOLEDROPDOWN  
  
 					DEFINE DROPDOWN MENU BUTTON Button_2a  
 						ITEM 'Exit'	ACTION Form_1.Release 
 						POPUP 'More' 
 							ITEM 'Disable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .F. 
 							ITEM 'Enable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .T. 
 						END POPUP 
 						ITEM 'About'	ACTION MsgInfo ("MiniGUI ToolBar Demo")  
 					END MENU 
  
 				BUTTON Button_3a ; 
 					CAPTION '&Close' ; 
 					PICTURE 'button6.bmp' ; 
 					ACTION MsgInfo('Click! 3') ; 
 					DROPDOWN 
  
 					DEFINE DROPDOWN MENU BUTTON Button_3a  
 						ITEM 'Disable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .F. 
 						ITEM 'Enable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .T. 
 					END MENU 
  
 			END TOOLBAR 
  
 			DEFINE TOOLBAR ToolBar_b BUTTONSIZE 45,40 FONT 'ARIAL' SIZE 8 FLAT  
  
 				BUTTON Button_1b ; 
 					CAPTION 'More ToolBars...' ; 
 					PICTURE 'button7.bmp' ; 
 					ACTION MsgInfo('Click! 1');  
  
 				BUTTON Button_2b ; 
 					CAPTION 'Button 2' ; 
 					PICTURE 'button8.bmp' ; 
 					ACTION MsgInfo('Click! 2');  
 					SEPARATOR 
  
 				BUTTON Button_3b ; 
 					CAPTION 'Button 3' ; 
 					PICTURE 'button7.bmp' ; 
 					ACTION MsgInfo('Click! 3') 
  
 			END TOOLBAR 
  
 			DEFINE TOOLBAR ToolBar_c BUTTONSIZE 45,40 FONT 'Arial' SIZE 8 CAPTION 'ToolBar 3' FLAT 
  
 				BUTTON Button_1c ; 
 					CAPTION 'Check 1' ; 
 					PICTURE 'button4.bmp' ; 
 					ACTION MsgInfo('Hey!'); 
 					CHECK GROUP 
  
 				BUTTON Button_2c ; 
 					CAPTION 'Check 2' ; 
 					PICTURE 'button5.bmp' ; 
 					ACTION MsgInfo('Hey!') ;  
 					CHECK GROUP 
  
 				BUTTON Button_3c ; 
 					CAPTION 'Check 3' ; 
 					PICTURE 'button6.bmp' ; 
 					ACTION MsgInfo('Hey!') ; 
 					SEPARATOR; 
 					CHECK GROUP 
  
 				BUTTON Button_4c ; 
 					CAPTION 'Help Check' ; 
 					PICTURE 'button9.bmp' ; 
 					ACTION MsgInfo('Hey!') ; 
 					CHECK  
  
 			END TOOLBAR 
  
          COMBOBOX Combo_1 ; 
 			WIDTH 100 ; 
 			ITEMS { '1 | Uno' , '2 | Dos' , '3 | tres' } ; 
 			VALUE 1 ; 
 			ON ENTER MsgInfo ( Form_1.Combo_1.ITEMHEIGHT ) ; 
 			UPPERCASE ; 
 			ITEMHEIGHT 21 ; 
 			FONT 'Courier' SIZE 12  
  
          EDITBOX Edit_1 ; 
          WIDTH  100 ; 
          HEIGHT  40 ; 
          VALUE   '12345'+CRLF+'67890' ; 
          READONLY ; 
          NOVSCROLL NOHSCROLL 
  
 		END SPLITBOX 
  
 	END WINDOW 
  
 	CENTER WINDOW Form_1 
  
 	ACTIVATE WINDOW Form_1 
  
 Return Nil