i_window.ch 
 ... 
    #xtranslate <w> . SplitBox . \<x\> . \<c\> . \<p:Caption,Enabled,Value\> := \<n\> => SetProperty ( <"w"> , "SplitBox", \<"x"\> , \<"c"\> , \<"p"\> , \<n\> )  
  
    #xcommand DEF WINDOW <w> ; 
          [ <dummy1: OF, PARENT> <parent> ] ; 
          [ AT <row>,<col> ] ; 
          [ ROW <row> ] ; 
          [ COL <col> ] ; 
          [ WIDTH <wi> ] ; 
          [ HEIGHT <h> ] ; 
          [ MINWIDTH <minWidth> ] ; 
          [ MINHEIGHT <minHeight> ] ; 
          [ MAXWIDTH <maxWidth> ] ; 
          [ MAXHEIGHT <maxHeight> ] ; 
          [ VIRTUAL WIDTH <vWidth> ] ; 
          [ VIRTUAL HEIGHT <vHeight> ] ; 
          [ CLIENTAREA <clientwidth>,<clientheight> ] ; 
          [ TITLE <title> ] ; 
          [ ICON <icon> ] ; 
          [ <main:  MAIN> ] ; 
          [ <mdi: MDI> ] ; 
          [ <child: CHILD> ] ; 
          [ <panel: PANEL> ] ; 
          [ <modal: MODAL> ] ; 
          [ <main:  WINDOWTYPE MAIN> ] ; 
          [ <child: WINDOWTYPE CHILD> ] ; 
          [ <panel: WINDOWTYPE PANEL> ] ; 
          [ <modal: WINDOWTYPE MODAL> ] ; 
          [ WINDOWTYPE STANDARD ] ; 
          [ <noshow: NOSHOW> ] ; 
          [ <topmost: TOPMOST> ] ; 
          [ <palette: PALETTE> ] ; 
          [ <noautorelease: NOAUTORELEASE> ] ; 
          [ <nominimize: NOMINIMIZE> ] ; 
          [ <nomaximize: NOMAXIMIZE> ] ; 
          [ <nosize: NOSIZE> ] ; 
          [ <nosysmenu: NOSYSMENU> ] ; 
          [ <nocaption: NOCAPTION> ] ; 
          [ CURSOR <cursor> ] ; 
          [ ON INIT <InitProcedure> ] ; 
          [ ON RELEASE <ReleaseProcedure> ] ; 
          [ ON INTERACTIVECLOSE <interactivecloseprocedure> ] ; 
          [ ON MOUSECLICK <ClickProcedure> ] ; 
          [ ON MOUSEDRAG <MouseDragProcedure> ] ; 
          [ ON MOUSEMOVE <MouseMoveProcedure> ] ; 
          [ ON MOVE <MoveProcedure> ] ; 
          [ ON SIZE <SizeProcedure> ] ; 
          [ ON MAXIMIZE <MaximizeProcedure> ] ; 
          [ ON MINIMIZE <MinimizeProcedure> ] ; 
          [ ON RESTORE <RestoreProcedure> ] ; 
          [ ON PAINT <PaintProcedure> ] ; 
          [ ON DROPFILES <DropProcedure> ] ; 
          [ <dummy2: BACKCOLOR, BKBRUSH> <backcolor> ] ; 
          [ FONT <FontName> SIZE <FontSize> ] ; 
          [ NOTIFYICON <NotifyIcon> ] ; 
          [ NOTIFYTOOLTIP <NotifyIconTooltip> ] ; 
          [ ON NOTIFYCLICK <NotifyLeftClick> ] ; 
          [ ON NOTIFYDBLCLICK <NotifyDblClick> ] ; 
          [ ON NOTIFYBALLOONCLICK <NotifyBalloonClick> ] ; 
          [ ON GOTFOCUS <GotFocusProcedure> ] ; 
          [ ON LOSTFOCUS <LostFocusProcedure> ] ; 
          [ ON SCROLLUP <scrollup> ] ; 
          [ ON SCROLLDOWN <scrolldown> ] ; 
          [ ON SCROLLLEFT <scrollleft> ] ; 
          [ ON SCROLLRIGHT <scrollright> ] ; 
          [ ON HSCROLLBOX <hScrollBox> ] ; 
          [ ON VSCROLLBOX <vScrollBox> ] ; 
          [ <helpbutton: HELPBUTTON> ] ; 
          [ <flashexit: FLASHEXIT> ] ; 
    => ; 
    DECLARE WINDOW <w>  ;; 
    _DefWindow ( <"w">, <title>, <col>, <row>, <wi>, <h>, <.nominimize.>, <.nomaximize.>, <.nosize.>, <.nosysmenu.>, <.nocaption.>, {<minWidth>, <minHeight>}, {<maxWidth>, <maxHeight>}, <{InitProcedure}>, <{ReleaseProcedure}> , <{MouseDragProcedure}>, <{SizeProcedure}> , <{ClickProcedure}> , <{MouseMoveProcedure}>, [<backcolor>] , <{PaintProcedure}> , <.noshow.> , <.topmost.> , <.main.> , <icon> , <.child.> , <FontName> , <FontSize>, <NotifyIcon> , <NotifyIconTooltip> , <{NotifyLeftClick}>  , <{GotFocusProcedure}>, <{LostFocusProcedure}> , <vHeight> , <vWidth> , <{scrollleft}> , <{scrollright}> , <{scrollup}> , <{scrolldown}> , <{hScrollBox}> , <{vScrollBox}> , <.helpbutton.> , <{MaximizeProcedure}> , <{MinimizeProcedure}> , <cursor> , <.noautorelease.> , <{interactivecloseprocedure}> , <{RestoreProcedure}> , <{MoveProcedure}> , <{DropProcedure}> , <.mdi.> , <.palette.> , <{NotifyDblClick}> , <"parent"> , <.panel.> , <{NotifyBalloonClick}> , <clientwidth> , <clientheight>, <.modal.>, <.flashexit.> ) 
 ... 
 функцию к себе в либу положи 
 *-----------------------------------------------------------------------------* 
 FUNCTION _DefWindow ( FormName, Caption, x, y, w, h, nominimize, nomaximize, ; 
       nosize, nosysmenu, nocaption, aMin, aMax, InitProcedure, ReleaseProcedure, ; 
       MouseDragProcedure, SizeProcedure, ClickProcedure, MouseMoveProcedure, aRGB, ; 
       PaintProcedure, noshow, topmost, main, icon, child, fontname, fontsize, ; 
       NotifyIconName, NotifyIconTooltip, NotifyIconLeftClick, GotFocus, LostFocus, ; 
       VirtualHeight, VirtualWidth, scrollleft, scrollright, scrollup, scrolldown, ; 
       hscrollbox, vscrollbox, helpbutton, MaximizeProcedure, MinimizeProcedure, cursor, ; 
       NoAutoRelease, InteractiveCloseProcedure, RestoreProcedure, MoveProcedure, DropProcedure, ; 
       mdi, palette, NotifyIconDblClick, cPanelParent, panel, NotifyBalloonClick, ; 
       clientwidth, clientheight, modal, flashexit ) 
 *-----------------------------------------------------------------------------* 
       LOCAL FormHandle, Parent := cPanelParent 
  
       modal := modal .or. ! Empty( _HMG_IsModalActive ) 
  
       If ( main  := main .or. Empty( _HMG_MainHandle ) ) 
          modal := child := panel := mdi := .F. 
       EndIf 
  
       If modal 
  
          FormHandle := _DefineModalWindow ( FormName, Caption, x, y, w, h, Parent, ; 
                        nosize, nosysmenu, nocaption, aMin, aMax, ; 
                        InitProcedure, ReleaseProcedure, MouseDragProcedure, ; 
                        SizeProcedure, ClickProcedure, MouseMoveProcedure, aRGB, ; 
                        PaintProcedure, icon, FontName, FontSize, GotFocus, ; 
                        LostFocus, VirtualHeight, VirtualWidth, ; 
                        scrollleft, scrollright, scrollup, scrolldown, ; 
                        hscrollbox, vscrollbox, helpbutton, cursor, noshow, ; 
                        NoAutoRelease, InteractiveCloseProcedure, MoveProcedure, ; 
                        DropProcedure, clientwidth, clientheight, flashexit ) 
  
       Else 
  
          DECLARE CUSTOM COMPONENTS &FormName 
  
          FormHandle := _DefineWindow ( FormName, Caption, x, y, w, h, nominimize, nomaximize, ; 
                        nosize, nosysmenu, nocaption, aMin, aMax, InitProcedure, ReleaseProcedure, ; 
                        MouseDragProcedure, SizeProcedure, ClickProcedure, MouseMoveProcedure, aRGB, ; 
                        PaintProcedure, noshow, topmost, main, icon, child, fontname, fontsize, ; 
                        NotifyIconName, NotifyIconTooltip, NotifyIconLeftClick, GotFocus, LostFocus, ; 
                        VirtualHeight, VirtualWidth, scrollleft, scrollright, scrollup, scrolldown, ; 
                        hscrollbox, vscrollbox, helpbutton, MaximizeProcedure, MinimizeProcedure, cursor, ; 
                        NoAutoRelease, InteractiveCloseProcedure, RestoreProcedure, MoveProcedure, DropProcedure, ; 
                        mdi, palette, NotifyIconDblClick, cPanelParent, panel, NotifyBalloonClick, ; 
                        clientwidth, clientheight ) 
                       
       EndIf 
  
 RETURN FormHandle 
  
 использование 
    DEF WINDOW wMain AT nY, nX WIDTH nW HEIGHT nH ; 
        ICON       "1MAIN_ICO"        ; 
        TITLE      SHOW_TITLE         ; 
        BACKCOLOR  SILVER             ; 
        MAIN       NOMAXIMIZE NOSIZE  ; 
        FONT cFont SIZE nFontSize      
 ... 
    DEF WINDOW &cFormName AT nY, nX WIDTH nW HEIGHT nH ; 
        TITLE cTitle ICON cIcoRes                         ; 
        BACKCOLOR aBackColor                              ; 
        WINDOWTYPE STANDARD                               ; 
        NOSIZE NOMAXIMIZE   TOPMOST                       ; 
        FONT cFontName SIZE nFontSize                     ; 
        ON INIT  ( this.topmost := .F., _wSend(1) )       ;  
        ON RELEASE  NIL                                   ;   
        ON INTERACTIVECLOSE lFormClose 
 и т.д.