Отправлено: 24.07.07 22:50. Заголовок: Где можно взять примеры работы с OLE Open Office

Всем привет.
В связи с борьбой с пиратами нужно переползать на открытый ОФИС.
А как работать с этим OLE в хХарборе - я не знаю.
Может кто-нибудь поделиться примерами ?

Заранее благодарю.

 Отправлено: 25.07.07 07:44. Заголовок: Re:

Неоднократно уже давал этот пример в самых разных местах

Function BrwToZxc(oB)
// -------------------------------------------------------------
// Экспорт обьекта Browse в OpenOffice Calc
// -------------------------------------------------------------
Local oStarManager, oStarDesktop, oDocument, oSheet, oRange
Local nRow := 1, nCol, nCol2, nMerge, oCol, cGrid
Local acHead := {}, lFoot := .f., x, ser
Local nStyle

oStarManager := NewOle('com.sun.star.ServiceManager')

if oStarManager # nil

Begin sequence

oStarDesktop := oStarManager:createInstance('com.sun.star.frame.Desktop')
oDocument := oStarDesktop:LoadComponentFromURL(;
'private:factory/scalc',;
'_blank',;
0,;
{})

oSheet:=oDocument:Sheets:getByIndex(0)


nRow := 1
for nCol := 1 TO oB:ColCount
oCol := oB:GetColumn(nCol)
oRange := oSheet:getCellByPosition(nCol-1, nRow-1)
if ! Empty(oCol:oHeader:aTitles[nRow])
oRange:SetString(OemToAnsi(oCol:heading))
zcCellBorder(oRange, 9)
endif

next

if nRow > 0
zcCellBorder(oSheet:getCellRangeByPosition(0,0,oB:ColCount-1,0), 8)
zcCellBorder(oSheet:getCellRangeByPosition(0,nRow-1,oB:ColCount-1,nRow-1), 9)
oSheet:TitleRows:StartRow := 1
oSheet:TitleRows:EndRow := nRow
oSheet:PrintTitleRows := .t.
endif

oB:GoTop()
while ! oB:HitBottom
nRow++
for nCol := 1 to oB:ColCount
oCol := oB:GetColumn(nCol)
x := Eval(oCol:Block)
if ! Empty(x) .and. ValType(x) == 'C' .and. ! Empty(Val(StrTran(x, "'", '')))
x := Val(StrTran(x, "'", ''))
elseif ValType(x)=='D'
x := DTOC(x)
endif
if oCol:cargo # nil .and. len(oCol:cargo) >= 6 .and.;
ValType(oCol:cargo[6]) == 'C' .and. oCol:cargo[6] = '$'
oSheet:getCellByPosition(nCol-1, nRow-1):NumberFormat := 2
endif
if ! Empty(x)
if ValType(x) == 'C'
oSheet:getCellByPosition(nCol-1, nRow-1):SetString(x)
else
oSheet:getCellByPosition(nCol-1, nRow-1):SetValue(x)
endif
endif
next
oB:Down()
enddo

if oB:lFoots
nRow++
zcCellBorder(oSheet:getCellRangeByPosition(0,nRow-1,oB:ColCount-1,nRow-1), 8)
for nCol := 1 to oB:ColCount
if ! Empty(oB:GetColumn(nCol):footing)
x := oB:GetColumn(nCol):footing
if ! Empty(Val(StrTran(x, "'", '')))
x := Val(StrTran(x, "'", ''))
// elseif oB:GetColumn(nCol):nAjuste = 38
// x := Val(x)
endif
oSheet:getCellByPosition(nCol-1, nRow-1):SetString(x)
endif
next
endif

for nCol := 1 to oB:ColCount
oSheet:getColumns():getByIndex(nCol-1):OptimalWidth := .t.
next

end
endif
Return nil


Static func zcCellBorder(oRange, nNSEW)
Local oBorder := oRange:TableBorder
Local oLine

if nNSEW == 8
oLine := oBorder:TopLine
elseif nNSEW == 9
oLine := oBorder:BottomLine
elseif nNSEW == 10
oLine := oBorder:RightLine
elseif nNSEW == 7
oLine := oBorder:LeftLine
endif
oLine:OuterLineWidth := 10
oLine:InnerLineWidth := 0

if nNSEW == 8
oBorder:TopLine := oLine
elseif nNSEW == 9
oBorder:BottomLine := oLine
elseif nNSEW == 10
oBorder:RightLine := oLine
elseif nNSEW == 7
oBorder:LeftLine := oLine
endif

oRange:TableBorder := oBorder
Return nil

 Отправлено: 25.07.07 08:50. Заголовок: Re:

Можно еще посмотреть архив форума

http://www.oooforum.org/forum/viewforum.phtml?f=9

Там есть масса примеров
Можно там задать свой вопрос

 Отправлено: 25.07.07 12:09. Заголовок: Re:

