Отправлено: 27.08.16 10:49. Заголовок: Можно ли, не создавая никаких окон

ни консольного, ни графического, напрямую работать с экраном? К примеру, перекрасить область на экране в известных координатах.

 Отправлено: 27.08.16 11:17. Заголовок: Как к Харбору прикру..

Как к Харбору прикрутить GetDC, к примеру? Кто может помочь?)

 Отправлено: 27.08.16 12:13. Заголовок: PSP пишет Как к Харб..

PSP пишет

цитата:

Как к Харбору прикрутить GetDC,

MiniGui c_winapimisc.c

 
 ... 
 HB_FUNC( GETDC ) 
 { 
    HB_RETNL( ( LONG_PTR ) GetDC( ( HWND ) HB_PARNL( 1 ) ) ); 
 } 
 ...

 Отправлено: 27.08.16 13:08. Заголовок: Ок, спасибо. Пошёл и..

Ок, спасибо. Пошёл изучать)

 Отправлено: 27.08.16 15:39. Заголовок: Воспользовался библо..

Воспользовался библой BosTaurus. Вроде работает)

 Отправлено: 27.08.16 15:52. Заголовок: PSP А для чего это ..

PSP
А для чего это тебе ?

 Отправлено: 27.08.16 15:59. Заголовок: Индикатор доступност..

Индикатор доступности http-ресурса в сети, который не зависит от оконного менеджера винды и программ, которые "любят" быть наверху))

 Отправлено: 27.08.16 17:01. Заголовок: PSP пишет: Индикато..

PSP пишет:

цитата:

Индикатор доступности http-ресурса в сети

Как сделаешь, поделись примером !

 Отправлено: 27.08.16 21:48. Заголовок: Может имеет смысл п..

Может имеет смысл посадить индикатор в TRAY ? Он там мигает разными цветами (в зависимости
от ситуации) да и видео всегда

 Отправлено: 27.08.16 21:56. Заголовок: fil пишет: Может им..

fil пишет:

цитата:

Может имеет смысл посадить индикатор в TRAY ?

Это - касса. Трэя нет. Эксплорера тоже. Кассовая программа "наверху". Ничего другого там не будет.

 Отправлено: 27.08.16 22:00. Заголовок: Andrey пишет: Как с..

Andrey пишет:

цитата:

Как сделаешь, поделись примером !

На вскидку - как-то так:

 
 #include "hmg.ch" 
 #include "BosTaurus.CH" 
 #include "Inkey.ch" 
  
 #require "hbtip" 
  
  
 FUNCTION    Main 
  
 LOCAL   hDC, sBTStruct 
 LOCAL   oHttp, lActive 
 LOCAL   n, d 
  
 WHILE  .T. 
  
    oHttp := TIPClientHTTP():New( "http://www.yandex.ru", .F. ) 
  
    IF  ( lActive := oHttp:open() ) 
       oHttp:close() 
    END   //IF 
  
    n  := Seconds() 
    d  := Date() 
  
    WHILE  Seconds() - n < 10  .and.  d == Date()    // пауза 10 сек. В эти 10 сек показывается "статусный квадрат". Учесть смену даты 
  
       hDC := BT_CreateDC( , BT_HDC_DESKTOP, @sBTstruct ) 
       IF  lActive 
          BT_DrawFillRectangle( hDC, 10, 10, 20, 20, { 73, 240, 17 }, { 73, 240, 17 }, 3 )   // зеленый квадрат 
       ELSE 
          BT_DrawFillRectangle( hDC, 10, 10, 20, 20, { 235, 16, 16 }, { 235, 16, 16 }, 3 )   // красный квадрат 
       END   // IF 
       BT_DeleteDC( sBTstruct ) 
  
       hb_ReleaseCPU() 
  
    END  // WILE 
  
    hb_ReleaseCPU() 
  
 END   // WHILE 
  
 RETURN 
 

Проверялось пока что только на обычном компе.

 Отправлено: 28.08.16 00:01. Заголовок: Ежели кассовая прога..

Ежели кассовая прога сверху тогда можно встроить индикатор в ее окно. Напр. заголовок
менять (ежели не POPUP) или на DC чего рисовать

 Отправлено: 28.08.16 01:54. Заголовок: PSP пишет: На вскид..

PSP пишет:

цитата:

На вскидку - как-то так:

