Directory() - Заполнение массива информацией о файлах по указанному пути. 
 Синтаксис       
  
       Directory( [<cDirectory>], [<cAttribute>] ) --> aDirectory     
  
 Параметры       
 <cDirectory>         
  
 <cDirectory> - символьная строка, которая указывает диск, каталог и файл. Полученная информация считывается в массив. Можно определить маску файла, подставив символы * или ?. Если параметр <cDirectory> не определен, используется *.*. При такой маске считывается вся информация о файлах текущего пути.       
  
 <cAttribute>         
 Этот дополнительный атрибут расширяет информацию о файле, помещенном в массив. <cAttribute> состоит из одного и более следующих символов: "D","H","S","V". Ниже представлены правильные значения для <cAttribute>: 
  
       Атрибут    Значение     Действие 
 -------------------------------------------------------------- 
       D          Directory  В массив включаются имена каталогов 
        H          Hidden     В массив включаются скрытые файлы 
        S          System     В массив включаются системные файлы 
        V          Volume     В массив включается имя диска, игнорируя файлы 
 Возвращаемое значение функции       
 Возвращаемое значение Directory() состоит из двумерного массива, в котором каждый элемент является подмассивом, содержащем информацию об очередном файле, выбранном в соответствии с аргументом <cDirectory>. Колонки массива могут быть установлены символическими константами, определенными в файле Directry.ch. Содержимое каждой колонки массива предоставлено в следующем таблице: 
  
       Константа    Cодержимое                    Тип данных 
 -------------------------------------------------------------- 
        F_NAME       имя файла                     C 
         F_SIZE       размер файла                  N 
         F_DATE       дата последнего изменения     D 
         F_TIME       время последнего изменения    C 
         F_ATTR       атрибут файла                 C 
  
                          (скрытый, системный...) 
  
  
 Если в <cDirectory> указан не правильный путь или спецификация файла, или вообще не найдено никаких соответствующих файлов, возвращается пустой массив.     
  
 Описание  
  
 Функция управления окружающей средой Directory() предоставляют информацию обо всех или выбранных файлах по указанному пути.     
  
 #include: Directry.ch 
  
 Смотрите также: AEval(), FClose() 
  
 ПРИМЕР-1: 
  
 // Directory() 
  
          // В примере определяется количество  байт, 
          // занимаемых файлами DBF в текущем каталоге. 
  
  
      #include "Directry.ch" 
  
      PROCEDURE Main 
        LOCAL aDbfFiles := Directory("*.DBF") 
        LOCAL nCount    := Len(aDbfFiles) 
        LOCAL n, nSum 
         nSum := 0 
        FOR n:= 1 TO nCount 
           nSum += aDbfFiles[ n, F_SIZE ] 
        NEXT 
        ? nCount, "DBF файлы знаимают", nSum, "байт" 
      RETURN 
  
 ------------------------------------------------------- 
  
 ПРИМЕР-2: 
 // В примере все PRG файлы сортируются по имени файла, 
 // а вся полученная о них информация заносится в файл вывода. 
  
      PROCEDURE Main 
        LOCAL aPrgFiles := Directory("*.PRG") 
        // сортировка массива по имени 
        ASort( aPrgFiles,,, {|a1,a2| a1[ F_NAME ] < a2[ F_NAME ] } ) 
        // вывод данных на принтер и параллельно в файл 
        SET PRINTER TO Prglist.txt 
        SET PRINTER ON 
  
        // вывод массива 
        AEval( aPrgFiles, ; 
               {|a| QOut( PadR( a[ F_NAME ], 30 ) , ; 
                                a[ F_SIZE ]       , ; 
                                a[ F_DATE ]       , ; 
                                a[ F_TIME ]       , ; 
                                a[ F_ATTR ]         ) } ) 
  
        SET PRINTER TO 
         SET PRINTER OFF 
      RETURN