Паша, спасибо большое.

 Отправлено: 25.07.07 12:26. Заголовок: Re:

Не заметил, еще нужна функция:

Static func NewOle(cServer)
Local oServer, hObj

Begin sequence
hObj := CreateOleObject( cServer )
if OleError() == 0
oServer := TOleAuto():new( hObj )
#ifdef __HARBOUR__
oServer:cClassName := cServer
#endif
endif
end
if oServer == nil
Alert('Ошибка инициализации OLE:' + cServer)
endif
Return oServer

если что-то выдираешь из своей библиотеки, обязательно попадется какая-то нестандартная функция

 Отправлено: 25.07.07 14:22. Заголовок: Re:

Вот сам наконец-то решил оседлать OO-writer, и еще маленький примерчик

Задача: открыть документ и на место закладки вставить значение

func OOWriter(cFile, cBookmark, cValue)
Local oStarManager, oStarDesktop, oDocument
Local oBookmarks, oBookmark

cFile := StrTran(cFile, "\", "/")
cFile := StrTran(cFile, " ", "%20")

cFile := "file:///" + cFile

oStarManager := NewOle('com.sun.star.ServiceManager')

if oStarManager # nil

Begin sequence

oStarDesktop := oStarManager:createInstance('com.sun.star.frame.Desktop')
oDocument := oStarDesktop:LoadComponentFromURL(;
cFile,'_blank', 0, {})

oBookmarks := oDocument:getBookmarks()

oBookmark := oBookmarks:GetByName(cBookmark)

oBookMark:getAnchor:setString(cValue)

retu nil

 Отправлено: 25.07.07 21:25. Заголовок: Re:

Спасибо большое, Паша !!!
А можно ли одновременно установить OpenOffice и MsOffice ?
И как тогда это вместе будет работать ?

 Отправлено: 25.07.07 21:35. Заголовок: Re:

Andrey пишет:

цитата:

А можно ли одновременно установить OpenOffice и MsOffice ?

Вот и пробни ;)

 Отправлено: 25.07.07 22:20. Заголовок: Re:

Спасибо Дима за добрые пожелания...., а я то думал что сие мне делать не придется ....

 Отправлено: 26.07.07 12:20. Заголовок: Re:

конечно можно
я в своих программах в тулбаре помещаю 2 кнопки - экспорт в эксель и оо-калк
если соответствующий офис установлен, работает, ну а на нет суда нет

 Отправлено: 30.07.08 15:37. Заголовок: Добрый день уважаемы..

Добрый день уважаемые!
А может кто нибудь подсказать, как узнать закончил SCalc печатать файл или нет?
Просто столкнулся с проблемой во время закрытия документа с параметрами Hidden = .t., который был отправлен на печать.
Может у кого ссылка есть на мануал про эту тему или просто кусочек кода завалялся???
Помогите, плиз...

 Отправлено: 01.08.08 09:00. Заголовок: Корректировочки

Ну соврал малость... свойства HIDDEN это было сделано на ООо Васике, в его родной среде

цитата:

DIM oProperty AS NEW com.sun.star.beans.PropertyValue SET oProperty.Name = "Hidden" SET oProperty.Value = True

Так у меня и не получилось на xHb создать невидимый документ
Может у кого получилось? подскажите пожалуйста...

а по поводу предидущего сообщения нашел коечто http://www.oooforum.org/forum/viewtopic.phtml?t=4922 ...
по крайней мере узнал как это делать из-под ООо Васика.

 Отправлено: 01.08.08 12:34. Заголовок: spair2k пишет: Ну с..

spair2k пишет:

цитата:

Ну соврал малость... свойства HIDDEN это было сделано на ООо Васике, в его родной среде цитата: DIM oProperty AS NEW com.sun.star.beans.PropertyValue SET oProperty.Name = "Hidden" SET oProperty.Value = True Так у меня и не получилось на xHb создать невидимый документ Может у кого получилось? подскажите пожалуйста...

oStarDesktop := oStarManager:createInstance('com.sun.star.frame.Desktop')

oProperty := oServiceMamager:bridge_GetStruct("com.sun.star.beans.PropertyValue")

oProperty:Name := "Hidden"
oProperty:Value := .T.

Return oStarDesktop:LoadComponentFromURL(;
cFile, '_blank', 0, {oProperty})

 Отправлено: 09.08.09 10:19. Заголовок: OpenOffice уже отк..

OpenOffice уже открывается.
А как открыть имеющийся файл или шаблон для заполнения?

 Отправлено: 10.08.09 08:23. Заголовок: Vlad04 пишет: А как..

Vlad04 пишет:

цитата:

А как открыть имеющийся файл или шаблон для заполнения?

oStarManager := TOleAuto():New('com.sun.star.ServiceManager')
oStarDesktop := oStarManager:createInstance('com.sun.star.frame.Desktop')