Спасибо ! Прикольно !
В коллекции пригодиться !

 Отправлено: 28.08.16 10:57. Заголовок: fil пишет: или на D..

fil пишет:

цитата:

или на DC чего рисовать

Так вот я и рисую на DC. Только не конкретного окна (что тоже имеет смысл, спасибо), а всего экрана.

 Отправлено: 28.08.16 12:41. Заголовок: fil пишет: тогда мо..

fil пишет:

цитата:

тогда можно встроить индикатор в ее окно. Напр. заголовок

В FWH есть примерчик индикатора- полупрозрачное окошко , всегда "наверху" , на несколько секунд. На нем
можно разместить картинку , надпись или меню....

PS Это, как "идея " :)



function DesktopAlert( oWnd )

local oDlg, oBrush, oFont
local hLogo := FWLogoBitMap()
local oBtnClose
local oBtnDown
local oFontBody


DEFINE FONT oFont NAME "Verdana" BOLD
DEFINE FONT oFontBody NAME "Verdana" SIZE 0, -9
DEFINE BRUSH oBrush GRADIENT { { 1, nRgb( 221, 236, 253 ), nRgb( 95, 131, 179 ) } }

DEFINE DIALOG oDlg STYLE nOr( WS_POPUP, WS_BORDER ) BRUSH oBrush ;
SIZE 328, 73

@ 0.6, 6 SAY "A desktop notification" OF oDlg TRANSPARENT FONT oFont


@ 1.2, 6 SAY "ПОДКЛЮЧЕНО !" OF oDlg;
TRANSPARENT FONT oFont SIZE 100,30 COLOR CLR_HGREEN
@ 1.8, 6 SAY "Обед через 15 минут." OF oDlg;
TRANSPARENT FONT oFontBody SIZE 100,30 COLOR CLR_WHITE



@ 0.6, oDlg:nWidth-175 BTNBMP oBtnClose FILENAME "D:\fwh\bitmaps\16x16\cancel.bmp" ;
SIZE 10, 10 OF oDlg NOBORDER ACTION oDlg:End()

@ 0.6, oDlg:nWidth-185 BTNBMP oBtnDown FILENAME "D:\fwh\bitmaps\16x16\darrow.bmp" ;
SIZE 10, 10 OF oDlg NOBORDER ACTION oDlg:End()


oBtnClose:ltransparent:=.t.
oBtnDown:ltransparent:=.t.

ACTIVATE DIALOG oDlg ;
ON INIT ( SetTransparent( oDlg ), oDlg:Shadow(), BuildTimer( oDlg ) ) ;
ON CLICK oDlg:End() ;
ON PAINT DrawBitmap( hDC, hLogo, 9, 9 ) ;
VALID ( DeleteObject( hLogo ), .T. ) ;
NOWAIT

oBrush:End()
oFont:End()
oWnd:SetFocus()

return nil

//----------------------------------------------------------------------------//

function BuildTimer( oDlg )

local oTimer
local nStart := Seconds()

oDlg:SetPos( ScreenHeight() - 80, ScreenWidth( 0 ) - 350 )

DEFINE TIMER oTimer OF oDlg ;
INTERVAL 10;
ACTION If( Seconds() - nStart > 5, oDlg:End(),)

ACTIVATE TIMER oTimer

return nil

//----------------------------------------------------------------------------//

#define GWL_EXSTYLE -20
#define WS_EX_LAYERED 524288

static function SetTransparent( oDlg )

SetWindowLong( oDlg:hWnd, GWL_EXSTYLE, nOr( GetWindowLong( oDlg:hWnd, GWL_EXSTYLE ), WS_EX_LAYERED ) )

SetLayeredWindowAttributes( oDlg:hWnd, 0, 180, 2 )

return nil

 Отправлено: 28.08.16 12:51. Заголовок: ММК Спасибо, учту)..

ММК
Спасибо, учту)
Проверю свой вариант в бою сначала. А там видно будет)

 Отправлено: 29.08.16 16:31. Заголовок: В процессе натурных ..

В процессе натурных испытаний выяснилось, что оно не работает на Windows Embedded XP и 7 (возможно где-то еще, не проверял). Проблема решилась заменой вызова BT_CreateDC(...) на BT_CreateDC( 0, BT_HDC_ALLCLIENTAREA, @sBTstruct ).