* ---------------- * 
 FUNC KeyDriver(nKey) // обработчик всех кнопок в программе! 
  
 STATIC context_active  := FALSE 
 STATIC show_map_active := FALSE 
 STATIC lost_focus      := FALSE 
  
 LOCAL i,tmp  
  
  // 
  IF lost_focus               // фокус потерян ? 
   IF (nKey == HB_K_GOTFOCUS) // но вдруг вернулся ? 
    REPEAT                    // обнуляем все последующие  
    UNTIL INKEY()==0          // нажатия кнопок или мыши 
    lost_focus := FALSE       // восстанавливаем норм.работу 
   ENDIF  
   RETURN 0 
  ENDIF 
  // 
  SWITCH nKey 
  // 
  CASE K_LBUTTONDOWN             // левая кнопка мыши ? 
   // 
   IF (MROW() == 0) .AND. (MCOL() >= MAXCOL()-2)  // переключатель Rus/Lat ? 
    KbdFlip()                             // переключаем клаву 
    nKey := 0 
   ELSE 
    nKey := MouseFixLDown()       // фиксируем нажатие, засекаем время, игнорируем 
   ENDIF 
   EXIT 
  
  CASE K_LBUTTONUP               // отпускание кнопки будем интерпретировать 
   nKey := MouseFixLUp()         // в зависимости от времени, сколько она была нажата 
   IF (nKey == K_CTRL_V) .OR. ;  // нужна доп. обработка на случай Copy/Paste из буфера ? 
      (nKey == K_CTRL_C) 
    nKey := KeyDriver(nKey)      // recursive call ! 
   ENDIF 
   EXIT 
  
  CASE K_MWFORWARD               // прокрутка колесика вперед ? 
   IF ShiftPressed()             // ускоряем 
    PutInKbd({K_UP,K_UP,K_UP}) 
   ELSEIF CtrlPressed()          // еще больше ускоряем 
    PutInKbd({K_UP,K_UP,K_UP,K_UP,K_UP,K_UP,K_UP,K_UP,K_UP,K_UP}) 
   ENDIF 
   nKey := K_UP 
   EXIT 
  
  CASE K_MWBACKWARD              // тоже самое, но назад 
   IF ShiftPressed() 
    PutInKbd({K_DOWN,K_DOWN,K_DOWN}) 
   ELSEIF CtrlPressed() 
    PutInKbd({K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN,K_DOWN}) 
   ENDIF 
   nKey := K_DOWN 
   EXIT 
    
  CASE K_INS                            // проверяем на вставку из буфера 
   IF CtrlPressed() .OR. ShiftPressed() // Shift+Ins или Ctrl+V ? 
    hb_GtInfo( HB_GTI_CLIPBOARDPASTE ) 
    nKey := 0                           // остальное не нужно 
   ENDIF 
   EXIT 
  
  CASE K_CTRL_C                  // K_CTRL_C пересекается с K_PGDN ! 
   IF CtrlPressed()              // поэтому тут нужна доп. проверка 
    IF GetActive() != NIL 
     hb_gtInfo( HB_GTI_CLIPBOARDDATA, ALLTRIM(Transform(GetActive():VarGet(),""))) 
     RETURN 0 
    ENDIF 
   ENDIF 
   EXIT 
   // 
  CASE K_LDBLCLK                 // двойной щелчок левой кнопкой 
   mouse_ldown_on  := FALSE      // выключаем слежение за scroll 
   nKey := MouseMapCheck(nKey)   // обрабтываем, как обычно, с учетом зон 
   EXIT 
   // 
  CASE K_MDBLCLK                 // двойной щелчок колесиком мыши - тест 
   IF show_map_active 
    TONE(200,1) 
   ELSE 
    show_map_active := TRUE 
    MouseMap("show_all") 
    show_map_active := FALSE 
   ENDIF 
   nKey := 0 
   EXIT 
  
  CASE K_MMLEFTDOWN              // мышь движется c зажатой левой кнопкой ? 
   // mouse_ldown_on := FALSE    // в дальнейшем проигнорируем обычное нажатие 
                                 // слишком "нервно", чуть двинулся и ппц... 
                                 // скинем флаг только после того, как зафиксируем движуху 
   nKey := MouseFixMove(nKey)    // обрабатываем как scroll 
   EXIT 
  
  CASE K_MOUSEMOVE               // мышь движется ? 
   nKey := 0                     // игнорируем 
   EXIT 
  
  CASE K_RBUTTONDOWN 
   IF context_active             // выключить меню на старом месте 
    PutInKbd(K_RBUTTONDOWN)      // и включить на новом 
    nKey := K_CONTEXT_OFF        // подменяем кнопку, чтобы выключить меню 
   ELSE                          // включить контекстное меню 
    context_active:=TRUE 
    i:=MouseContextMenu()        // включаем  
    context_active:=FALSE 
    nKey := i                    // возвращем кнопку, нажатую юзером 
   ENDIF 
   EXIT 
  
  CASE HB_K_CLOSE                // закрытие окна приложения? 
   nKey := K_ESC                // игнорируем, типа выход из тек.диалога 
   EXIT 
  
  CASE HB_K_LOSTFOCUS            // потеря фокуса? (GTWVT only) 
   lost_focus := TRUE 
   nKey := 0 
   EXIT 
  
  CASE HB_K_GOTFOCUS             // восстановление фокуса? (GTWVT only) 
   lost_focus := FALSE           // скорее всего, никогда не попадет сюда 
   nKey := 0                     // из-за проверки до SWITCH 
   EXIT 
  
  CASE 44                        // запятая - мешает набору цифр на клавиатуре справа! 
   IF KbdIsRus() .AND. !ShiftPressed() 
    nKey := 46                   // сразу заменяем на точку 
   ENDIF 
   EXIT 
  
  END // SWITCH 
  
 RETURN nKey // process as usual