/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  * 
  * Copyright 2021 Sergej Kiselev <bilance@bilance.lv> 
  * Copyright 2021 Verchenko Andrey <verchenkoag@gmail.com> 
 */ 
 ANNOUNCE RDDSYS 
  
 #define _HMG_OUTLOG 
  
 #include "minigui.ch" 
  
 Function Main 
    Local nFSize := 16, cFName := "Arial" 
    Local nWDate, nWTime, x, y, nG, x2, cTime, oGet, cSay, nHObj 
    Local ix,cv 
  
    SET CENTURY ON 
  
    SET NAVIGATION EXTENDED 
  
    nWDate := 290 
    nWTime := 160 
    nG     := 20 
    cTime  := Space(6) 
    nHObj  := nFSize*2 
  
    DEFINE WINDOW Form_1 ; 
       AT 0,0 ; 
       WIDTH 600 ; 
       HEIGHT 490 ; 
       TITLE "MiniGUI Date + Time Demo" ; 
       MAIN ; 
       FONT cFName SIZE nFSize 
  
       y := 20 
       x := nG 
  
       cSay := "Period from:" 
       @ y, x LABEL Label_1 VALUE cSay WIDTH nWDate HEIGHT nHObj 
  
       y += Form_1.Label_1.Height 
  
       // дата период начало 
       @ y, x DATEPICKER Date_1 VALUE DATE() WIDTH nWDate HEIGHT nHObj ; 
         DATEFORMAT "dd'.'MMMM' 'yyyy" SHOWNONE 
  
       x2 := Form_1.Date_1.Col + Form_1.Date_1.Width + nG 
  
       // время период начало 
       @ y, x2 GETBOX Time_1 OBJ oGet VALUE cTime WIDTH nWTime HEIGHT nHObj  ; 
         PICTURE "@R 99:99:99" VALID {|og| bValid( og ) } BUTTONWIDTH nHObj  ; 
         ON GOTFOCUS {|| SendMessage(This.Handle, 177 /*EM_SETSEL*/, 0, Len( This.Value )) } ; 
         ON INIT {|| _SetAlign ( This.Name, ThisWindow.Name, "CENTER" ) } ; 
         IMAGE {"MINIGUI_EDIT_CANCEL",NIL } ; 
         ACTION  ( This.Value := space(6) ) 
  
       y += Form_1.Date_1.Height + nG*2 
  
       cSay := "Period to:" 
       @ y, x LABEL Label_2 VALUE cSay WIDTH nWDate HEIGHT nHObj 
  
       y += Form_1.Label_2.Height 
  
       // дата период конец 
       @ y, x DATEPICKER Date_2 VALUE DATE()+2 WIDTH nWDate HEIGHT nHObj ; 
         DATEFORMAT "dd'.'MMMM' 'yyyy" SHOWNONE 
  
       // время период конец 
       @ y, x2 GETBOX Time_2 OBJ oGet VALUE cTime WIDTH nWTime HEIGHT nHObj ; 
         PICTURE "@R 99:99:99" VALID {|og| bValid( og ) } BUTTONWIDTH nHObj ; 
         ON GOTFOCUS {|| SendMessage(This.Handle, 177 /*EM_SETSEL*/, 0, Len( This.Value )) } ; 
         ON INIT {|| _SetAlign ( This.Name, ThisWindow.Name, "CENTER" ) } ; 
         IMAGE { "MINIGUI_EDIT_CANCEL", "MINIGUI_EDIT_OK" }               ; 
         ACTION  ( This.Time_2.Value := cTime )    ; 
         ACTION2 ( This.Time_2.Value := "235959" ) 
  
       y += Form_1.Date_2.Height + nG 
  
       @ y, x BUTTON Button_1 CAPTION "Get search bar"  ; 
         WIDTH nWDate + nWTime + nG HEIGHT 35 ; 
         ACTION ( Form_1.Label_Search.Value := mySearchString() ) 
  
       y += Form_1.Button_1.Height + nG * 2 
  
       @ y, x LABEL Label_Search VALUE "Search line:" WIDTH Form_1.Width - 40 ; 
         HEIGHT 80 TOOLTIP "Search line" FONTCOLOR RED 
  
    END WINDOW 
  
    CENTER WINDOW Form_1 
    ACTIVATE WINDOW Form_1 
  
 Return Nil 
  
 * ----------------------------------------------------------------------------------- * 
 Function mySearchString() 
 * ----------------------------------------------------------------------------------- * 
    Local cDate1, cDate2, cTime1, cTime2, cRet 
  
    cDate1 := HB_DTOC( Form_1.Date_1.Value, 'YYYY-MM-DD') 
    cDate2 := HB_DTOC( Form_1.Date_2.Value, 'YYYY-MM-DD') 
    cTime1 := left(trim(This.Time_1.Value) + repl("0", 6), 6) 
    cTime2 := left(trim(This.Time_2.Value) + repl("0", 6), 6) 
    cTime1 := Transform(cTime1, "@R 99:99:99") 
    cTime2 := Transform(cTime2, "@R 99:99:99") 
    cRet   := "" 
  
    // поиск по полю TSZ типа "T@=" 
    // = ModTime 8 Last modified date & time of this record 
    // @ DayTime 8 Date & Time 
    // T Time 4 or 8 Only time (if width is 4 ) or Date & Time (if width is 8 ) 
  
    IF VAL(cTime1) > 0 .OR. VAL(cTime2) > 0  // время задано 
       cRet  += '( HB_TSTOSTR(SKLAD->TSZ) >= "'+cDate1+'" .AND. ' 
       cRet  += 'HB_TSTOSTR(SKLAD->TSZ) <= "'+cDate2+'" )' 
       cRet  += ' ???? ' + cTime1 + ' ???? ' + cTime2 
    ELSE 
       // время не задано 
       cRet  += '( HB_TSTOSTR(SKLAD->TSZ) >= "'+cDate1+'" .AND. ' 
       cRet  += 'HB_TSTOSTR(SKLAD->TSZ) <= "'+cDate2+'" )' 
    ENDIF 
    cRet  += ' .AND. !DELETED()' 
  
 Return cRet 
  
 * ----------------------------------------------------------------------------------- * 
 STATIC FUNCTION bValid( oGet, nPost )  // проверка правильности времени в GetBox 
 * ----------------------------------------------------------------------------------- * 
    LOCAL lRet, lVl1, lVl2, lVl3, nVal 
    LOCAL cVal := left(trim(oGet:VarGet()) + repl("0", 6), 6) 
    LOCAL hGet := This.Handle 
    LOCAL hWnd := ThisWindow.Handle 
  
    lVl1 := lVl2 := lVl3 := .F. 
  
    nVal := Val(left(cVal, 2)) 
    IF nVal >= 0 .and. nVal < 24 ; lVl1 := .T. 
    ENDIF 
    nVal := Val(subs(cVal, 3, 2)) 
    IF nVal >= 0 .and. nVal < 60 ; lVl2 := .T. 
    ENDIF 
    nVal := Val(subs(cVal, 5, 2)) 
    IF nVal >= 0 .and. nVal < 60 ; lVl3 := .T. 
    ENDIF 
  
    lRet := lVl1 .and. lVl2 .and. lVl3 
  
    IF ! lRet 
       // есть команды\ф-ии управления временем Tooltip, если надо исп. ShowGetValid можно применить 
       // т.е. сохранить старое, поставить новое и потом после ShowGetValid (InkeyGui) восстановить 
       SetFocus(hGet) 
       ShowGetValid( hGet, This.Name+": Задайте правильно значение времени ! ", 'ОШИБКА '+ThisWindow.Name, 'E' ) 
       InkeyGui( 5 * 1000 ) 
       SetFocus(hWnd) 
  
       oGet:VarPut(space(6)) 
       oGet:Refresh() 
       SetFocus(hGet) 
       lRet := .T. 
    ENDIF 
  
 RETURN lRet 
  
 #pragma BEGINDUMP 
  
 #define _WIN32_WINNT 0x0600 
  
 #include <windows.h> 
  
 #include "hbapi.h" 
 #include "hbapicdp.h" 
  
 #include <commctrl.h> 
  
 #if ( defined( __BORLANDC__ ) && __BORLANDC__ < 0x582 ) 
 typedef struct _tagEDITBALLOONTIP 
 { 
    DWORD   cbStruct; 
    LPCWSTR pszTitle; 
    LPCWSTR pszText; 
    INT     ttiIcon; // From TTI_* 
 } EDITBALLOONTIP, *PEDITBALLOONTIP; 
  
 #define EM_SHOWBALLOONTIP   (ECM_FIRST + 3)     // Show a balloon tip associated to the edit control 
 #define Edit_ShowBalloonTip(hwnd, peditballoontip)  (BOOL)SNDMSG((hwnd), EM_SHOWBALLOONTIP, 0, (LPARAM)(peditballoontip)) 
 #define EM_HIDEBALLOONTIP   (ECM_FIRST + 4)     // Hide any balloon tip associated with the edit control 
 #define Edit_HideBalloonTip(hwnd)  (BOOL)SNDMSG((hwnd), EM_HIDEBALLOONTIP, 0, 0) 
  
 #define ECM_FIRST               0x1500      // Edit control messages 
 #endif  // (__BORLANDC__ < 0x582) 
  
 // ToolTip Icons (Set with TTM_SETTITLE) 
 #define TTI_NONE                0 
 #define TTI_INFO                1 
 #define TTI_WARNING             2 
 #define TTI_ERROR               3 
 #if (_WIN32_WINNT >= 0x0600) 
   #define TTI_INFO_LARGE        4 
   #define TTI_WARNING_LARGE     5 
   #define TTI_ERROR_LARGE       6 
 #endif  // (_WIN32_WINNT >= 0x0600) 
  
 /* 
    ShowGetValid( hWnd, cText [ , cTitul ]   [ , cTypeIcon ] ) 
 */ 
  
 #if ( HB_VER_MAJOR == 3 ) 
   #define _hb_cdpGetU16( cdp, fCtrl, ch)  hb_cdpGetU16(cdp, ch ) 
   #define _hb_cdpGetChar(cdp, fCtrl, ch)  hb_cdpGetChar(cdp, ch) 
 #else 
   #define _hb_cdpGetU16( cdp, fCtrl, ch)  hb_cdpGetU16(cdp, fCtrl, ch ) 
   #define _hb_cdpGetChar(cdp, fCtrl, ch)  hb_cdpGetChar(cdp, fCtrl, ch) 
 #endif 
  
 HB_FUNC( SHOWGETVALID ) 
 { 
    int i, k; 
    const char *tp, *s; 
    WCHAR Text[512]; 
    WCHAR Title[512]; 
  
    EDITBALLOONTIP bl; 
  
    PHB_CODEPAGE  s_cdpHost = hb_vmCDP(); 
  
    HWND hWnd = ( HWND ) hb_parnl(1); 
  
    if( ! IsWindow( hWnd ) ) 
       return; 
  
    bl.cbStruct = sizeof( EDITBALLOONTIP ); 
    bl.pszTitle = NULL; 
    bl.pszText  = NULL; 
    bl.ttiIcon  = TTI_NONE; 
  
    if( HB_ISCHAR( 2 ) ){ 
  
        ZeroMemory( Text,  sizeof(Text) ); 
  
        k = hb_parclen(2); 
        s = (const char *) hb_parc(2); 
        for(i=0;i<k;i++) Text[ i ] = _hb_cdpGetU16( s_cdpHost, TRUE, s[ i ] ); 
        bl.pszText  = Text; 
    } 
  
    if( HB_ISCHAR( 3 ) ){ 
  
        ZeroMemory( Title,  sizeof(Title) ); 
  
        k = hb_parclen(3); 
        s = (const char *) hb_parc(3); 
        for(i=0;i<k;i++) Title[ i ] = _hb_cdpGetU16( s_cdpHost, TRUE, s[ i ] ); 
        bl.pszTitle  = Title; 
    } 
  
    tp = ( const char * ) hb_parc(4); 
  
    switch( *tp ){ 
        case 'E' :  bl.ttiIcon  = TTI_ERROR_LARGE;   break; 
        case 'e' :  bl.ttiIcon  = TTI_ERROR;         break; 
  
        case 'I' :  bl.ttiIcon  = TTI_INFO_LARGE;    break; 
        case 'i' :  bl.ttiIcon  = TTI_INFO;          break; 
  
        case 'W' :  bl.ttiIcon  = TTI_WARNING_LARGE; break; 
        case 'w' :  bl.ttiIcon  = TTI_WARNING;       break; 
  
    } 
  
    Edit_ShowBalloonTip( hWnd, &bl ); 
  
 } 
  
 #pragma ENDDUMP