/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  * 
  * Copyright 2015 Verchenko Andrey <verchenkoag@gmail.com> 
 */ 
  
 #include "minigui.ch" 
 #include "hbthread.ch"  
  
 PROCEDURE Main 
    PUBLIC nILogoWait 
  
    DEFINE WINDOW Form1 ; 
 	AT 0 , 0 ; 
 	WIDTH 600 HEIGHT 400 ; 
 	TITLE "Window with expectation (preloding) in stream" ; 
         BACKCOLOR {0,176,240} ; 
 	MAIN  
  
         @ 10, 0 LABEL Label_1  WIDTH 600 HEIGHT 28 ; 
           VALUE 'For:' SIZE 16 BOLD TRANSPARENT CENTERALIGN 
  
         @ 50,20 BUTTON Btn_Start CAPTION "Start!" WIDTH 140 HEIGHT 48 ; 
           ACTION WaitingProcess()  
  
         @ 130,20 BUTTON Btn_End CAPTION "Close" WIDTH 140 HEIGHT 48   ; 
           ACTION ThisWindow.Release()  
  
  
    END WINDOW 
  
    CENTER WINDOW Form1 
    ACTIVATE WINDOW Form1 
  
 RETURN 
  
 /////////////////////////////////////////////////////////////////// 
 FUNCTION WaitingProcess() 
    LOCAL nI, cMsg, nTime 
    Local Th 
    PRIVATE aBegin 
    PRIVATE lexit:=.t. 
    aBegin := WaitWinCreate( "Working..." )  // создать окно ожидания 
  
    // Запускаем в отдельном потоке (preloding) 
    th:=hb_threadStart(HB_THREAD_INHERIT_MEMVARS, @WaitWinTimer(),@aBegin) 
  
    nTime := SECONDS() 
  
    FOR nI := 1 TO 50 
  
       Form1.Label_1.Value := 'For nI := ' + HB_NtoS(nI)  
  
       // final waiting 
       INKEYGUI(100) 
  
       DO EVENTS 
  
    NEXT 
  
 lexit:=.f. 
 hb_threadDetach(th)    
  
    WaitWinClose(aBegin)  //  убить окно ожидания 
  
    cMsg := "Elapsed processing time - " + SECTOTIME( SECONDS() - nTime )  
    MsgInfo(cMsg) 
  
 RETURN NIL 
  
 ////////////////////////////////////////////////////////////////////////////// 
 FUNCTION WaitWinCreate( cTitle, lCenter, nWRow, nWCol) 
    LOCAL nI, cFormName := "WaitWin_" + AllTRim( Str( _GetId() ) ) 
    LOCAL nTime := SECONDS() 
    LOCAL aPict := {"FR01","FR02","FR03","FR04","FR05","FR06","FR07","FR08",; 
                    "FR09","FR10","FR11","FR12"} 
    DEFAULT cTitle := "Wait", lCenter := .T., nWRow := 0, nWCol := 0 
  
    M->nILogoWait := 1  // номер показа картинки 
  
    //SET INTERACTIVECLOSE OFF 
  
    DEFINE WINDOW &cFormName ; 
      ROW 0 COL 0 ; 
      WIDTH 420 HEIGHT 230 ; 
      TITLE cTitle ; 
      MODAL NOSYSMENU NOSIZE ; 
      BACKCOLOR WHITE        ; 
      FONT 'Tahoma' SIZE 12 
  
      @ 10,10 LABEL Label_1   ; 
        WIDTH 400 HEIGHT 20 ; 
        VALUE "Time passed " + TIME() ; 
        CENTERALIGN VCENTERALIGN TRANSPARENT 
  
      @ 40, (420-128)/2 IMAGE Image_1 PICTURE aPict[1] ; 
        WIDTH 128 HEIGHT 128 ; 
        WHITEBACKGROUND TRANSPARENT 
  
      @ 40 + 128 + 2, 10 LABEL Label_2   ; 
        WIDTH 400 HEIGHT 20 ; 
        VALUE 'Wait a little is being processed ...'   ; 
        CENTERALIGN VCENTERALIGN TRANSPARENT 
  
    END WINDOW 
  
    Center Window &cFormName 
    IF lCenter == .F. 
        SetProperty( cFormName, "Row", nWRow ) 
        SetProperty( cFormName, "Col", nWCol ) 
    ENDIF 
    Activate Window &cFormName NoWait 
  
   RETURN { cFormName, aPict, nTime } // вернуть номер окна, чтобы по нему потом убить окно 
  
 ////////////////////////////////////////////////////////////////////// 
 FUNCTION WaitWinTimer(aDim) 
    LOCAL cFormName := aDim[1], aPict := aDim[2], nTime := aDim[3] 
    LOCAL cTime := "Time passed " + SECTOTIME( SECONDS() - nTime ) 
    LOCAL cPict    
                 do while lexit 
    M->nILogoWait ++  // номер показа картинки 
    M->nILogoWait := IIF( M->nILogoWait > LEN(aPict), 1, M->nILogoWait ) 
    cPict := aPict[M->nILogoWait] 
    cTime := "Time passed " + SECTOTIME( SECONDS() - nTime ) 
    SetProperty( cFormName, "Label_1", "Value", cTime ) 
    SetProperty( cFormName, "Image_1", "Picture", cPict ) 
    InkeyGui(50) 
    DO EVENTS 
  
                 enddo 
  
 RETURN NIL 
  
 ////////////////////////////////////////////////////////////////////// 
 FUNCTION WaitWinClose(aDim) 
    LOCAL cFormName := aDim[1] 
  
    Domethod(cFormName,"Release") 
  
    DO MESSAGE LOOP 
  
 RETURN NIL