#include "hmg.ch" 
  
 FUNCTION main 
  
    DEFINE WINDOW button_test ;  
       AT 0,0 ;  
       WIDTH 800 ;  
       HEIGHT 600 ;  
       MAIN ;  
       TITLE "button program test"  
  
    @ 100, 10 BUTTON butt_0959_A ;  
       CAPTION " 1 " ;  
       ACTION msgInfo( 1 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 1 
  
    @ 100, 140 BUTTON butt_0959_B ;  
       CAPTION " 2 " ;  
       ACTION msgInfo( 2 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 2 
  
    @ 100, 270 BUTTON butt_0959_C ;  
       CAPTION " 3 " ;  
       ACTION msgInfo( 3 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 3 
  
    @ 100, 400 BUTTON butt_0959_D ;  
       CAPTION " 4 " ;  
       ACTION msgInfo( 4 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 4 
  
    @ 100, 530 BUTTON butt_0959_E ;  
       CAPTION " 5 " ;  
       ACTION msgInfo( 5 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 5 
  
    @ 100, 660 BUTTON butt_0959_F ;  
       CAPTION " 6 " ;  
       ACTION msgInfo( 6 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 6 
  
    @ 145.00, 10 BUTTON butt_0959_G ;  
       CAPTION " 7 " ;  
       ACTION msgInfo( 7 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 7 
  
    @ 145.00, 140 BUTTON butt_0959_H ;  
       CAPTION " 8 " ;  
       ACTION msgInfo( 8 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 8 
  
    @ 145.00, 270 BUTTON butt_0959_I ;  
       CAPTION " 9 " ;  
       ACTION msgInfo( 9 ) ;  
       WIDTH 100 ;  
       HEIGHT 30 HOTKEY 9 
  
    END WINDOW  
  
    CENTER WINDOW button_test  
  
    ACTIVATE WINDOW button_test  
  
 RETURN 
 

 
 #include "hmg.ch"  
    
 FUNCTION main  
    Local nW := 40, nX := 10, nS := 10 
  
    SET CENTURY  ON 
    SET DATE     GERMAN 
  
    SET OOP      ON 
  
    DEFINE WINDOW button_test ;   
       AT 0,0 ;   
       WIDTH 800 ;   
       HEIGHT 400 ;   
       MAIN ;   
       TITLE "button program test"   
   
    @ 100, nX BUTTON butt_1 ;   
       CAPTION " 1 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_2 ;   
       CAPTION " 2 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_3 ;   
       CAPTION " 3 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_4 ;   
       CAPTION " 4 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_5 ;   
       CAPTION " 5 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_6 ;   
       CAPTION " 6 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_7 ;   
       CAPTION " 7 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_8 ;   
       CAPTION " 8 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30  
   
      nX += nW + nS 
    @ 100, nX BUTTON butt_9 ;   
       CAPTION " 9 " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
   
      nX += nW + nS * 5 
 /* 
    @ 100, nX BUTTON butt_F ;   
       CAPTION " F " ;   
       ACTION MsgInfo(This.Caption+' '+This.Name, ThisWindow.Name) ;   
       WIDTH  nW ;   
       HEIGHT 30   
 */ 
    @ 100, nX BUTTON butt_F ;   
       CAPTION " F " ;   
       ACTION _wPost(11, This.Index) ;   
       WIDTH  nW ;   
       HEIGHT 30   
  
       WITH OBJECT This.Object 
       :Event( 1        , {|| This.butt_1.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 2        , {|| This.butt_2.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 3        , {|| This.butt_3.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 4        , {|| This.butt_4.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 5        , {|| This.butt_5.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 6        , {|| This.butt_6.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 7        , {|| This.butt_7.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 8        , {|| This.butt_8.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 9        , {|| This.butt_9.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 10       , {|| This.butt_F.SetFocus, DoEvents(), _PushKey( VK_SPACE ) } )  
       :Event( 11       , {|ob| MsgInfo(ob:Name+' '+This.Caption+' '+This.Name, 'Find button') } )   
       :Event( 99       , {|ow| ow:Release() } )   
       END WITH 
  
       ON KEY ESCAPE ACTION _wPost(99) 
       ON KEY      1 ACTION _wPost(1) 
       ON KEY      2 ACTION _wPost(2) 
       ON KEY      3 ACTION _wPost(3) 
       ON KEY      4 ACTION _wPost(4) 
       ON KEY      5 ACTION _wPost(5) 
       ON KEY      6 ACTION _wPost(6) 
       ON KEY      7 ACTION _wPost(7) 
       ON KEY      8 ACTION _wPost(8) 
       ON KEY      9 ACTION _wPost(9) 
 //      ON KEY RETURN ACTION _wPost(10) 
     ON KEY RETURN ACTION _wPost(11, This.butt_F.Index) 
   
    END WINDOW   
   
    CENTER WINDOW button_test   
   
    ACTIVATE WINDOW button_test   
   
 RETURN  
  

 
 *----------------------------------------------------------------------------* 
 FUNCTION GetTextWidthHeight( aTxt, FontName, FontSize ) 
 *----------------------------------------------------------------------------* 
    LOCAL hFont, lFont, nWidth := 0, nHeigth := 0, cTxt 
  
    DEFAULT aTxt := { 'W' }, FontName := App.FontName, FontSize := App.FontSize 
  
    IF VALTYPE( aTxt ) == 'C' 
       aTxt := { aTxt } 
    ENDIF 
  
    hFont := GetFontHandle( FontName ) 
  
    IF ( lFont := hFont == 0 ) 
       hFont := InitFont( FontName, FontSize ) 
    ENDIF 
  
    FOR EACH cTxt IN aTxt 
        IF Len(cTxt) == 0 
           cTxt := 'W' 
        ENDIF 
        nWidth := Max( nWidth, GetTextWidth( 0, cTxt, hFont ) ) 
        IF nHeight == 0 
           nHeight := GetTextHeight( 0, cTxt, hFont ) 
        ENDIF 
    NEXT 
  
    IF lFont 
       DeleteObject( hFont ) 
    EndIf 
  
 RETURN { nWidth, nHeight } 
 

   DEFINE TAB Tab_1 OF Form_Card ; 
      ......... 
       ON CHANGE SizePageBack( Form_Card.Tab_1.Value ) 
         
       _HMG_ActiveTabBottom := .F. // lBottomStyle 
  
        FOR nI := 1 TO LEN( aTabName ) 
           IF aStatCheckTabView[nI] // показ вкладки разрешено ! 
              PAGE aTabName[ nI ]  //IMAGE cResTabImage 
                 cNameLabel := 'Page_' + hb_ntos( nI ) 
                 @ 24, 2 LABEL &cNameLabel VALUE "" WIDTH 0 HEIGHT 0 BACKCOLOR aTabColor[nI] 
                 // вывести поля карточки 
                 ShowPageCard( nI, nRowTab, aTabColor[ nI ], aDimCard[ nI ],; 
                                aFontNames, aFontFields, lEditPrg, nFSizeTab )    
              END PAGE 
           ENDIF   
        NEXT 
  
    END TAB 
  
    // Assign the colors to the Tab bookmarks 
    Form_Card.Tab_1.Cargo := aTabColor

 
 #include "minigui.ch"   
 #include "tsbrowse.ch"   
   
 REQUEST SQLMIX   
   
 Procedure Main()   
   
 rddSetDefault( "SQLMIX" )   
   
 DEFINE WINDOW Form1 ;   
 	AT 0,0 ;   
 	WIDTH (RR_GetDesktopArea()[4] * 0.99) ;   
 	HEIGHT (RR_GetDesktopArea()[3] * 0.91) ;   
 	TITLE "TsBrowse Array Test" ;   
 	MAIN ;   
 	FONT 'Tahoma' SIZE 9   
   
 END WINDOW   
   
 Test()  
   
 Form1.Center   
 Form1.ACTIVATE   
   
 Return   
   
 *--------------------------------------------------------------   
   
 Function Test()   
 local i := 0   
 local j := 0   
 Local aStr := {}   
 local cAlias := "TEST"   
 local cBrw := "BRW"   
   
 PUBLIC &cBrw   
   
 FOR j := 1 TO 300   
 	AADD( aStr, {"F_" + NTOC(j) , "N", 14, 2 } )  
 NEXT  
   
 dbCreate( cAlias, aStr,, .T., cAlias )   
   
 FOR i := 1 TO 100   
 	(cAlias)->( DbAppend() )  
 	FOR j := 1 TO 300   
 		(cAlias)->( FieldPut(j, i*j) )  
 	NEXT  
 NEXT  
   
 DEFINE TBROWSE &cBrw ;  
 	At 20, 5 ;  
 	ALIAS cAlias ;   
 	OF Form1 ;   
 	WIDTH (Form1.Width - 20) ;   
 	HEIGHT (Form1.Height - 70) ;   
 	COLORS { CLR_BLACK, CLR_WHITE } ;   
 	FONT "MS Sans Serif" ;   
 	SIZE 8 ;   
 	CELL;   
 	SELECTOR .T.  
 END TBROWSE   
   
 //&cBrw:bUserKeys := { |x,y,z| left_right_key(x, y, z) }  
 //&cBrw:bChange := { |x| tbrow_refresh(x) }  
   
 &cBrw:LoadFields( FALSE )   
  
 &cBrw:bEvents := {|ob,nm,np,nl| tsb_events(ob,nm,np,nl) } 
   
 Return Nil  
  
 function tsb_events( oBrw, nMsg, nWParam, nLParam ) 
    Local nRet   := 0, nKey, nFlag 
    Local lCtrl  := _GetKeyState( VK_CONTROL ) 
    Local lShift := _GetKeyState( VK_SHIFT   ) 
    Local lAlt   := _GetKeyState( VK_MENU    ) 
    Static n_CntLeft := 0, n_CntRight := 0, n_LeftRight := 5 
  
    nKey  := nWParam 
    nFlag := nLParam 
  
    If lCtrl .or. lShift .or. lAlt 
    ElseIf nMsg == WM_KEYDOWN 
       If    nKey == VK_LEFT 
          n_CntLeft ++ 
          If n_CntLeft >= n_LeftRight 
             nRet := 1 
             InkeyGui(100) 
             n_CntLeft := 0 
          EndIf 
          DoEvents() 
       ElseIf nKey == VK_RIGHT 
          n_CntRight ++ 
          If n_CntRight >= n_LeftRight 
             nRet := 1 
             InkeyGui(100) 
             n_CntRight := 0 
          EndIf 
          DoEvents() 
       EndIf 
    ElseIf nMsg == WM_KEYUP 
       n_CntLeft := n_CntRight := 0 
    EndIf 
  
 return nRet 
  

 
 #include "minigui.ch" 
 #include "TSBrowse.ch" 
  
  
 PROCEDURE MAIN 
  
    LOCAL oBrw, aDatos, aArray, aHead, aSize, aFoot, aPict, aAlign, aName, aFontHF 
    LOCAL aFont := {} 
    // Local hFontHead, hFontFoot 
    LOCAL cFontName := _HMG_DefaultFontName 
    LOCAL nFontSize := 11 
  
    SET DECIMALS TO 4 
    SET DATE     TO GERMAN 
    SET EPOCH    TO 2000 
    SET CENTURY  ON 
    SET EXACT    ON 
  
    DEFINE FONT Font_1  FONTNAME cFontName SIZE nFontSize 
    DEFINE FONT Font_2  FONTNAME cFontName SIZE nFontSize BOLD 
  
    AAdd( aFont, GetFontHandle( "Font_1" ) ) 
    AAdd( aFont, GetFontHandle( "Font_2" ) ) 
  
    DEFINE WINDOW test ; 
       TITLE "SetArray For Report Demo" ; 
       MAIN ; 
       NOMAXIMIZE NOSIZE 
  
    DEFINE STATUSBAR FONT cFontName SIZE nFontSize 
       STATUSITEM "0"                 // WIDTH 0 FONTCOLOR BLACK 
       STATUSITEM "Item 1" WIDTH 230  // FONTCOLOR BLACK 
       STATUSITEM "Item 2" WIDTH 230  // FONTCOLOR BLACK 
       STATUSITEM "Item 3" WIDTH 230  // FONTCOLOR BLACK 
    END STATUSBAR 
  
    DEFINE TBROWSE oBrw ; 
       AT 1 + iif( IsVistaOrLater(), GetBorderWidth()/2, 0 ), ; 
          1 + iif( IsVistaOrLater(), GetBorderHeight()/2, 0 ) ; 
       WIDTH test.WIDTH - 2 * GetBorderWidth() ; 
       HEIGHT test.HEIGHT - GetTitleHeight() - ; 
          GetProperty( "test", "StatusBar", "Height" ) - ; 
          2 * GetBorderHeight() ; 
       ENUMERATOR ; 
       FONT  cFontName  SIZE  nFontSize ; 
       GRID  EDIT 
  
       aDatos   := CreateDatos() 
  
       aArray   := aDatos[ 1 ] 
       aHead    := aDatos[ 2 ] 
       aSize    := aDatos[ 3 ] 
       aFoot    := aDatos[ 4 ] 
       aPict    := aDatos[ 5 ] 
       aAlign   := aDatos[ 6 ] 
       aName    := aDatos[ 7 ] 
  
    // hFontHead := aFont[1]                // normal Header 
    // hFontFoot := aFont[2]                //  bold  Footer 
    // aFontHF   := { hFontHead, hFontFoot } 
  
    // aFontHF   := aFont[1]                // normal Header, Footer 
       aFontHF   := aFont[2]                //  bold  Header, Footer 
  
       oBrw := SetArrayTo( "oBrw", "test", aArray, aFontHF, aHead, aSize, aFoot, aPict, aAlign, aName ) 
  
       oBrw:nWheelLines    := 1 
       oBrw:nClrLine       := COLOR_GRID 
       oBrw:nHeightCell    += 5 
       oBrw:nHeightHead    += 5 
       IF ! Empty( aFoot ) 
          oBrw:nHeightFoot += 5 
       ENDIF 
       IF oBrw:lEnum 
          oBrw:nHeightSpecHd := oBrw:nHeightCell 
       ENDIF 
  
       oBrw:nFreeze     := 2 
       oBrw:lLockFreeze := .T. 
       oBrw:bEvents     := {|ob,nm,np,nl| tsb_events(ob,nm,np,nl) } 
       oBrw:nCell       := oBrw:nFreeze + 1 
  
    END TBROWSE 
  
    oBrw:SetNoHoles() 
    oBrw:SetFocus() 
  
    END WINDOW 
  
    DoMethod( "test", "Activate" ) 
  
 RETURN 
  
 * ====================================================================== 
  
 STATIC FUNCTION CreateDatos() 
  
    LOCAL a, b, i, j, k := 1000, n 
    LOCAL aDatos, aHead, aSize, aFoot, aPict, aAlign, aName 
  
    aDatos := Array( k ) 
    FOR i := 1 TO k 
        a := { " ", ;                                  // 1 
          i, ;                                         // 2 
          ntoc( i ) + "_123", ;                        // 3 
          Date() + i, ;                                // 4 
          PadR( "Test line - " + ntoc( i ), 20 ), ;    // 5 
          Round( ( 10000 -i ) * i / 3, 2 ), ;          // 6 
          100.00 * i, ;                                // 7 
          0.12, ;                                      // 8 
          Round( 100.00 * i * 0.12, 2 ), ;             // 9 
          Round( 1234567.00 / i, 3 ), ;                // 10 
          PadR( "Line " + StrZero( i, 5 ), 20 ), ;     // 11 
          Date(), ;                                    // 12 
          Time(), ;                                    // 13 
          i % 2 == 0 }                                 // 14 
        n := Len(a) 
        FOR b := 1 TO 10 
            FOR j := 1 TO n ; AAdd(a, a[ j ]) 
            NEXT 
        NEXT 
        aDatos[ i ] := a 
    NEXT 
  
    aHead  := AClone( aDatos[ 1 ] ) 
    // AEval(aHead, {|x,n| aHead[ n ] := "Head_" + hb_ntos(n) }) 
    AEval( aHead, {| x, n| aHead[ n ] := "H_" + hb_ntos( n ) + ; 
       iif( n % 2 == 0, CRLF + "S_" + hb_ntos( n ), "" ) } ) 
  
    aFoot  := Array( Len( aDatos[ 1 ] ) ) 
    AEval( aFoot, {| x, n| aFoot[ n ] := n } ) 
    // aFoot  := .T.                        // подножие есть с пустыми значениями 
  
    aPict     := Array( Len( aDatos[ 1 ] ) )   // можно не задавать, формируются 
    aPict[ 10 ] := "99999999999.999"           // автоматом для C,N по мах значению 
  
    aSize     := Array( Len( aDatos[ 1 ] ) )   // можно не задавать, формируются 
    aSize[ 10 ] := aPict[ 10 ]                 // автоматом по мах значению в колонке 
  
    aAlign    := Array( Len( aDatos[ 1 ] ) )   // тип поля C   - DT_LEFT 
    aAlign[ 2 ] := DT_CENTER                   // D,L - DT_CENTER 
                                               // N   - DT_RIGHT 
  
    aName     := Array( Len( aDatos[ 1 ] ) ) 
    AEval( aName, {| x, n| aName[ n ] := "MyName_" + hb_ntos( n ) } ) 
  
 RETURN { aDatos, aHead, aSize, aFoot, aPict, aAlign, aName } 
  
 function tsb_events( oBrw, nMsg, nWParam, nLParam ) 
    Local nRet   := 0, nKey, nFlag, nCol, nFrez 
    Local lCtrl  := _GetKeyState( VK_CONTROL ) 
    Local lShift := _GetKeyState( VK_SHIFT   ) 
    Local lAlt   := _GetKeyState( VK_MENU    ) 
    Static n_CntLeft := 0, n_CntRight := 0, n_LeftRight := 3 
  
    nCol  := oBrw:nCell 
    nFrez := oBrw:nFreeze + 1 
    nKey  := nWParam 
    nFlag := nLParam 
  
    If lCtrl .or. lShift .or. lAlt 
    ElseIf nMsg == WM_KEYDOWN 
       If    nKey == VK_LEFT .and. nCol > nFrez 
          n_CntLeft ++ 
          If n_CntLeft >= n_LeftRight 
             nRet := 1 
             InkeyGui(100) 
             n_CntLeft := 0 
          EndIf 
          DoEvents() 
       ElseIf nKey == VK_RIGHT .and. nCol <= oBrw:nColCount() 
          n_CntRight ++ 
          If n_CntRight >= n_LeftRight 
             nRet := 1 
             InkeyGui(100) 
             n_CntRight := 0 
          EndIf 
          DoEvents() 
       EndIf 
    ElseIf nMsg == WM_KEYUP 
       n_CntLeft := n_CntRight := 0 
    EndIf 
  
 return nRet