PROCEDURE main 
  
    Exm_MSExcel() 
  
    RETURN 
  
 STATIC PROCEDURE Exm_MSExcel() 
    LOCAL oExcel, oWorkBook, oWorkSheet, oAS 
  
    IF ( oExcel := win_oleCreateObject( "Excel.Application" ) ) != NIL 
  
       oWorkBook := oExcel:WorkBooks:Add() 
       oAS := oExcel:ActiveSheet() 
  
       WITH OBJECT oAs 
       // Set font for all cells 
          :Cells:Font:Name := "Arial" 
          :Cells:Font:Size := 12 
  
          :Cells( 1, 1 ):Value := "OLE from Harbour" 
          :Cells( 1, 1 ):Font:Size := 16 
  
          :Cells( 3, 1 ):Value := "String:" 
          :Cells( 3, 2 ):Value := "Hello, World!" 
          :Cells( 4, 1 ):Value := "Numeric:" 
          :Cells( 4, 2 ):Value := 1234.56 
          :Cells( 5, 1 ):Value := "Logical:" 
          :Cells( 5, 2 ):Value := .T. 
          :Cells( 6, 1 ):Value := "Date:" 
          :Cells( 6, 2 ):Value := DATE() 
          :Cells( 7, 1 ):Value := "Timestamp:" 
          :Cells( 7, 2 ):Value := HB_DATETIME() 
  
          // Some formatting 
          :Columns( 1 ):Font:Bold := .T. 
          :Columns( 2 ):HorizontalAlignment := -4152  // xlRight 
  
          :Columns( 1 ):AutoFit() 
          :Columns( 2 ):AutoFit() 
          :Columns( 3 ):AutoFit() 
          :Columns( 4 ):AutoFit() 
  
          :Cells( 3, 2 ):Font:ColorIndex := 3  // red 
  
          :Range( "A1:B1" ):HorizontalAlignment := 7 
          :Range( "A3:B7" ):Select() 
  
          :Range( "A3:B7" ):Sort( oAS:Range("A4"), 1 /*xlAscending*/ ) 
       ENDWITH 
  
       oAs:Protect( "password" ) 
       //oAs:UnProtect( "password" ) 
  
       oExcel:Visible := .T. 
  
       //oExcel:Quit() 
    ELSE 
       ? "Error: MS Excel not available. [" + win_oleErrorText()+ "]" 
    ENDIF