*-----------------------------------------------------------------------* 
 FUNCTION myDbStruMod( aStru, cFile )    
 *-----------------------------------------------------------------------* 
  LOCAL i, cAls, cNew, cExt, nOld := select() 
  
  If Empty( cFile ) .or. !myDbUse( cFile ) 
     dbSelectArea(nOld) 
     RETURN .F. 
  EndIf 
  
  cAls := Alias() 
  cNew := hb_FNameExtSet( lower(dbInfo(DBI_FULLPATH)), "" ) + '_new_stru'  
  cExt := lower(dbInfo(DBI_TABLEEXT)) 
  
  USE 
  
  i := Set( _SET_DELETED, .F. ) 
  
  dbCreate( cNew, aStru, , .T., cAls+'_NEW' ) 
  APPEND FROM ( cFile ) 
  GO TOP 
  USE 
  
  Set( _SET_DELETED, i ) 
  
  fErase( hb_FNameExtSet(cFile, IndexExt()) ) 
  If ( i := empty(fErase( cFile )) ) 
     i := empty(fRename( cNew + cExt, cFile )) 
  EndIf 
  If ! i 
     fErase( cNew + cExt ) 
     dbSelectArea(nOld) 
     RETURN .F. 
  EndIf 
  
  dbSelectArea(nOld) 
  
 RETURN .T. 
  
 *-----------------------------------------------------------------------* 
 FUNCTION myDbUse( cDbf, cAls, lShared, cRdd, nWhl ) 
 *-----------------------------------------------------------------------* 
    LOCAL lRet := .F., nOld := Select() 
    DEFAULT lShared TO .T., nWhl TO 10 
  
    cDbf := hb_FNameExtSet( cDbf, ".dbf" ) ; NetErr( .F. ) 
  
    IF !hb_FileExists(cDbf) ; RETURN lRet 
    ENDIF 
  
    SELECT 0 
    IF     empty (cAls)     ; cAls := '_XYZ_'+hb_ntos(select()) 
    ELSEIF select(cAls) > 0 ; cAls += '_'    +hb_ntos(select()) 
    ENDIF 
  
    DO WHILE nWhl-- > 0 
       lRet := .F. 
       BEGIN SEQUENCE WITH { |e|break(e) } 
          DbUseArea( .F., cRdd, cDbf, cAls, lShared ) 
          lRet := ! NetErr() .and. Used() 
       END SEQUENCE 
       IF lRet; EXIT 
       ENDIF 
       wApi_Sleep(100) 
    ENDDO 
  
    IF lRet 
       If OrdCount() > 0 ; OrdSetFocus(1) 
       EndIf 
       dbGoTop() 
    ELSE 
       dbSelectArea(nOld) 
    ENDIF 
  
 RETURN lRet 
  
 *-----------------------------------------------------------------------* 
 FUNCTION myStruAddFields(aStru, aFields, nPos)  
 *-----------------------------------------------------------------------* 
    LOCAL oStru := oHmgData(), aField 
    Default nPos := 0  // insert before position if nPos > 0 
  
    IF !hb_IsArray(aFields[1]) ; aFields := { aFields } 
    ENDIF 
  
    IF nPos > 0 
       FOR EACH aField IN aStru 
           IF hb_enumIndex(aField) == nPos 
              AEval(aFields, {|a| oStru:Set(a[1], aClone(a)) }) 
           ELSE 
              oStru:Set(aField[1], aField) 
           ENDIF 
       NEXT 
    ELSE 
       AEval(aStru  , {|a| oStru:Set(a[1], a) }) 
       AEval(aFields, {|a| oStru:Set(a[1], a) }) 
    ENDIF 
  
 RETURN oStru:Values() 
  
 *-----------------------------------------------------------------------* 
 FUNCTION myStruDelFields(aStru, cFields)  
 *-----------------------------------------------------------------------* 
    LOCAL aField, aStruNew := {} 
  
    cFields := "," + upper(StrTran(cFields, " ", "")) + "," 
  
    FOR EACH aField IN aStru 
        IF ! ","+aField[1]+"," $ cFields 
           AAdd(aStruNew, aField) 
        ENDIF 
    NEXT 
  
 RETURN aStruNew 
  
 *-----------------------------------------------------------------------* 
 FUNCTION myDbDelFields(cFile, cFields)   
 *-----------------------------------------------------------------------* 
    LOCAL lRet := .F., aStru 
  
    IF Empty(cFields) .or. !hb_IsChar(cFields)  ; RETURN lRet 
    ELSEIF !myDbUse(cFile, , .F.) /*EXCLUSIVE*/ ; RETURN lRet 
    ENDIF 
    aStru := dbStruct() 
    USE 
  
    aStru := myStruDelFields(aStru, cFields) 
  
    IF Len(aStru) > 0 ; lRet := myDbStruMod( aStru, cFile ) 
    ENDIF 
  
 RETURN lRet 
  
 *-----------------------------------------------------------------------* 
 FUNCTION myDbAddFields(cFile, aFields, nPos)   
 *-----------------------------------------------------------------------* 
    LOCAL lRet := .F., aStru 
  
    IF !myDbUse(cFile, , .F.) /*EXCLUSIVE*/ ; RETURN lRet 
    ENDIF 
    aStru := dbStruct() 
    USE 
  
    aStru := myStruAddFields(aStru, aFields, nPos) 
  
    IF Len(aStru) > 0 ; lRet := myDbStruMod( aStru, cFile ) 
    ENDIF 
  
 RETURN lRet