cFile := StrTran(cFile, "\", "/")
cFile := StrTran(cFile, " ", "%20")

cFile := "file:///" + cFile

aProps := {}

oStarDesktop:LoadComponentFromURL(;
cFile, '_blank', 0, aProps)

 Отправлено: 26.02.16 12:40. Заголовок: А как можно вставить..

А как можно вставить картинку в ячейку и отформатировать ячейку в размер картинки с привязкой картинки к ячейке?

 Отправлено: 27.02.16 17:44. Заголовок: как вставить картинк..

как вставить картинку разобрался:

Скрытый текст

oFrame:=oDocument:CurrentController:Frame dispatcher:=oStarManager:createInstance("com.sun.star.frame.DispatchHelper") arg1:=oStarDesktop:bridge_GetStruct("com.sun.star.beans.PropertyValue") arg2:=oStarDesktop:bridge_GetStruct("com.sun.star.beans.PropertyValue") arg3:=oStarDesktop:bridge_GetStruct("com.sun.star.beans.PropertyValue") arg1:Name:="FileName" arg1:Value:="file:///D:/IMAGE/24.JPG" arg2:Name:="FilterName" arg2:Value:="JPEG - Joint Photographic Experts Group" arg3:Name:="AsLink" arg3:Value:=.F. arg:={arg1,arg2,arg3} dispatcher:executeDispatch(oFrame,".uno:InsertGraphic","",0,arg)

А вот отформатировать ее по размеру не получается. Может кто знает как можно это сделать?

 Отправлено: 27.02.16 18:07. Заголовок: MIKHAIL Возможно на..

MIKHAIL
Возможно надо погуглить

 Отправлено: 16.03.16 13:22. Заголовок: После работы с докум..

После работы с документом, закрываю его oDoc:close(.t.), но Open Office висит в памяти и блокирует временные фалы.
Если же закрывать приложение через oStarDesktop:terminate() то он закрывает и другие открытые документы (writer и calc ).
Как корректно закрывать процесс вызванный именно работой приложения и не затрагивать остальные открытые документы ?

 Отправлено: 16.03.16 22:18. Заголовок: Документация...

Когда-то нашел для себя что-то полезное на сайте
https://wiki.openoffice.org/wiki/RU

Есть форум
http://www.forumooo.ru/

 Отправлено: 03.06.16 18:27. Заголовок: Есть исходник 2007г...

Есть исходник 2007г. вызова Open Office на хХарборе. Работает до сих пор.
Перетащил на МиниГуи - вешает задачу намертво.

Подскажите пожалуйста, где ошибка ?
Скрытый текст

/*=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= От: Логошный Сергей <?????@yandex.ru> Кому: мне Написано: 16 августа 2007 г., 9:18:59 Тема: OpenOffice. =-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-= */ FUNCTION OpenWriter(cFile) LOCAL oDoc, oApp , oDeskTop, aPr, aProp, oPr, oProperty LOCAL bLastHandler, objLocal, cMsg, FileURL FileURL:='file://localhost/'+StrTran(cFile,'\','/') /* пробовал так делать - не пошло тоже cFile := StrTran(cFile, "\", "/") cFile := StrTran(cFile, " ", "%20") FileURL:= "file://" + cFile */ MsgDebug( cFile , FileURL ) // создаём окно ожидания с потоком //WaitThreadCreate( 'Вызываю Open Office...' ) bLastHandler := ERRORBLOCK( { | objErr | MyHandler( objErr, .T.) }) BEGIN SEQUENCE oApp:= TOleAuto():new("com.sun.star.ServiceManager") RECOVER USING objLocal cMsg := "Не могу запустить - Open Office !;; (Не установлен на этом компьютере !);" MsgStop(cMsg,"Ошибка!") RETURN NIL END ERRORBLOCK( bLastHandler ) // "Запускаю - Open Office !;; (Найден на этом компьютере !);" oDeskTop:=oApp:createInstance("com.sun.star.frame.Desktop") aProp:=Array(1) aPr:=Array(1) oProperty:=oApp:Bridge_GetStruct("com.sun.star.beans.PropertyValue") oProperty:Name:= "AsTemplate" oProperty:Value:= .T. aProp[1]:=oProperty oDoc:=oDeskTop:LoadComponentFromURL(FileURL,"_blank", 0,aProp) oPr:=oApp:Bridge_GetStruct("com.sun.star.beans.PropertyValue") oPr:Name:="FilterName" oPr:Value:="Rich Text Format" aPr[1]:=oPr oDoc:storeAsURL(FileURL,aPr) //WaitThreadClose() // закрыть окно "ожидания" RETURN '' FUNCTION MyHandler (objError, lLocalHandler) IF lLocalHandler BREAK objError ENDIF RETURN NIL