METHOD FilterFTS( cFind, lUpper, lFocus ) CLASS TSBrowse 
    LOCAL nLen := 0, cAlias := ::cAlias, ob := Self 
    DEFAULT lUpper := .T. 
  
    If lUpper .and. HB_ISCHAR( cFind ) 
       cFind := Upper( cFind ) 
    EndIf 
  
    IF ! Empty( cFind ) 
       ( cAlias )->( DbSetFilter( {|| ob:FilterFTS_Line( cFind, lUpper, ob) }, ; 
                                     "ob:FilterFTS_Line( cFind, lUpper, ob)" ) ) 
    ELSE 
       ( cAlias )->( DbClearFilter() ) 
    END 
  
    ( cAlias )->( DbGotop() ) 
    DO WHILE ( cAlias )->( !EOF() ) 
       DO EVENTS 
       nLen++ 
       ( cAlias )->( DbSkip(1) ) 
    ENDDO 
    ( cAlias )->( DbGotop() ) 
    DO EVENTS 
  
    ::bLogicLen := {|| nLen } 
    ::Reset() 
  
    If ! empty(lFocus) 
       ::SetFocus() 
    EndIf 
  
 RETURN Nil 
  
 METHOD FilterFTS_Line( cFind, lUpper ) CLASS TSBrowse 
    LOCAL nCol, oCol, xVal, lRet := .F. 
    DEFAULT lUpper := .T. 
  
    FOR nCol := 1 TO Len( ::aColumns ) 
        oCol := ::aColumns[ nCol ] 
        If nCol == 1 .and. ::lSelector; LOOP 
        ElseIf ! oCol:lVisible        ; LOOP 
        ElseIf oCol:lBitMap           ; LOOP 
        EndIf 
        xVal := ::bDataEval(oCol, , nCol) 
        If HB_ISCHAR( xVal ) 
           If lUpper 
              lRet := cFind $ Upper( xVal ) 
           Else 
              lRet := cFind $ xVal 
           EndIf 
           If lRet 
              EXIT 
           EndIf 
        EndIf 
    NEXT 
  
 RETURN lRet 
  
 и в примере 
 STATIC FUNCTION RefreshBrowse() 
 LOCAL cSeek := Alltrim( Form_0.Text_1.Value ) 
  
    IF ! Empty(cSeek) 
       oBrw_1:FilterFTS(cSeek, .T.) 
    ELSE 
       oBrw_1:FilterFTS( Nil ) 
    END 
  
 RETURN Nil 
 

 
 *----------------------------------------------------------------------------* 
 FUNC RecGet() 
 *----------------------------------------------------------------------------* 
    LOCAL oRec := oKeyData() 
  
    AEval( Array( FCount() ), {|v,n|  oRec:Set( FieldName( n ), FieldGet( n ) ) } ) 
  
 RETURN oRec 
  
 *----------------------------------------------------------------------------* 
 FUNC RecPut( oRec ) 
 *----------------------------------------------------------------------------* 
    nCnt := 0 
  
    AEval( oRec:GetAll(.F.), {|a,n| n := FieldPos(a[1]), nCnt += n, ; 
                               iif( n > 0, FieldPut( n, a[2] ), ) } ) 
  
 RETURN nCnt > 0 
 

 
 STATIC FUNCTION RecnoClone(oBrw) 
    LOCAL oRec 
  
    If empty(oBrw:bAddBefore) 
       oBrw:bAddBefore := {|ob| oRec := (ob:cAlias)->( RecGet() ), ; 
                                oRec:Del('FieldName1'), ; 
                                oRec:Del('FieldName2'), ; 
                                oRec:Set('FieldName5', 'abcde'), ; 
                                oRec:Set('FieldName7', 12345) } 
       oBrw:bAddAfter  := {|ob,ladd| iif( ladd, (ob:cAlias)->( RecPut(oRec), ) } 
    EndIf 
  
    oBrw:AppendRow(.T.) 
    
    (oBrw:cAlias)->(DbCommit()) 
  
 RETURN Nil