#include "i_winuser.ch" 
 #include "minigui.ch" 
 #include "hbclass.ch" 
 #include "hbwin.ch" 
  
 MEMVAR oPub 
  
 FUNCTION MAIN() 
 LOCAL i,j,k, aYes,oL,oE 
  
  PUBLIC oPub := MyPubl():New() 
  
  MyFunc() 
  
  oPub:Destroy() 
  
 RETURN 
  
 FUNCTION MyFunc() 
 LOCAL i,j,k, aYes,oL,oE 
  
  aYes := { "Text ", 10.00, 20.00, Date() } 
  
  k := 10 
  
  oE := oPub:oErr 
  oL := oPub:oLog 
  
  oE:Put(repl("=",10), Date(), repl("=", 20)) 
  oL:Put(repl("=",10), Date(), repl("=", 20)) 
  
  FOR i := 1 TO k 
  
      oPub:oLog:Put( PadR(aYes[1]+ltrim(str(i)), 20),   ; 
                     PadL(aYes[2] * i, 12),             ; 
                     PadL(aYes[3] * i, 12),             ; 
                     PadC(aYes[4] + i, 12) ) 
  
      IF i == 3 .or. i == 7 
         oE:Put("Error <", ltrim(str(i)), ">") 
      ENDIF 
  
  NEXT 
  
 RETURN 
  
 CLASS ToFile                 // Класс вывода в файл txt 
  
  VAR cFile  INIT '' 
  VAR hFile  INIT 0 
  VAR cTab   INIT '' 
  VAR cCrLf  INIT '' 
  
  METHOD New() 
  METHOD Open() 
  METHOD Close() 
  METHOD Put() 
  METHOD PutTab() 
  METHOD PutCrLf() 
  METHOD Val2Txt() 
  
 ENDCLASS 
  
 METHOD New( cFile )  CLASS ToFile 
  
  IF ! empty(cFile) .and. valtype(cFile) == "C" 
     ::cFile := cFile 
  ENDIF 
  ::cTab  := chr(9) 
  ::cCrLf := chr(13)+chr(10) 
  
 RETURN Self 
  
 METHOD Open() 
  
  IF empty(::cFile); RETURN .F. 
  ENDIF 
  
  ::hFile := iif( File(::cFile), FOpen(::cFile, 2) , FCreate(::cFile) ) 
  
  IF ::hFile > 0; FSeek( ::hFile, 0, 2 ) 
  ENDIF 
  
 RETURN ( ::hFile > 0 ) 
  
 METHOD Close()    CLASS ToFile 
  
  IF ::hFile > 0 
     FClose( ::hFile ) 
     ::hFile := 0 
  ENDIF 
  
 RETURN 
  
 METHOD Put( ... )   CLASS ToFile 
 LOCAL i,j, aParams, nParams, lParams 
  
  nParams := PCount() 
  
  IF ::hFile < 1 .or. nParams < 1; RETURN 
  ENDIF 
  
  aParams := hb_aParams() 
  lParams := nParams > 1  
  
  FOR i := 1 TO nParams 
      j := ::Val2Txt( aParams [ i ] ) 
      IF len(j) > 0;  FWrite(::hFile, j) 
      ENDIF 
      IF i != nParams .and. lParams;  ::PutTab() 
      ENDIF 
  NEXT 
  
  IF lParams;  ::PutCrlf() 
  ENDIF 
  
 RETURN 
  
 METHOD PutTab()   CLASS ToFile 
  
  IF len(::cTab) > 0; FWrite(::hFile, ::cTab) 
  ENDIF 
  
 RETURN 
  
 METHOD PutCrLf()  CLASS ToFile 
  
  IF len(::cCrLf) > 0; FWrite(::hFile, ::cCrLf) 
  ENDIF 
  
 RETURN 
  
 METHOD Val2Txt( xVal )  CLASS ToFile 
 LOCAL cTx := "", cTp := valtype(xVal) 
  
  IF     cTp=='C';  cTx := xVal 
  ELSEIF cTp=='N';  cTx := LTrim(Str(xVal))  
  ELSEIF cTp=='L';  cTx := iif(xVal, "Yes", "No ") 
  ELSEIF cTp=='D';  cTx := DToC( xVal ) 
  ELSEIF cTp=='A';  AEval(xVal, {|x,i| cTx += x + ::cTab }) 
  ENDIF    
  
 RETURN cTx 
  
 CLASS MyPubl                 // Класс контейнер 
  
  VAR oLog 
  VAR oErr 
  
  METHOD New() 
  METHOD Destroy() 
  
 ENDCLASS 
  
 METHOD New() CLASS MyPubl 
  
  ::oLog := ToFile():New("_MyLog.txt") 
  ::oErr := ToFile():New("_MyErr.txt") 
  
  ::oLog:Open() 
  ::oErr:Open() 
  
 RETURN Self 
  
 METHOD Destroy() CLASS MyPubl 
  
  ::oLog:Close() 
  ::oErr:Close() 
  
 RETURN