/* 
  * MINIGUI - Harbour Win32 GUI library Demo 28-01-2022 
  * 
  * Copyright 2022 Dima - http://clipper.borda.ru/?32-dima 
  * 
  * Сколько клиентов подключилось к серверу (RDP-сессии) или список логинов RDP-сессий ?  
  * How many clients connected to the server (RDP sessions) or a list of RDP session logins?  
 */ 
  
 #define _HMG_OUTLOG 
 #include "hmg.ch" 
  
 REQUEST HB_CODEPAGE_RU1251 
 ANNOUNCE RDDSYS 
 ///////////////////////////////////////////////////////////////////// 
 PROCEDURE MAIN(cComp) 
    LOCAL cLog, aRet 
    DEFAULT cComp := "" 
  
    SET EPOCH TO ( Year(Date()) - 50 ) 
    SET LANGUAGE TO RUSSIAN   
    SET CODEPAGE TO RUSSIAN   
    SET Date TO GERMAN 
   
    cLog := ChangeFileExt( Application.ExeName, ".log" ) 
    DELETEFILE(cLog) 
    SET LOGFILE TO &cLog   // set filename for debug output to file 
  
    SET WINDOW MAIN OFF 
  
    ? REPL("= ",20) + "program Start " + HB_TSTOSTR( hb_DateTime() ) + REPL(" =",20) 
     
    cComp := IIF( LEN(cComp) == 0, GetComputerName(), cComp ) 
    ? "Computername:", cComp 
    ? "Current user:", GetUserName() 
    ? "          OS:", wmiOsver(cComp) 
    ? "Where is the program running ? RDP session:", win_OsIsTSClient() 
    //IF win_OsIsTSClient() 
       aRet := HmgLogonSession(cComp) 
       ? "hmgLogonSession()=", aRet, HB_ValToExp(aRet) 
    //ENDIF 
  
    ? "." ; ? "=== End ===" 
  
    ShellExecute( 0, "Open", cLog,,, 1 ) 
  
 RETURN 
  
 ///////////////////////////////////////////////////////////////////// 
 FUNCTION WMIService( cComp )  
    LOCAL oWMI ,oLocator  
    DEFAULT cComp := "." 
    
    BEGIN SEQUENCE WITH {| oErr | Break( oErr ) }     
       oLocator:= win_oleCreateObject( "wbemScripting.SwbemLocator" )  
       oWMI:= oLocator:ConnectServer(cComp,"ROOT\CIMV2")  
    END SEQUENCE  
  
 RETURN oWMI  
  
 ///////////////////////////////////////////////////////////////////// 
 // какая версия на компе 
 FUNCTION wmiOsver(cComp)     
    LOCAL cRet, objWMI, Ocosver, elem 
  
    cRet   := "" 
    objWMI := WmiService(cComp)    
    objWMI:Security_:ImpersonationLevel  := 3  
    objWMI:Security_:AuthenticationLevel := 6  
    
    Ocosver := objWMI:InstancesOf ("Win32_OperatingSystem")  
    FOR EACH elem IN Ocosver 
      cRet += elem:name + CRLF 
    NEXT  
  
 RETURN cRet  
  
 ///////////////////////////////////////////////////////////////////// 
 // Функция, позволяющая получить информацию о терминальных сессиях 
 // на сервере (локальный/удаленный компьютер). 
 // Рекомендация: 
 // Перед применением проверить на компьютерах 
 // Windows Management Instrumentation (WMI): 
 // 1. Состояние служб. 
 // 2. Разрешение в брандмауэре. 
 // 
 FUNCTION hmgLogonSession(cComp) 
    LOCAL aRet, objWMI, nI, elem, oTerminal, objItem, userlist, id 
    DEFAULT cComp := "." 
  
    nI   := 0 
    aRet := {} 
    ? REPL("-",40) 
  
    objWMI := WmiService(cComp)    
    
    objWMI:Security_:ImpersonationLevel  := 3  
    objWMI:Security_:AuthenticationLevel := 6  
    
    oTerminal := objWMI:ExecQuery("Select * from Win32_LogonSession Where LogonType=10")   
    FOR EACH objItem IN oTerminal  
       // objItem:Name и остальные фишки почему то возвращают NIL   
       ? "   Caption               ",  objItem:Caption               
       ? "   Description           ",  objItem:Description           
       ? "   InstallDate           ",  objItem:InstallDate           
       ? "   Name                  ",  objItem:Name                  
       ? "   Status                ",  objItem:Status                
       ? "   StartTime             ",  objItem:StartTime             
       ? "   AuthenticationPackage ",  objItem:AuthenticationPackage 
       ? "   LogonId               ",  objItem:LogonId               
       ? "   LogonType             ",  objItem:LogonType             
       if !empty(objItem:LogonId)  
           nI++  
       endif  
       ? REPL("-",40) 
    NEXT  
    ? "Number of terminal sessions:",nI  
  
    ? REPL("-",40) 
    FOR EACH objItem IN oTerminal  
       id := objItem:LogonId  
       userlist := objWMI:ExecQuery("ASSOCIATORS OF {Win32_LogonSession.LogonId="+id+"} WHERE AssocClass=Win32_LoggedOnUser Role=Dependent")  
       FOR EACH elem IN userlist  
          AADD( aRet, elem:name + " Status:" + elem:Status ) 
       NEXT  
    NEXT      
          
 RETURN aRet  
 

