FUNC Main(cConnect, cDir, cFileName,nSkipBuffer) 
  // 
  IF Empty( cConnect ) .OR. (cConnect == ".") 
   cConnect := "192.168.1.120:2812" 
  ENDIF 
  // 
  IF Empty( cDir ) .OR. (cDir == ".") 
   cDir := "w:\hb\data\" 
  ENDIF 
  // 
  IF LEN(DIRECTORY(cDir+"*.*")) == 0 
   ? "Directory "+cDir+" is wrong" 
   QUIT 
  ENDIF 
  // 
  IF EMPTY(cFileName) .OR. (cFileName == ".") 
   cFileName := "invcheck" 
  ENDIF 
  // 
  IF EMPTY(nSkipBuffer) 
   nSkipBuffer := 21 // by default 
  ELSE 
   nSkipBuffer := VAL(nSkipBuffer) 
   IF EMPTY(nSkipBuffer) 
    nSkipBuffer := 21 
   ENDIF 
  ENDIF 
  // 
  ? "1)    cConnect = ",cConnect 
  ? "2)        cDir = ",cDir 
  ? "3)   cFileName = ",cFileName 
  ? "4) nSkipBuffer = ",hb_NTOS(nSkipBuffer) 
  // 
  IF FILE(cDir+cFileName+".dbf") 
   ? "Table "+cDir+cFileName+".dbf is reachable locally. OK" 
  ELSE 
   ? "Table "+cDir+cFileName+".dbf is not reachable locally. QUIT" 
   QUIT 
  ENDIF 
  // 
  IF Leto_Connect(cConnect) >= 0 
   ? "LetoDBf - connect ok." 
   Leto_ToggleZip(1) 
   LETO_SETSKIPBUFFER( nSkipBuffer ) 
  ELSE 
   ? "LetoDbf - failed to connect. QUIT" 
   QUIT 
  ENDIF 
  // 
  IF Leto_File(cFileName+".dbf") 
   LetoSpeedTest(cDir,cFileName,10000) 
  ELSE 
   ? "Leto_File('"+cFileName+".dbf') = FALSE" 
  ENDIF 
  ? 
  ? "Press any key to exit" 
  INKEY(0) 
  // 
 RETURN 0 
  
 * ---------------------------------------- * 
 FUNC LetoSpeedTest(cWorkDir,cFileName,nSize) 
  
 LOCAL nStart,nStop,i,aRecords 
  // 
  USE (cWorkDir+cFileName) INDEX (cWorkDir+cFileName) EXCLUSIVE NEW VIA "DBFNTX" 
  IF NETERR() 
   ? "DBFNTX - open error." 
   RETURN .F. 
  ELSE 
   ? "Table "+cFileName+".dbf is opened, it has "+hb_NTOS(RECCOUNT())+" records,",; 
      hb_NTOS(FileSize(cWorkDir+cFileName+".dbf") / (1024 * 1024))," MB" 
   ? 
  ENDIF 
  // 
  aRecords := ARRAY(nSize) 
  FOR i:=1 TO nSize 
   aRecords[ i ] := INT(RAND()*nSize) 
  NEXT i 
  // 
  ? "Testing "+hb_NTOS(nSize)+" jumps via DBFNTX: " 
  nStart := hb_Milliseconds() 
  FOR i:=1 TO nSize 
   GO aRecords[ i ] 
   DoSomething()  
  NEXT i 
  nStop := hb_Milliseconds() 
  // 
  ?? STR(nStop-nStart,10),"ms, "+STR(nSize/(nStop-nStart)*1000,10,1)+" jumps/sec" 
  CLOSE  
  // 
  USE (cFileName) INDEX (cFileName) EXCLUSIVE NEW VIA "LETO" 
  IF NETERR() 
   ? "LETO - open error." 
   RETURN .F. 
  ELSE 
   ? "Testing "+hb_NTOS(nSize)+" jumps via   LETO: " 
  ENDIF 
  nStart := hb_Milliseconds() 
  FOR i:=1 TO nSize 
   GO aRecords[ i ] 
   DoSomething() 
  NEXT i 
  nStop := hb_Milliseconds() 
  // 
  ?? STR(nStop-nStart,10),"ms, "+STR(nSize/(nStop-nStart)*1000,10,1)+" jumps/sec" 
  CLOSE  
  // 
 RETURN "done" 
  
 * ----------------------------- * 
 STATIC FUNC DoSomething()  
  
 LOCAL x := FIELDGET(1),; 
       y := FIELDGET(2) 
  
 RETURN hb_ValToExp(x)+hb_ValToExp(y)  
 * 
 * 
 * EOF is here...