//    ..... 
       nerr=0 
       cerr=""       
       get_dbfpar(filename,,,,,,@nerr,@cerr) 
     if nerr#0 
         // "Некорректная БД" 
     endif 
  
  //........ 
  
 Function get_dbfpar(fn,f_size,nbyte,last_rec,rec_size,of_set,nerr,cerr) 
    // параметры DBF 
    static arr_err:={; 
                   {0,"<Нет ошибки         > "} ,; //1 
                   {1,"<Не файл БД         > "} ,; //2 
                   {2,"<Неверный размер БД > "} ,; //3 
                   {4,"<Нет доступа Read+Sh> "} ,; //4 
                   {5,"<Аттрибут READONLY  > "} ,; //5 
                   {6,"<Дата БД больше тек.> "}  ; //6 
                    } 
    Local ret:=.t.,s,nHandle 
    LOCAL nCurrent,fattr:=0 
    Local sag:=chr(03),ierr:=1 
       f_size  :=0 
       nbyte   :=0 
       last_rec:=0 
       rec_size:=0 
       of_set  :=0 
  
    DO WHILE .t. 
       nerr    :=arr_err[1,1]; cerr := arr_err[1,2] 
       s:=space(32) 
       nHandle:=fopen(fn,FO_READ+FO_SHARED) 
  
    if ( ret:=(nHandle>=0) ) 
    nCurrent := FSEEK( nHandle, 0, FS_RELATIVE ) // Get file position 
    // Get file length 
    nbyte   := FSEEK( nHandle, 0, FS_END )       // размер файла 
    FSEEK( nHandle, nCurrent )                   // Reset file position 
  
        fread(nHandle,@s,32) 
        sag:= asc(substr(s,1,1)) 
        if !(sag=3.or.sag=131) // БД или БД с мемо 
           ret:=.f.;ierr:=2 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
        endif 
        last_rec:= ; 
         256*256*(; 
         256*asc(substr(s,8,1)) ; 
            +asc(substr(s,7,1)) ; 
            )+; 
         256*asc(substr(s,6,1)) ; 
            +asc(substr(s,5,1)) 
         rec_size:=;  // размер записи 
         256*asc(substr(s,12,1)) ; 
            +asc(substr(s,11,1)) 
         of_set:=;  // смещение - размер заголовка 
         256*asc(substr(s,10,1)) ; 
            +asc(substr(s, 9,1)) 
        f_size:= last_rec*rec_size+of_set+1 // размер базы 
        if abs(f_size-nbyte)>rec_size // несовпадение размера базы и файла 
           ret:=.f.;ierr:=3 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
        endif 
        if f_size > nbyte+1 
           ret:=.f.;ierr:=2 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
        endif 
        FCLOSE(nHandle) 
        if ret 
              if ISBIT(FILEATTR(fn),1)// Readonly 
           ret:=.f.;ierr:=5 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
               EXIT 
              endif 
              if FILEDATE(fn) > date() 
           ret:=.f.;ierr:=6 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
              endif 
        endif 
       else //nHandle<0 
           ret:=.f.;ierr:=4 
           nerr:=arr_err[ierr,1]; cerr := arr_err[ierr,2] 
     endif 
     EXIT 
    ENDDO 
   return ret