/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
 */ 
  
 #include "minigui.ch" 
 #include "Dbstruct.ch" 
  
 REQUEST DBFCDX 
  
 Function Main 
  
 	SET CENTURY ON 
 	SET DELETED ON 
  
 	SET BROWSESYNC ON	 
  
 	DEFINE WINDOW Form_1 ; 
 		AT 0,0 ; 
 		WIDTH 640 HEIGHT 480 ; 
 		TITLE 'MiniGUI Browse Demo' ; 
 		MAIN NOMAXIMIZE ; 
 		ON INIT OpenTables() ; 
 		ON RELEASE CloseTables() 
  
 		DEFINE MAIN MENU  
 			POPUP 'File' 
 				ITEM 'Set Browse Value'	ACTION Form_1.Browse_1.Value := Val ( InputBox ('Set Browse Value','') ) 
 				ITEM 'Get Browse Value'	ACTION MsgInfo ( Str ( Form_1.Browse_1.Value ) ) 
 				ITEM 'Refresh Browse'	ACTION Form_1.Browse_1.Refresh 
 				SEPARATOR 
 				ITEM 'Get Struct'		ACTION ( astr := dbstruct(), MsgInfo ( astr[1][2], astr[1][1] ) ) 
 				SEPARATOR 
 				ITEM 'Exit'		ACTION Form_1.Release 
 			END POPUP 
 			POPUP 'Help' 
 				ITEM 'About'		ACTION MsgInfo ("MiniGUI Browse Demo")  
 			END POPUP 
 		END MENU 
  
 		DEFINE STATUSBAR 
 			STATUSITEM '' 
 		END STATUSBAR 
  
 		@ 10,10 BROWSE Browse_1									; 
 			WIDTH 610  										; 
 			HEIGHT 390 										;	 
 			HEADERS { 'Code' , 'First Name' , 'Last Name', 'Birth Date', 'Married' , 'Biography' } ; 
 			WIDTHS { 100 , 150 , 150 , 150 , 150 , 150 } ; 
 			WORKAREA Test ; 
 			FIELDS { 'Test->Code' , 'Test->First' , 'Test->Last' , 'Test->Birth' , 'Test->Married' , 'Test->Bio' } ; 
 			TOOLTIP 'Browse Test' ; 
 			ON CHANGE ChangeTest() ; 
 			JUSTIFY { BROWSE_JTFY_RIGHT,BROWSE_JTFY_CENTER, BROWSE_JTFY_CENTER, BROWSE_JTFY_CENTER,BROWSE_JTFY_CENTER,BROWSE_JTFY_CENTER} 
  
 	END WINDOW 
  
 	CENTER WINDOW Form_1 
  
 	Form_1.Browse_1.SetFocus 
  
 	ACTIVATE WINDOW Form_1 
  
 Return Nil 
  
 Procedure OpenTables() 
  
 	if !file("test.dbf") 
 		CreateTable() 
 	endif 
  
 	Use Test Via "DBFCDX" Shared 
 	Go Top 
  
 	Form_1.Browse_1.Value := RecNo() 
 	 
 Return 
  
 Procedure CloseTables() 
 	Use 
 Return 
  
 Procedure ChangeTest() 
 	Form_1.StatusBar.Item(1) := 'RecNo() ' + Alltrim ( Str ( RecNo ( ) ) )  
 Return  
  
 Procedure CreateTable 
  
 LOCAL aDbf[6][4], i 
  
         aDbf[1][ DBS_NAME ] := "Code" 
         aDbf[1][ DBS_TYPE ] := "+" 
         aDbf[1][ DBS_LEN ]  := 4 
         aDbf[1][ DBS_DEC ]  := 0 
         // 
         aDbf[2][ DBS_NAME ] := "First" 
         aDbf[2][ DBS_TYPE ] := "Character" 
         aDbf[2][ DBS_LEN ]  := 25 
         aDbf[2][ DBS_DEC ]  := 0 
         // 
         aDbf[3][ DBS_NAME ] := "Last" 
         aDbf[3][ DBS_TYPE ] := "Character" 
         aDbf[3][ DBS_LEN ]  := 25 
         aDbf[3][ DBS_DEC ]  := 0 
         // 
         aDbf[4][ DBS_NAME ] := "Married" 
         aDbf[4][ DBS_TYPE ] := "Logical" 
         aDbf[4][ DBS_LEN ]  := 1 
         aDbf[4][ DBS_DEC ]  := 0 
         // 
         aDbf[5][ DBS_NAME ] := "Birth" 
         aDbf[5][ DBS_TYPE ] := "Date" 
         aDbf[5][ DBS_LEN ]  := 8 
         aDbf[5][ DBS_DEC ]  := 0 
         // 
         aDbf[6][ DBS_NAME ] := "Bio" 
         aDbf[6][ DBS_TYPE ] := "Memo" 
         aDbf[6][ DBS_LEN ]  := 10 
         aDbf[6][ DBS_DEC ]  := 0 
         // 
  
         DBCREATE("Test", aDbf, "DBFCDX") 
  
 	Use test Via "DBFCDX" 
 	 
  
 	For i:= 1 To 100 
 		append blank 
 		Replace First With 'First Name '+ Str(i) 
 		Replace Last With 'Last Name '+ Str(i) 
 		Replace Married With .t. 
 		replace birth with date()+i-10000 
 	Next i 
  
 	delete all for recno()%10==0 
 	PACK 
  
 	Use 
  
 Return