/*  
  * MINIGUI - Harbour Win32 GUI library Demo 28-01-2022  
  *  
  * Copyright 2022 Dima - http://clipper.borda.ru/?32-dima  
  *  
  * Сколько клиентов подключилось к серверу (RDP-сессии) или список логинов RDP-сессий ?   
  * How many clients connected to the server (RDP sessions) or a list of RDP session logins?   
 */  
   
 #define _HMG_OUTLOG  
 #include "hmg.ch"  
   
 REQUEST HB_CODEPAGE_RU1251  
 ANNOUNCE RDDSYS  
 /////////////////////////////////////////////////////////////////////  
 PROCEDURE MAIN  
    LOCAL oWMI, objWMI, oTerminal, objItem, Ocosver, elem, cLog 
      
    SET EPOCH TO ( Year(Date()) - 50 )  
    SET LANGUAGE TO RUSSIAN    
    SET CODEPAGE TO RUSSIAN    
    SET Date TO GERMAN  
    
    cLog := ChangeFileExt( Application.ExeName, ".log" )  
    DELETEFILE(cLog)  
    SET LOGFILE TO &cLog   // set filename for debug output to file  
   
    SET WINDOW MAIN OFF  
   
    ? REPL("= ",20) + "program Start " + HB_TSTOSTR( hb_DateTime() ) + REPL(" =",20)  
  
    ? "win_OsIsTSClient()", win_OsIsTSClient()  
      
    objWMI := WmiService()    
      
    objWMI:Security_:ImpersonationLevel  := 3  
    objWMI:Security_:AuthenticationLevel := 6  
      
    Ocosver:= objWMI:InstancesOf ("Win32_OperatingSystem")  
    for each elem in Ocosver  
       ? elem:name  
    next  
      
    oTerminal := objWMI:ExecQuery("Select * from Win32_LogonSession Where LogonType=10" )   
      
    ? "Number of terminal sessions:",oTerminal:count  
    FOR EACH objItem IN  oTerminal  
       ? "objItem:LogonId", objItem:LogonId  
       ? "objItem:StartTime", objItem:StartTime  
       ? objItem:Name 
       // objItem:Name и остальные фишки почему то возвращают NIL   
    next  
  
    oTerminal := objWMI:ExecQuery("Select * from Win32_LogonSession Where LogonType=10" )   
    FOR EACH objItem IN  oTerminal  
       id       := objItem:LogonId  
       userlist := objWMI:ExecQuery("ASSOCIATORS OF {Win32_LogonSession.LogonId="+id+"} WHERE AssocClass=Win32_LoggedOnUser Role=Dependent")  
       ? id 
       For each elem in userlist  
          ? elem:name, elem:Status 
       Next  
    NEXT 
  
    ? "." ; ? "=== End ==="  
  
    ShellExecute( 0, "Open", cLog,,, 1 )  
   
 RETURN   
  
 /////////////////////////////////////////////////////////////////////  
 FUNCTION WMIService( cComp )  
    Local oWmi ,oLocator  
    hb_default(@cComp,'.')  
      
    BEGIN SEQUENCE WITH {| oErr | Break( oErr ) }     
       oLocator:= win_oleCreateObject( "wbemScripting.SwbemLocator" )  
       oWMI := oLocator:ConnectServer(cComp,"ROOT\CIMV2")  
    End SEQUENCE  
  
 RETURN oWmi