////////////////////////////////////////////////////////////////////// 
 FUNCTION MyCreateNewXls(cFileName) 
    LOCAL nI, oExcel, nVerExcel, oWorkBook, oSheet, cMsg, nErr 
    LOCAL nLine, nCount, aDim, cFont, nFSize, cType, xValue, nDecVal 
  
    IF ! IsExcelFound()   // check for Excel on your computer 
       RETURN .F. 
    ENDIF 
  
    IF FILE( cFileName ) 
       nErr := DELETEFILE(cFileName) 
       IF nErr # 0 
          cMsg := REPLICATE( "-._.", 16 ) + ";;" 
          cMsg += "Ошибка удаления файла: "+cFileName+" !; Ошибка №: "+HB_NtoS(nErr)+";;" 
          cMsg += "Файл занят другим процессом в памяти !;;" 
          cMsg += REPLICATE( "-._.", 16 ) + ";;" 
          cMsg := AtRepl( ";", cMsg, CRLF ) 
          MsgStop( cMsg , "Error!" ) 
          RETURN .F. 
       ENDIF 
    ENDIF 
  
    oExcel := TOleAuto():New( "Excel.Application" ) 
    oExcel:Visible := .F.  
    oExcel:DisplayAlerts := .F.  
  
    nVerExcel := VAL( oExcel:Version )    
    oWorkBook := oExcel:WorkBooks:Add()   
  
    oSheet := oExcel:ActiveSheet() 
    cFont := "Arial" ;  nFSize := 12   
    oSheet:Cells:Font:Name := cFont 
    oSheet:Cells:Font:Size := nFSize 
  
    nLine  := 3   
    nCount := 7   
    // ------- table header --------------- 
    oSheet:Cells( 1, 1 ):Value := "Test table for converting Xls to Csv" 
    oSheet:Cells( 1, 1 ):Font:Size := nFSize 
    // Combine the cells of the selected range from 1 to nCount into one cell 
    oSheet:Range(oSheet:cells(1,1),oSheet:cells(1,nCount)):MergeCells:=.t.  
    oSheet:Cells( 1, 1 ):HorizontalAlignment := xlCenter  
  
    DO WHILE .T. 
  
       aDim := { DATE(), "901010"+HB_NtoS(10+nLine), "001", "Street", "11A" , HB_NtoS(nLine), 100-(nLine*1.5) } 
  
       FOR nI := 1 TO LEN(aDim) 
          cType   := VALTYPE(aDim[nI]) 
          xValue  := aDim[nI]   
         
          IF cType == "D" 
             oSheet:Cells( nLine, nI ):SET( "NumberFormat", "@" )  
          ELSEIF cType == "N" 
             nDecVal := xValue - INT(xValue)    
             IF nDecVal == 0   // значит целое число 
                oSheet:Cells( nLine, nI ):SET( 'NumberFormat', '## ### ###0' )  
             ELSE  
                oSheet:Cells( nLine, nI ):SET( 'NumberFormat', '## ### ###0,00' )  
             ENDIF 
          ELSE 
             oSheet:Cells( nLine, nI ):SET( "NumberFormat", '@' )  
          ENDIF 
          oSheet:Cells( nLine, nI ):Value := xValue 
          oSheet:Cells( nLine, nI ):Borders():LineStyle := 1 
         
       NEXT 
  
       nLine ++ 
       IF nLine > 103  
          EXIT 
       ENDIF 
  
       DO EVENTS  // ALWAYS! To make the form NOT freeze 
  
    ENDDO 
  
    oSheet:Cells( nLine+1, 1 ):Value := "End table" 
  
    oWorkBook:SaveAs( cFileName, xlWorkbookNormal )  // строка 105 
    oExcel:Quit() 
  
    RETURN .T.