/* 
  * MiniGUI ComboBox Demo 
 */ 
  
 #include "minigui.ch" 
  
 Function Main 
    Local cClr, nClr, aClr 
    Local aItems := {    'RED',    'BLUE',    'GREEN',    'YELLOW' } 
    Local aClrA  := {     RED ,     BLUE ,     GREEN ,     YELLOW  } 
    Local aClrN  := { CLR_RED , CLR_BLUE , CLR_GREEN , CLR_YELLOW  } 
  
    DEFINE WINDOW Form_1 ; 
       AT 0,0 ; 
       WIDTH 400 ; 
       HEIGHT 200 ; 
       TITLE 'ComboBox Demo' ; 
       MAIN  
  
       DEFINE MAIN MENU 
          DEFINE POPUP 'Test' 
             ITEM 'Get Value'       ACTION MsgInfo(cValToChar(This.Combo_1.Value)) 
             ITEM 'Get Value Cargo' ACTION MsgInfo(Combo_Val()) 
             SEPARATOR 
             ITEM 'Set Value 1' ACTION Form_1.Combo_1.Value := 1 
             ITEM 'Set Value 2' ACTION Form_1.Combo_1.Value := 2 
             ITEM 'Set Value 3' ACTION Form_1.Combo_1.Value := 3 
             ITEM 'Set Value 4' ACTION Form_1.Combo_1.Value := 4 
             SEPARATOR 
             ITEM 'Get DisplayValue' ACTION MsgInfo( Form_1.Combo_1.DisplayValue ) 
          END POPUP 
       END MENU 
  
       @ 15,20 COMBOBOX Combo_1 ; 
          ITEMS aItems ; 
          VALUE 0 ; 
          DISPLAYEDIT ; 
          LOWERCASE ; 
          FONTCOLOR NAVY ; 
          BACKCOLOR WHITE 
  
       This.Combo_1.Cargo := oHmgData() 
  
       WITH OBJECT This.Combo_1.Cargo 
          FOR EACH cClr, nClr, aClr IN aItems, aClrN, aClrA 
              :Set(cClr, { nClr, aClr }) 
          NEXT 
       END WITH 
  
    END WINDOW 
  
    CENTER WINDOW Form_1 
  
    ACTIVATE WINDOW Form_1 
  
 Return Nil 
  
  
 Static Function Combo_Val() 
    Local cRet := "", cNam, nClr, aClr, nPos, aTmp 
    Local nVal := This.Combo_1.Value 
    Local oVal := This.Combo_1.Cargo 
    Local aNam := oVal:Keys() 
    Local aVal := oVal:Values()  
  
    cRet += cValToChar(nVal) 
  
    IF nVal > 0 
       cNam := aNam[ nVal ] 
       nClr := aVal[ nVal ][1] 
       aClr := aVal[ nVal ][2] 
       nPos := oVal:Pos(cNam) 
       nVal := oVal:Pos( This.Combo_1.DisplayValue ) 
       aTmp := oVal:Get( This.Combo_1.DisplayValue, {,} ) 
       cRet += ": "+cNam+"  "+cValToChar(nClr)+"  "+hb_valtoexp(aClr)+ ; 
                         "  "+cValToChar(nPos)+"  "+cValToChar(nVal)+"  "+hb_valtoexp(aTmp) 
       aTmp := oVal:GetAll() 
       cRet  += CRLF+CRLF + StrTran(hb_valtoexp(aTmp), "},", "},"+CRLF) 
       cRet += CRLF+CRLF+hb_valtoexp(aTmp[ nVal ]) 
    ENDIF 
  
 Return cRet