*----------------------------------------------------------------------------* 
 FUNCTION oFDB_Connect(cFdb, cUsr, cPsw, cErr, lNoDbf) 
 *----------------------------------------------------------------------------* 
    LOCAL oac := App.Cargo 
    LOCAL o := oHmgData(), cPref, cMsg, cKod, nCnt 
    LOCAL cSql, aRec, cTbl, aFld, cFld, nFld, aStru, oField 
  
    STATIC s_oFdb ; IF s_oFdb == NIL ; s_oFDB := oHmgData() ; ENDIF 
    // регистация баз в работе 
    IF Empty(s_oFdb:Get(cFdb)) ; s_oFdb:Set(cFdb, hb_FNameName(cFdb)) 
    ENDIF 
  
    cPref := "_" + cValToChar(s_oFdb:Pos(hb_FNameName(cFdb)))  
  
    Default cUsr := "SYSDBA", cPsw := "masterkey", lNoDbf := .F. 
    Default cErr := "ERROR!;Can't connect to database !" 
  
    o:cDriver  := 'DRIVER=Firebird/InterBase(r) driver;UID=^1;PWD=^2;DBNAME=^3;' 
  
    o:cConnect := o:cDriver 
    o:aTables  := {} 
    o:oTables  := oHmgData() 
    o:oFields  := oHmgData() 
                 
    o:cConnect := StrTran(o:cConnect, "^1", cUsr) 
    o:cConnect := StrTran(o:cConnect, "^2", cPsw) 
    o:cConnect := StrTran(o:cConnect, "^3", cFdb) 
  
    o:cBase    := cFdb 
    o:cPref    := cPref 
    o:lNoDbf   := lNoDbf 
    o:cError   := cErr + " " + o:cBase + " " 
    o:cDbfTabl := oac:cPath + "_Tables"  
    o:cDbfStru := oac:cPath + "_TablesStru"  
    o:cAlsTabl := upper(cPref) + "_TABL" 
    o:cAlsStru := upper(cPref) + "_STRU" 
    o:aDbfTabl := {{"R_CODE"    , "C",  4, 0 }, ; 
                   {"R_TABLE"   , "C", 20, 0 }, ; 
                   {"R_COUNT"   , "N",  7, 0 }} 
    o:aDbfStru := {{"R_CODE"    , "C",  4, 0 }, ; 
                   {"R_NAME"    , "C", 10, 0 }, ; 
                   {"F_NAME"    , "C", 20, 0 }, ; 
                   {"R_TYPE"    , "C",  1, 0 }, ; 
                   {"R_LEN"     , "N",  7, 0 }, ; 
                   {"R_DEC"     , "N",  5, 0 }, ; 
                   {"F_AllowNul", "L",  1, 0 }, ; 
                   {"F_DataSize", "N", 10, 0 }, ; 
                   {"F_DataType", "N",  3, 0 }} ; 
  
    // --------------------------------------------- блоки кода - псевдо методы 
  
    o:ErrorAlert  := {|aVal|                      // ODBC error message 
                       Local cMsg, cTxt 
                       Local oo := ATail(aVal)    // Self 
                       cMsg := cTxt := "" 
                       IF oo:lError 
                          IF Len(aVal) == 2 ; cTxt := aVal[1] 
                          ENDIF 
                          IF !HB_ISCHAR(cTxt) ; cTxt := cValToChar(cTxt) 
                          ENDIF 
                          cMsg := oo:cError 
                          IF oo:lErrorSql 
                             cMsg += CRLF + oo:oConnect:SQLErrorMessage() 
                             cMsg += CRLF + oo:oConnect:cSQL 
                          ENDIF 
                          AlertStop( cTxt + cMsg ) 
                       ENDIF 
                       Return cMsg 
                       } 
  
    o:Disconnect  := {|aVal|                      // disconnect odbc 
                       Local oo := ATail(aVal)    // Self 
                       IF oo:lConnect 
                          oo:oConnect:Destroy() 
                          oo:lConnect  := .F. 
                          oo:lError    := .F. 
                          oo:lErrorSql := .F. 
                          oo:cBase     := "" 
                          oo:cPref     := "" 
                          oo:cDbfTabl  := "" 
                          oo:cDbfStru  := "" 
                          oo:cAlsTabl  := "" 
                          oo:cAlsStru  := "" 
                       ENDIF 
                       Return .T. 
                       } 
  
    o:GetTable    := {|aVal|                      // get table R_CODE, R_TABL    
                       Local oo := ATail(aVal)    // Self 
                       Local xTabl := aVal[1]     // номер\имя таблицы 
                       Local oRet  := oHmgData() 
                       Local nOldA, cAls 
                       Local cTabl, nTabl, lTabl, nKod, nTbl 
                       oRet:R_CODE  := "" 
                       oRet:R_TABLE := "" 
                       oRet:N_TABLE := 0 
                       oRet:N_COUNT := 0 
                       IF !oo:lConnect ; Return oRet 
                       ENDIF 
                       cAls  := oo:cAlsTabl + "_TMP" 
                       nOldA := Select() 
                       USE ( oo:cDbfTabl ) ALIAS ( cAls ) NEW SHARED 
                       GO TOP 
                       nKod := FieldPos("R_CODE" ) 
                       nTbl := FieldPos("R_TABLE") 
                       IF  IsNumeric(xTabl) ; nTabl := xTabl 
                       ELSEIF IsChar(xTabl) ; xTabl := upper(alltrim(xTabl)) 
                       ENDIF 
                       DO WHILE !EOF() 
                          lTabl := .F. 
                          IF  IsNumeric(xTabl) 
                              lTabl := Val(FieldGet(nKod)) == nTabl 
                          ELSEIF IsChar(xTabl) 
                              cTabl := alltrim(FieldGet(nTbl)) 
                              lTabl := upper(cTabl) == xTabl 
                          ENDIF 
                          IF lTabl 
                             oRet:R_CODE  := FieldGet(nKod) 
                             oRet:R_TABLE := upper(alltrim(FieldGet(nTbl))) 
                             oRet:N_COUNT := FieldGet(FieldPos("R_COUNT")) 
                             oRet:N_TABLE := RecNo() 
                             EXIT 
                          ENDIF 
                          SKIP 
                       ENDDO 
                       USE 
                       dbSelectArea(nOldA) 
                       Return oRet 
                       } 
  
    o:GetTableStru := {|aVal|                     // get table structure 
                       Local oo := ATail(aVal)    // Self 
                       Local xTabl := aVal[1]     // номер\имя таблицы 
                       Local nOldA, cAls, nPos 
                       Local cFld, cTyp, nLen, nDec, cNam 
                       Local oTbl := oo:Do("GetTable", xTabl) 
                       oTbl:A_STRU  := {} 
                       oTbl:O_FIELD := oHmgData() 
                       IF Empty(oTbl:N_TABLE) ; Return oTbl 
                       ENDIF 
                       nPos  := 0 
                       cAls  := oo:cAlsStru + "_TMP" 
                       nOldA := Select() 
                       USE ( oo:cDbfStru ) ALIAS ( cAls ) NEW SHARED 
                       SET ORDER TO 1 
                       SET SCOPE TO oTbl:R_CODE, oTbl:R_CODE 
                       GO TOP 
                       DO WHILE !EOF() 
                          nPos++ 
                          cFld := alltrim((cAls)->&("R_NAME")) 
                          cTyp := (cAls)->&("R_TYPE") 
                          nLen := (cAls)->&("R_LEN" ) 
                          nDec := (cAls)->&("R_DEC" ) 
                          cNam := alltrim((cAls)->&("F_NAME")) 
                          IF Empty(cFld) ; cFld := "R_" + hb_ntos(nPos) 
                          ENDIF 
                          IF cTyp == "U" ; cTyp := "C" 
                          ENDIF 
                          IF nLen ==  0  ; nLen := 10  
                          ENDIF 
                          AAdd(oTbl:A_STRU, {cFld, cTyp, nLen, nDec, cNam}) 
                          oTbl:O_FIELD:Set(cNam, cFld) 
                          SKIP 
                       ENDDO 
                       USE 
                       dbSelectArea(nOldA) 
                       Return oTbl 
                       } 
  
    o:TablesCount := {|aVal|                           // count(*) in all tables 
                       Local oo := aVal[1]             // Self 
                       Local nRow := 0, cTbl, lErr 
                       FOR EACH cTbl IN oo:aTables 
                           nRow := oo:Do('GetRowCount', cTbl) 
                           oo:oTables:Set(cTbl, nRow) 
                           lErr := nRow < 0 
                           IF lErr ; EXIT 
                           ENDIF 
                       NEXT 
                       Return lErr 
                       } 
  
    o:GetRowCount := {|aVal|                           // count(*) in table 
                       Local nCnt := -1, oo := aVal[2] // Self 
                       Local cTbl := aVal[1] 
                       Local cSql := "SELECT COUNT(*) FROM " 
                       IF oo:lConnect .and. ! oo:lError 
                          oo:lError    := .F. 
                          oo:lErrorSql := .F. 
                          oo:oConnect:SetSql( cSql + cTbl ) 
                          IF oo:oConnect:Open() 
                             nCnt := 0 
                             IF HB_ISARRAY(oo:oConnect:aRecordset) .and. ; 
                                       Len(oo:oConnect:aRecordset) > 0 
                                nCnt := oo:oConnect:aRecordset[1][1] 
                             ENDIF 
                          ELSE 
                             oo:lError    := .T. 
                             oo:lErrorSql := .T. 
                          ENDIF 
                          oo:oConnect:Close() 
                          IF oo:lError ; oo:Do('ErrorAlert') 
                          ENDIF 
                       ENDIF 
                       Return nCnt 
                       } 
  
    o:RowSelect   := {|aVal| 
                       Local oo := ATail(aVal)        // Self 
                       Local cSql := aVal[1]          // 'SELECT ...' 
                       Local cTmp := upper(cSql) 
                       Local oRet := oHmgData() 
                       Local aRec, oFld, nTmp, cTbl 
                       IF ( nTmp := At(" FROM ", cTmp) ) > 0 
                          cTmp := ltrim(subs(cTmp, nTmp + 6)) 
                          cTbl := left(cTmp, At(" ", cTmp) - 1) 
                       ELSE 
                          cTbl := cSql 
                          cSql := "SELECT * FROM " + cSql 
                       ENDIF 
                       oRet:cTbl  := cTbl 
                       oRet:cSql  := cSql 
                       oRet:lErr  := !oo:lConnect 
                       oRet:aArr  := {}   
                       oRet:aFld  := {} 
                       IF oo:lConnect .and. !oo:lError 
                          oo:lError    := .F. 
                          oo:lErrorSql := .F. 
                          oo:oConnect:SetSql( cSql ) 
                          IF oo:oConnect:Open() 
                             FOR EACH oFld IN oo:oConnect:Fields 
                                 AAdd( oRet:aFld, oFld:FieldName ) 
                             NEXT 
                             FOR EACH aRec IN oo:oConnect:aRecordset 
                                 AAdd( oRet:aArr, AClone(aRec) ) 
                             NEXT      
                          ELSE 
                             oo:lError    := .T. 
                             oo:lErrorSql := .T. 
                          ENDIF 
                          oo:oConnect:Close() 
                          IF oo:lError  
                             oRet:lErr := .T. 
                             oRet:aFld := {} 
                             oRet:aArr := {} 
                             oo:Do('ErrorAlert') 
                          ENDIF 
                       ENDIF 
                       Return oRet 
                       } 
  
    o:GetSqlType  := {|aVal|                // sql type -> dbf type 
                       Local nDataType := aVal[1] 
                       Local cType := "U" 
                       SWITCH nDataType 
                       CASE  1           // SQL_CHAR 
                       CASE -8           // SQL_WCHAR 
                       CASE -9           // SQL_WVARCHAR 
                       CASE 12           // SQL_VARCHAR                    
                          cType := 'C' 
                          EXIT 
                       CASE  2           // SQL_NUMERIC 
                       CASE  3           // SQL_DECIMAL 
                       CASE  4           // SQL_INTEGER 
                       CASE  5           // SQL_SMALLINT 
                       CASE  6           // SQL_FLOAT 
                       CASE  7           // SQL_REAL 
                       CASE  8           // SQL_DOUBLE 
                       CASE -5           // SQL_BIGINT 
                       CASE -6           // SQL_TINYINT 
                          cType := 'N' 
                          EXIT 
                       CASE  9           // SQL_DATE           
                       CASE 91           // SQL_TYPE_DATE                    
                          cType := 'D' 
                          EXIT 
                       CASE 11           // SQL_TIMESTAMP                   
                       CASE 93           // SQL_TYPE_TIMESTAMP               
                          cType := 'T' 
                          EXIT 
                       CASE -4           // SQL_BLOB 
                          cType := 'B' 
                          EXIT 
                       ENDSWITCH 
                       Return cType 
                       } 
    // -------------------------------------------------- 
  
    o:oConnect  := TODBC():New( o:cConnect ) 
    o:lConnect  := !Empty( o:oConnect:cODBCRes ) 
    o:lError    := !o:lConnect 
    o:lErrorSql := .F. 
  
    IF o:lError                                // ERROR 
       ? o:cDriver  ; ? "DLL =", hb_FileExists(".\fbclient.dll"), "fbclient.dll" 
       ? o:cConnect ; ? "FDB =", hb_FileExists(o:cBase), o:cBase        
       ? Repl('=', Len(o:cConnect)) 
       AlertStop( o:cError,,,64 ) 
       RETURN o 
    ENDIF 
  
    // Tables list 
    cSql := 'SELECT rdb$relation_name FROM rdb$relations ' + ; 
            'WHERE rdb$view_blr IS null AND ' + ; 
            '(rdb$system_flag IS null OR rdb$system_flag = 0) ORDER BY 1' 
  
    o:oConnect:SetSql( cSql ) 
    IF o:oConnect:Open() 
       FOR EACH aRec IN o:oConnect:aRecordset 
           AAdd( o:aTables, alltrim( aRec[1] ) ) 
       NEXT      
    ELSE 
       o:lError    := .T. 
       o:lErrorSql := .T. 
    ENDIF 
    o:oConnect:Close() 
  
    IF o:lError                             // ERROR 
       cMsg := o:cError 
       IF o:lErrorSql 
          cMsg += CRLF + o:oConnect:SQLErrorMessage() 
          cMsg += CRLF + o:oConnect:cSQL 
       ENDIF 
       AlertStop( cMsg,,,64 ) 
       RETURN o 
    ENDIF 
  
    // Tables structure 
    cSql := 'SELECT FIRST 1 * FROM ' 
    FOR EACH cTbl IN o:aTables 
        o:oConnect:SetSql( cSql + cTbl ) 
        IF o:oConnect:Open() 
           aStru := {} 
           FOR EACH oField IN o:oConnect:Fields 
               aFld    := array(7) 
               aFld[1] := oField:FieldName 
               aFld[2] := o:Do('GetSqlType', oField:DataType) 
               aFld[3] := oField:DataSize 
               aFld[4] := oField:DataDecs  
               aFld[5] := oField:AllowNull 
               aFld[6] := oField:DataSize 
               aFld[7] := oField:DataType 
               IF     aFld[2] == "N" .and. aFld[3] > 18 
                  aFld[3] := 18 
               ELSEIF aFld[2] == "B"  // BLOB or M 
                  aFld[3] := 10 
               ELSEIF aFld[2] == "U" .and. aFld[3] > 999  // ??? 
                  aFld[3] := 10 
               ENDIF 
               AAdd( aStru, aFld ) 
           NEXT 
           o:oFields:Set(cTbl, aStru) 
        ELSE 
           o:lError    := .T. 
           o:lErrorSql := .T. 
        ENDIF 
        o:oConnect:Close() 
  
        IF o:lError ; EXIT                  // ERROR 
        ENDIF 
    NEXT 
  
    IF o:lError                             // ERROR 
       cMsg := o:cError 
       IF o:lErrorSql 
          cMsg += CRLF + o:oConnect:SQLErrorMessage() 
          cMsg += CRLF + o:oConnect:cSQL 
       ENDIF 
       AlertStop( cMsg,,,64 ) 
       RETURN o 
    ENDIF 
  
    // count rows in all Tables 
    o:Do('TablesCount') 
  
    IF lNoDbf .or. ( Select(o:cAlsTabl) > 0 .and. Select(o:cAlsStru) > 0 ) 
       RETURN 0 
    ENDIF 
     
    // create a list of Tables and Structures 
    IF !hb_FileExists(o:cDbfTabl+oac:ExtDbf) .or. !hb_FileExists(o:cDbfStru+oac:ExtDbf) 
       hb_FileDelete(o:cDbfTabl+".*") 
       hb_FileDelete(o:cDbfStru+".*") 
       dbCreate( o:cDbfStru, o:aDbfStru, , .T., o:cAlsStru ) 
       dbCreate( o:cDbfTabl, o:aDbfTabl, , .T., o:cAlsTabl ) 
       FOR EACH cTbl IN o:aTables 
           cKod := StrZero(hb_enumindex(cTbl), 4) 
           nCnt := o:oTables:Get(cTbl, 0) 
           DbSelectArea( o:cAlsTabl )              // Record Tables list 
           dbAppend() 
           AEval({cKod, cTbl, nCnt}, {|x,n| FieldPut(n, x) }) 
           DO EVENTS 
           DbSelectArea( o:cAlsStru )              // Record Structure 
           nFld := FieldPos("F_NAME") 
           FOR EACH aFld IN o:oFields:Get(cTbl) 
               dbAppend() 
               FieldPut(1, cKod) 
               AEval(aFld, {|x,n| FieldPut(n+2, x) }) 
               cFld := Alltrim( FieldGet( nFld ) ) 
               IF Len( cFld ) > 10                    //  имя в F_NAME > 10 
                  dbDelete() 
               ELSE 
                  FieldPut( nFld-1, cFld) 
               ENDIF 
               DO EVENTS 
           NEXT 
       NEXT 
       DbSelectArea( o:cAlsStru ) 
       INDEX ON &("R_CODE") TAG "CODE" 
       GO TOP 
       dbCloseArea() 
       DO EVENTS 
       DbSelectArea(o:cAlsTabl) 
       INDEX ON &("R_CODE") TAG "CODE" 
       GO TOP 
       dbCloseArea() 
       DO EVENTS 
    ENDIF 
  
    USE ( o:cDbfStru ) ALIAS ( o:cAlsStru ) NEW SHARED 
    IF OrdCount() == 0 
       INDEX ON &("R_CODE") TAG "CODE" 
    ENDIF 
    OrdSetFocus(1) 
    GO TOP 
  
    USE ( o:cDbfTabl ) ALIAS ( o:cAlsTabl ) NEW SHARED 
    IF OrdCount() == 0 
       INDEX ON &("R_CODE") TAG "CODE" 
    ENDIF 
    OrdSetFocus(1) 
    GO TOP 
  
 RETURN o 
 

 
 *----------------------------------------------------------------------------* 
 FUNCTION Main(cFile, cUser, cPass, cBclr) 
 *----------------------------------------------------------------------------* 
    LOCAL oTsb1, oTsb2, oac, owc, o 
    LOCAL oFdb, cFdb, cUsr, cPsw, cBrw 
    LOCAL oBrw1, oBrw2, nCnt1, nCnt2, nHtb 
    LOCAL nY, nX, nH, nW, nG, oDlu, lFile  
    LOCAL aBColor := {184, 107, 228}, aBClr 
    LOCAL cForm := "wMain" 
  
    IF !Find_In_Memory("Firebird Guardian")   
       AlertStop( "ERROR!;Firebird program not running!;Exit program",,,64 ) 
       QUIT 
    ENDIF 
  
    //AltD(1) 
    // база для работы Default 
    oac  := App.Cargo 
    cFdb := ".\FDB\Full_Receipt.fdb" 
    cUsr := "SYSDBA"                 
    cPsw := "masterkey" 
    oDlu := App.Object 
  
    IF ( lFile := cFile != NIL ) 
       cFdb := cFile 
       Default cUser := cUsr ; cUsr := cUser 
       Default cPass := cPsw ; cPsw := cPass 
    ENDIF 
  
    WaitWindow( "... Wait for the preparation to complete ...", .T. ) 
  
    IF !Set_Database_For_Work(cFdb, cUsr, cPsw, lFile) // FDB из ini или default 
       QUIT                                            // выход ERROR message была 
    ENDIF 
  
    cFdb  := oac:cBase 
    cUsr  := oac:cUsr 
    cPsw  := oac:cPsw 
    aBClr := oac:aBClr ; Default aBClr := aBColor 
  
    IF !Empty(cBclr) 
       IF left(cBclr, 1) == "{" .and. right(cBclr, 1) == "}" 
          aBClr := &cBclr 
       ENDIF 
    ENDIF 
  
    oac:oFDB := oFDB_Connect( cFdb, cUsr, cPsw ) ; oFdb := oac:oFDB 
  
    IF oFdb:lError ; QUIT             // выход ERROR message уже была 
    ENDIF 
  
    WaitWindow() 
  
    // размеры тсб 1 от dlu единиц  
    nCnt1       := Len( oFdb:aTables ) 
    oTsb1       := oTsb_Size( nCnt1, 4, "Normal", .F., .T., .T., .T. )   
    oTsb1:cForm := cForm 
    oTsb1:oFDB  := oFdb 
    // размеры тсб 2 от dlu единиц  
    nCnt2       := Len( oFdb:aTables ) 
    oTsb2       := oTsb_Size( nCnt2, 9, "Normal", .F., .T., .T., .T. )   
    oTsb2:cForm := cForm 
    oTsb2:oFDB  := oFdb 
    // координаты окна от тсб 
    nG   := oTsb1:nG 
    nHtb := 32        //oDlu:H2 + nG // высота для кнопок 
    nY   := 0 
    nX   := 0 
    nW   := oTsb1:nW + oTsb2:nW + nG * 2 
    nH   := oTsb1:nH + nG * 2 + nHtb 
 ... 
 

 
 *-----------------------------------------------------------------------------* 
 FUNCTION _oWindowDef ( oForm ) 
 *-----------------------------------------------------------------------------* 
  
    LOCAL o := oForm 
  
    Default o:cName  := o:FormName ; Default o:cName  := o:cFormName 
    Default o:cName  := o:Name      
  
    Default o:cTitle := o:Title    ; Default o:cTitle := o:cCaption 
    Default o:cTitle := o:Caption 
  
    Default o:nX := o:Col    ; Default o:nX := o:nCol    ; Default o:nX := o:x 
    Default o:nY := o:Row    ; Default o:nY := o:nRow    ; Default o:nY := o:y 
    Default o:nW := o:Width  ; Default o:nW := o:nWidth  ; Default o:nW := o:w 
    Default o:nH := o:Height ; Default o:nH := o:nHeight ; Default o:nH := o:h 
  
    Default o:nVirtualHeight := o:VirtualHeight 
    Default o:nVirtualHeight := o:VHeight ; Default o:nVirtualHeight := 0 
  
    Default o:nVirtualWidth  := o:VirtualWidth 
    Default o:nVirtualWidth  := o:VWidth  ; Default o:nVirtualWidth  := 0 
  
    Default o:lNoMinimize := o:NoMinimize ; Default o:lNoMinimize := .F. 
    Default o:lNoMaximize := o:NoMaximize ; Default o:lNoMaximize := .F. 
    Default o:lNoSize     := o:NoSize     ; Default o:lNoSize     := .F. 
    Default o:lNoSysmenu  := o:NoSysmenu  ; Default o:lNoSysmenu  := .F. 
    Default o:lNoCaption  := o:NoCaption  ; Default o:lNoCaption  := .F. 
                                                                     
    Default o:lNoHScroll  := o:NoHScroll  ; Default o:lNoHScroll  := .F. 
    Default o:lNoVScroll  := o:NoVScroll  ; Default o:lNoVScroll  := .F. 
    Default o:lFocused    := o:Focused    ; Default o:lFocused    := .F. 
                                                                   
    Default o:aMinSize    := o:MinSize    ; Default o:aMinSize    := o:aMinSize 
    Default o:aMaxSize    := o:MaxSize    ; Default o:aMaxSize    := o:aMaxSize 
                                                                   
    Default o:aBColor     := o:BackColor  ; Default o:aBColor     := o:aBackColor 
                                                                   
    Default o:lNoShow        := o:NoShow  ; Default o:lNoShow     := o:lHide 
    Default o:lNoShow        := o:Hide    ; Default o:lNoShow     := .F. 
    Default o:lTopmost       := o:Topmost ; Default o:lTopmost    := .F. 
    Default o:lPalette       := o:Palette                   
    Default o:lHelpbutton    := o:Helpbutton                
    Default o:lNoAutoRelease := o:NoAutoRelease 
    Default o:lFlashExit     := o:FlashExit 
                              
    Default o:lMdiMain       := o:MdiMain  ; Default o:lMdiMain    := .F. 
    Default o:lMdi           := o:Mdi      ; Default o:lMdi        := .F. 
    Default o:lMain          := o:Main     ; Default o:lMain       := .F. 
    Default o:lChild         := o:Child    ; Default o:lChild      := .F. 
    Default o:lModal         := o:Modal    ; Default o:lModal      := .F. 
    Default o:lPanel         := o:Panel    ; Default o:lPanel      := .F. 
    Default o:lStandard      := o:Standard ; Default o:lStandard   := .F. 
                            
    Default o:cIcon          := o:Icon                      
    Default o:cFontName      := o:FontName                  
    Default o:nFontSize      := o:FontSize 
    Default o:cPanelParent   := o:PanelParent              
    Default o:cCursor        := o:Cursor                    
  
    Default o:cNotifyIconName      := o:NotifyIconName            
    Default o:cNotifyIconTooltip   := o:NotifyIconTooltip         
  
    Default o:bNotifyIconLeftClick := o:NotifyIconLeftClick 
    Default o:bNotifyIconLeftClick := o:bOnNotifyLeftClick      
    Default o:bNotifyIconLeftClick := o:bNotifyClick      
  
    Default o:bNotifyIconDblClick  := o:NotifyIconDblClick 
    Default o:bNotifyIconDblClick  := o:bOnNotifyDblClick 
    Default o:bNotifyIconDblClick  := o:bNotifyDblClick 
  
    Default o:bNotifyBalloonClick  := o:NotifyBalloonClick 
    Default o:bNotifyBalloonClick  := o:bOnNotifyBalloonClick 
    Default o:bNotifyBalloonClick  := o:bBalloonClick 
  
    Default o:bInitProcedure       := o:InitProcedure  
    Default o:bInitProcedure       := o:bOnInitProcedure 
    Default o:bInitProcedure       := o:bOnInit 
    Default o:bInitProcedure       := o:bInit 
  
    Default o:bReleaseProcedure    := o:ReleaseProcedure 
    Default o:bReleaseProcedure    := o:bOnReleaseProcedure 
    Default o:bReleaseProcedure    := o:bOnRelease         
    Default o:bReleaseProcedure    := o:bRelease         
  
    Default o:bMouseDragProcedure  := o:MouseDragProcedure 
    Default o:bMouseDragProcedure  := o:bMouseDragProcedure 
    Default o:bMouseDragProcedure  := o:bOnMouseDrag       
    Default o:bMouseDragProcedure  := o:bMouseDrag       
    Default o:bMouseDragProcedure  := o:bDrag 
  
    Default o:bSizeProcedure       := o:SizeProcedure 
    Default o:bSizeProcedure       := o:bSizeProcedure 
    Default o:bSizeProcedure       := o:bOnSize 
    Default o:bSizeProcedure       := o:bSize 
  
    Default o:bClickProcedure      := o:ClickProcedure 
    Default o:bClickProcedure      := o:bClickProcedure 
    Default o:bClickProcedure      := o:bOnClick 
    Default o:bClickProcedure      := o:bClick 
  
    Default o:bMouseMoveProcedure  := o:MouseMoveProcedure 
    Default o:bMouseMoveProcedure  := o:bMouseMoveProcedure 
    Default o:bMouseMoveProcedure  := o:bOnMouseMove       
    Default o:bMouseMoveProcedure  := o:bMouseMove       
  
    Default o:bPaintProcedure      := o:PaintProcedure 
    Default o:bPaintProcedure      := o:bPaintProcedure 
    Default o:bPaintProcedure      := o:bOnPaint       
    Default o:bPaintProcedure      := o:bPaint       
  
    Default o:bGotFocus  := o:GotFocus     
    Default o:bGotFocus  := o:bOnGotFocus             
    Default o:bGotFocus  := o:bMouseHover 
    Default o:bGotFocus  := o:bHover 
  
    Default o:bLostFocus := o:LostFocus 
    Default o:bLostFocus := o:bOnLostFocus            
    Default o:bLostFocus := o:bMouseLeave 
    Default o:bLostFocus := o:bLeave 
  
    Default o:bMaximizeProcedure := o:MaximizeProcedure 
    Default o:bMaximizeProcedure := o:bOnMaximize 
    Default o:bMaximizeProcedure := o:bMaximize 
  
    Default o:bMinimizeProcedure := o:MinimizeProcedure 
    Default o:bMinimizeProcedure := o:bOnMinimize        
    Default o:bMinimizeProcedure := o:bMinimize        
  
    Default o:bInteractiveCloseProcedure := o:InteractiveCloseProcedure 
    Default o:bInteractiveCloseProcedure := o:bOnInteractiveClose 
    Default o:bInteractiveCloseProcedure := o:bInteractiveClose 
    Default o:bInteractiveCloseProcedure := o:bClose 
  
    Default o:bRestoreProcedure := o:RestoreProcedure 
    Default o:bRestoreProcedure := o:bOnRestore          
    Default o:bRestoreProcedure := o:bRestore  
  
    Default o:bMoveProcedure    := o:MoveProcedure 
    Default o:bMoveProcedure    := o:bOnMove             
    Default o:bMoveProcedure    := o:bMove 
  
    Default o:bDropProcedure    := o:DropProcedure 
    Default o:bDropProcedure    := o:bOnDrop             
    Default o:bDropProcedure    := o:bDrop  
  
    Default o:bScrollLeft       := o:ScrollLeft  
    Default o:bScrollRight      := o:ScrollRight               
    Default o:bScrollUp         := o:ScrollUp                  
    Default o:bScrollDown       := o:ScrollDown                
    Default o:bHScrollBox       := o:HScrollBox                
    Default o:bVScrollBox       := o:VScrollBox                
  
    Default o:nClientWidth      := o:ClientWidth               
    Default o:nClientHeight     := o:ClientHeight              
  
 RETURN oForm 
 

 
 FUNCTION _DefineWindow ( FormName, Caption, x, y, w, h, nominimize, nomaximize, ; 
 ... 
    LOCAL k, op 
 ... 
    IF FormName == NIL 
 ... 
    ELSEIF IsObject( FormName )        // Parameters 
       op := _oWindowDef( FormName )    
  
       FormName   := op:cName 
       Caption    := op:cTitle 
       x := op:nX ; y := op:nY ; w := op:nW ; h := op:nH 
       nominimize                := op:lNoMinimize 
       nomaximize                := op:lNoMaximize 
       nosize                    := op:lNoSize     
       nosysmenu                 := op:lNoSysmenu  
       nocaption                 := op:lNoCaption  
       aMin                      := op:aMinSize 
       aMax                      := op:aMaxSize 
       InitProcedure             := op:bInitProcedure 
       ReleaseProcedure          := op:bReleaseProcedure 
       MouseDragProcedure        := op:bMouseDragProcedure 
       SizeProcedure             := op:bSizeProcedure 
       ClickProcedure            := op:bClickProcedure 
       MouseMoveProcedure        := op:bMouseMoveProcedure 
       aRGB                      := op:aBColor 
       PaintProcedure            := op:bPaintProcedure 
       noshow                    := op:lNoShow  
       topmost                   := op:lTopmost 
       main                      := op:lMain 
       icon                      := op:cIcon 
       child                     := op:lChild 
       fontname                  := op:cFontName 
       fontsize                  := op:nFontSize 
       NotifyIconName            := op:cNotifyIconName    
       NotifyIconTooltip         := op:cNotifyIconTooltip 
       NotifyIconLeftClick       := op:bNotifyIconLeftClick 
       GotFocus                  := op:bGotFocus 
       LostFocus                 := op:bLostFocus 
       VirtualHeight             := op:nVirtualHeight 
       VirtualWidth              := op:nVirtualWidth 
       scrollleft                := op:bScrollLeft  
       scrollright               := op:bScrollRight 
       scrollup                  := op:bScrollUp    
       scrolldown                := op:bScrollDown  
       hscrollbox                := op:bHScrollBox  
       vscrollbox                := op:bVScrollBox  
       helpbutton                := op:lHelpButton 
       MaximizeProcedure         := op:bMaximizeProcedure 
       MinimizeProcedure         := op:bMinimizeProcedure 
       cursor                    := op:cCursor 
       NoAutoRelease             := op:lNoAutoRelease 
       InteractiveCloseProcedure := op:bInteractiveCloseProcedure 
       RestoreProcedure          := op:bRestoreProcedure 
       MoveProcedure             := op:bMoveProcedure 
       DropProcedure             := op:bDropProcedure 
       mdi                       := op:lMdi 
       palette                   := op:lPalette 
       NotifyIconDblClick        := op:bNotifyIconDblClick 
       cPanelParent              := op:cPanelParent 
       panel                     := op:lPanel 
       NotifyBalloonClick        := op:bNotifyBalloonClick 
       clientwidth               := op:nClientWidth  
       clientheight              := op:nClientHeight 
  
    ENDIF 
 ... 
 FUNCTION _DefineModalWindow ( FormName, Caption, x, y, w, h, Parent, nosize, nosysmenu, nocaption, aMin, aMax, ; 
 ... 
    LOCAL k, op 
 ... 
    IF FormName == NIL 
       FormName := _HMG_TempWindowName 
  
    ELSEIF IsObject( FormName ) 
       op := _oWindowDef( FormName )   // Parameters 
  
       FormName   := op:cName 
       Caption    := op:cTitle 
       x := op:nX ; y := op:nY ; w := op:nW ; h := op:nH 
       Parent                    := op:cParent 
       nosize                    := op:lNoSize     
       nosysmenu                 := op:lNoSysmenu  
       nocaption                 := op:lNoCaption  
       aMin                      := op:aMinSize 
       aMax                      := op:aMaxSize 
       InitProcedure             := op:bInitProcedure       
       ReleaseProcedure          := op:bReleaseProcedure    
       MouseDragProcedure        := op:bMouseDragProcedure  
       SizeProcedure             := op:bSizeProcedure       
       ClickProcedure            := op:bClickProcedure      
       MouseMoveProcedure        := op:bMouseMoveProcedure  
       aRGB                      := op:aBColor              
       PaintProcedure            := op:bPaintProcedure 
       icon                      := op:cIcon 
       FontName                  := op:cFontName 
       FontSize                  := op:nFontSize 
       GotFocus                  := op:bGotFocus      
       LostFocus                 := op:bLostFocus     
       VirtualHeight             := op:nVirtualHeight 
       VirtualWidth              := op:nVirtualWidth  
       scrollleft                := op:bScrollLeft    
       scrollright               := op:bScrollRight   
       scrollup                  := op:bScrollUp      
       scrolldown                := op:bScrollDown    
       hscrollbox                := op:bHScrollBox    
       vscrollbox                := op:bVScrollBox    
       helpbutton                := op:lHelpButton    
       cursor                    := op:cCursor 
       noshow                    := op:lNoShow  
       NoAutoRelease             := op:lNoAutoRelease 
       InteractiveCloseProcedure := op:bInteractiveCloseProcedure 
       MoveProcedure             := op:bMoveProcedure 
       DropProcedure             := op:bDropProcedure 
       clientwidth               := op:nClientWidth  
       clientheight              := op:nClientHeight 
       flashexit                 := op:lFlashExit 
  
    ENDIF 
 ... 
 для h_windowsMdi.prg 
 FUNCTION _DefineChildMDIWindow ( FormName, x, y, w, h, nominimize, nomaximize, ; 
 ... 
    LOCAL FormHandle , ChildIndex, op 
 ... 
    IF FormName == NIL 
       FormName := _HMG_TempWindowName 
  
    ELSEIF IsObject( FormName ) 
       op := _oWindowDef( FormName )   // Parameters 
  
       FormName   := op:cName 
       title      := op:cTitle 
       x := op:nX ; y := op:nY ; w := op:nW ; h := op:nH 
       nominimize                := op:lNoMinimize 
       nomaximize                := op:lNoMaximize 
       nocaption                 := op:lNoCaption  
       novscroll                 := op:lNoVScroll 
       nohscroll                 := op:lNoHScroll 
       FontName                  := op:cFontName 
       FontSize                  := op:nFontSize 
       initprocedure             := op:bInitProcedure    
       ReleaseProcedure          := op:bReleaseProcedure 
       ClickProcedure            := op:bClickProcedure 
       GotFocus                  := op:bGotFocus  
       LostFocus                 := op:bLostFocus 
       SizeProcedure             := op:bSizeProcedure 
       maximizeprocedure         := op:bMaximizeProcedure 
       minimizeprocedure         := op:bMinimizeProcedure 
       focused                   := op:lFocused 
       cursor                    := op:cCursor 
       InteractiveCloseProcedure := op:bInteractiveCloseProcedure 
       MouseMoveProcedure        := op:bMouseMoveProcedure 
  
    ENDIF 
 ...