* =========================================================================== 
 *   Просмотр файлов неограниченной длины. Адаптация под стиль Жукова Андрея 
 *   программы Станислава Кросмана, а также исправление логических ошибок. 
 *   !!! Для xHarbour не удалось заставить работать - заменил редактированием. 
 * =========================================================================== 
 #include "function.ch" 
  
 #define ATNUM(d,c,b,e)          IF(At(d,Subs(c,e+1))==0,0,At(d,Subs(c,e+1))+nPointer-1) 
  
 * #define BUFFER 4096             // Размер считываемого в начале буфера 
 * #define BUFFER2 2048            // Размер считываемого куска файла 
 * #define CRITICAL_LENTH 256      // Размер максимальной длины строки 
  
 ****    09.2001 Переделал старые установки т.к. вылетал при просмотре больших файлов 
 ****    после чего программа стала работать более стабильно. 
 ****    ? Не понятно как повлияли данные размеры и почему. Память ОЗУ не менялась. 
 #define BUFFER 2048             // Размер считываемого в начале буфера 
 #define BUFFER2 1024            // Размер считываемого куска файла 
 #define CRITICAL_LENTH 512      // Размер максимальной длины строки 
  
 STAT   nH                       // handler файла 
 STAT   nPointer                 // Указатель в файле 
  
 // Флаг позиции в файле(0-достигнуто начало файла,1-внутри файла,2-достигнут конец файла) 
 STAT   nFl_pos 
 STAT   cStr                     // Строка-буфер 
 STAT   nStrPoint:=1             // Указатель в строке 
  
 // Флаг позиции в строке-буфере(0-начало строки,1-внутри строки,2-достигнут конец строки) 
 STAT   nFf_pos 
 STAT   lFl_direction            // Направление последнего перемещения 
 STAT   nLenFile                 // Длина текстового файла. 
  
 // Отладочный пример. Даем параметры и вызываем функцию просмотра 
 PROC M__12__34_(); SET SCOR OFF; Wboard(); CLS; lLookFile("LOOPFILE.PRG",1,2,22,73,"RG+/B") 
     RETU 
  
 /* 
     Функция просмотра текстовых файлов неогран.длины при помощи обьекта-таблицы. 
     Параметры: Имя файла, координаты окна, цвет отображения текста. 
     Возврашает значиние ложь при обнаружении ошибки. 
 */ 
 FUNC lLookFile( cFile, nX, nY, nDx, nDy, cCol ) 
     LOCA x:=2, y:=2, x1:=nX+nDx-2, y1:=nY+nDy-2, nOldCur:=SetCursor() 
     LOCA cOldCol:=SetColor(), oB, oC, ik:=0 // Обьекты 
     PRIV GetList:={} 
     DEFAULT nX TO 0, nY TO 0, nDx TO 24, nDy TO 79, cCol TO "W/N" 
  
     fSwopen( nX, nY, nDx, nDy, cCol, 4 ) 
     @ 0,nY+nDy-42 SAY " Home-начало End-конец строки Esc - выход " 
     SetCursor( 0 ) 
  
     nH  := Fopen(cFile, FO_READ)            // Просматриваемый файл только для чтения 
     IF nH == -1 THEN RETU FALSE             // Ошибка при открытии файла. 
     nLenFile    := Fseek( nH, 0, FS_END)    // Вымеряем длину файла. 
  
     Go_home()                       // Устанавливаем указатель на начало файла 
  
     oB  := TBrowseNew(x, y, x1, y1) 
  
     //      Блоки кода перемещения по сканируемой строке. 
     oB:goTopBlock   := {|| Go_home() } 
     oB:goBottomBlock:= {|| Go_end() } 
     oB:skipBlock    := {|nSkip| Skipp(nSkip) } 
  
     // Колонка - извлеченная из строки буфера строка. 
     oC      := tbColumnNew("",{|| Take_str() }) // Пока без заголовка колонки. 
     oC:width:= y1 - y + 1 
     oB:addColumn( oC ) 
     oB:autolite := FALSE    // Не выделять текущую строку в процессе стабилизации. 
  
     // Начало обработки табличного обьекта. 
     WHIL TRUE 
         DispBegin() 
         WHIL !oB:stabilize() .AND. NextKey()==0 // Выполняем цикл стабилизации 
         ENDD 
         @ 0,1 SAY " "+IF(nFl_pos==0,"  0",IF(nFl_pos==2,"100",cProc()))+"% " 
         DispEnd() 
         IF ( ik:=Inkey(0) ) == K_ESC THEN EXIT 
  
         DO CASE                 // Обрабатываем нажатую клавишу. 
         CASE ik == K_LEFT 
             IF nStrPoint > 1    // Можно перемещаться еще влево. 
                 nStrPoint-- 
                 oB:refreshAll() 
             ENDI 
         CASE ik == K_RIGHT      // След. можно уходить за границу текста 256 знаков. 
             nStrPoint++ 
             oB:refreshAll() 
         CASE ik == K_PGDN 
             oB:rowPos   := oB:rowCount  // Текущая строка = количеству видим.строк 
             IF !oB:hitBottom    THEN oB:pageDown() 
         CASE ik == K_PGUP 
             oB:rowPos   := 1 
             IF !oB:hitTop       THEN oB:pageUp() 
         CASE ik == K_UP 
             oB:rowPos   := 1 
             oB:up(); oB:up() 
         CASE ik == K_DOWN 
             oB:rowPos   := oB:rowCount 
             oB:down(); oB:down() 
         CASE ik == K_CTRL_PGUP 
             IF !oB:hitTop       THEN oB:goTop() 
         CASE ik == K_HOME 
             IF nStrPoint <> 1 
                 nStrPoint   := 1 
                 oB:refreshAll() 
             ENDI 
         CASE ik == K_CTRL_PGDN 
             IF !oB:hitBottom    THEN oB:goBottom() 
         CASE ik == K_END 
             nStrPoint   += Max(0,60-nStrPoint) 
             oB:refreshAll() 
 *            oB:panEnd()    //  Эта запись вместо двух была в оригинале текста. 
         ENDC 
     END 
  
     Fclose( nH )            // Закрываем файл 
     fDeact( cOldCol )       // Закрываем окно. 
     SetCursor( nOldCur ) 
     RETU TRUE 
  
 /* 
         Начальное считывание из файла и перерисовка экрана. 
 */ 
 STAT FUNC Go_home() 
     nPointer    := 1                // Указатель в просматриваемом файле. 
     nFl_pos     := nFf_pos  := 0    // Позиция в буфере и файле. 
     lFl_direction           := TRUE // Направление последнего перемещения. 
  
     Fseek( nH, 0, FS_SET )          // Позиционируемся в начало файла. 
     cStr        := FreadStr( nH, BUFFER )   // Начальное чтение 
     RETU NIL 
  
 /* 
     Чтение с конца файла символов согласно размеру буфера и установ параметров 
 */ 
 STAT FUNC Go_end() 
     LOCA nI:=0, nJ := Fseek( nH, 0, FS_END)     // Вымеряем длину файла. 
  
     Fseek( nH, -Min(BUFFER,nJ), FS_END )        // От какого места берем в буфер 
     cStr    := FreadStr( nH, Min(BUFFER,nJ) )   // Считали в сканируюмую строку 
     Fseek( nH, 0, FS_END )                      // Ушли на конец файла. 
  
     nI      := Rat( CRLF, cStr ) 
     nPointer:= IF(/*есть еще знак конца строки CRLF*/ nI<>0, nI+2, 1 ) 
     nFl_pos := nFf_pos  := 2    // Признаки достижения конца строки и файла. 
     lFl_direction       := TRUE 
     RETU NIL 
  
 /* 
     Перемещение по таблице на nN строк. Направление зависит от знака nN. 
 */ 
 STAT FUNC Skipp( nN ) 
     LOCA nI := 0 
  
     IF nN >= 0  // Перемещение вниз по таблице 
          FOR nI:=1 TO nN 
             IF !Skipp_down()    THEN nN := nI-1 // Достигнут конец файла. 
          NEXT nI 
     ELSE        // Перемещаемся вверх по таблице. 
          nN := -nN 
          FOR nI:=1 to nN 
             IF !Skipp_up()      THEN nN := nI-1 // Достижение начала файла. 
          NEXT nI 
          nN := -nN 
     ENDI 
     RETU nN     // На сколько сумели сдвинуться. 
  
 /* 
         Перемещение на одну строку вниз по таблице (строке-буфере,файлу). 
 */ 
 STAT FUNC Skipp_down() 
     LOCA nI := ATNUM( CRLF, cStr, 1, nPointer-1 ) 
  
     IF nFl_pos == 2 THEN RETU FALSE // Ранее достигли конца файла. 
  
     // Необходима подкачка в буферную строку и есть для этого возможность. 
     IF nI == 0/*нет строк вывода*/ .AND. nFf_pos <> 2 /*находимся внутри файла*/ 
         Driver( TRUE )  // Читаем вниз по файлу. Пополняем cStr. 
         nI  := ATNUM(CRLF,cStr,1,nPointer-1) 
     ENDI 
  
     // Дальше некуда. Из файла считали все до самого его конца. 
     IF nI == 0 THEN nFl_pos:=2/*достигли конца файла*/; RETU FALSE 
  
     nPointer    := nI+2 // Перемещаем указатель 
     nFl_pos     := 1    // Шагаем внутри файла. 
     RETU TRUE 
  
 /* 
         Перемещение на одну строку вверх по таблице (строке-буферу,файлу) 
 */ 
 STAT FUNC Skipp_up() 
     LOCA nI := 0 
  
     IF nFl_pos == 0 THEN RETU FALSE             // Уже в начале строки. 
  
     nI  := Rat( CRLF, Left(cStr,nPointer-2) )   // Последнее вхождение CRLF 
     IF nI == 0 .AND. nFf_pos <> 0   // Нужна и возможна подкачка из файла. 
         Driver(FALSE)    // Читаем вверх. 
         nI   := Rat( CRLF, Left(cStr,nPointer-2) ) 
     ENDI 
  
     IF  nI == 0     // Более читать нечего. Достигли самого начала файла. 
         nPointer := 1 
         nFl_pos  := 0 
         RETU TRUE   // При след.вызове проанализирует nFl_pos 
     ENDI 
  
     nPointer    := nI+2 
     nFl_pos     := 1 
     RETU TRUE 
  
 /* 
     Возвращает строку просмотра в табличный обьект. 
 */ 
 STAT FUNC Take_str() 
     LOCA cSss:="", nI:=ATNUM( CRLF, cStr, 1, nPointer-1 ) 
  
     // Нет отдельной строки, а подкачать можно т.к. не достигнут конец файла. 
     IF (nI==0) .AND. (nFf_pos <> 2) 
        Driver( TRUE )   // Подкачиваем из буфера в cStr и изменяем указатель nPointer. 
        nI   := ATNUM( CRLF, cStr, 1, nPointer-1 ) 
     ENDI 
  
     IF nI == 0  // Более нет текстовых строк ниже указателя. 
         cSss    := Subs( Subs(cStr,nPointer), nStrPoint ) 
     ELSE 
         cSss    := Subs( Subs(cStr,nPointer,nI-nPointer), nStrPoint ) 
     ENDI 
     nI      := At(CRLF,cSss) 
     cSss    := Left( cSss+Spac(CRITICAL_LENTH), CRITICAL_LENTH )+CRLF 
     RETU cSss   //tabexpand(sss) 
  
 /* 
     Драйвер подкачки из текстового файла в сканируемую строку. Параметр 
     определяет направление просмотра. Истина читаем текст вниз по файлу. 
 */ 
 STAT FUNC Driver( lPar ) 
     LOCA cBuf:="", nI:=0, nJ:=0, nK:=0, nL:=0 
  
     nFf_pos := 1    // Просмотр производится внутри строки. 
  
     IF lPar .AND. nFf_pos <> 2  // Смотрим вниз, но конца файла не достигли. 
         IF !lFl_direction       // Идем в конец. 
             Fseek( nH, Len(cStr), FS_RELATIVE ) // С текущего места. 
             lFl_direction   := TRUE 
         ENDI 
         IF Len( cBuf:=FreadStr(nH,BUFFER2) ) <> BUFFER2 THEN nFf_pos:=2 
  
         cStr        := Right( cStr, Len(cStr) - Len(cBuf) ) + cBuf 
         nPointer    -= Len(cBuf) 
         // nPointer    += Len(cBuf) 
  
     ELSEIF nFf_pos <> 0         // Нет еще начала файла. Просмотр идет вверх. 
         IF lFl_direction        // Идем в начало файла. 
             Fseek( nH, -Len(cStr), FS_RELATIVE ) 
             lFl_direction   := FALSE 
         ENDI 
         nI  := Fseek( nH, -Min((nL:=Fseek(nH,0,FS_RELATIVE)),BUFFER2), FS_RELATIVE) 
         IF nI == 0  // Дальше некуда. 
             nFf_pos := 0 
             nJ      := nL - nI 
         ELSE 
             nJ      := BUFFER2 
         ENDI 
         /* 
             nJ - реальное значение, на которое удалось передвинуться, 
             nL - старое значение указателя в файле, 
             считываем строку 
         */ 
         cBuf    := FreadStr( nH, nJ ) 
         Fseek( nH, nI, FS_SET ) 
  
         cStr    := cBuf+Left(cStr,Len(cStr)-nJ) // корректируем строку 
         nPointer+=nJ 
     ENDI 
     RETU NIL 
  
 /* 
    Расчет и возврат процента прочтения текста из файла по статическим переменным 
 */ 
 STAT FUNC cProc() 
     LOCA nCur := Fseek( nH, 0, FS_RELATIVE ) 
     RETU Str( zInt(nCur*100/nLenFile), 3 )