#include "minigui.ch" 
 #include "TSBrowse.ch" 
  
  
 PROCEDURE MAIN 
  
    LOCAL oBrw, aDatos, aArray, aHead, aSize, aFoot, aPict, aAlign, aName, aFontHF 
    LOCAL aFont := {} 
    // Local hFontHead, hFontFoot 
    LOCAL cFontName := _HMG_DefaultFontName 
    LOCAL nFontSize := 11 
    LOCAL nY, nX, oCol 
    LOCAL cForm := "test" 
  
  
    SET DECIMALS TO 4 
    SET DATE     TO GERMAN 
    SET EPOCH    TO 2000 
    SET CENTURY  ON 
    SET EXACT    ON 
  
    DEFINE FONT Font_1  FONTNAME cFontName SIZE nFontSize 
    DEFINE FONT Font_2  FONTNAME cFontName SIZE nFontSize BOLD 
  
    AAdd( aFont, GetFontHandle( "Font_1" ) ) 
    AAdd( aFont, GetFontHandle( "Font_2" ) ) 
  
    DEFINE WINDOW test ; 
       TITLE "SetArray For Report Demo" ; 
       MAIN ; 
       NOMAXIMIZE NOSIZE 
  
    DEFINE STATUSBAR FONT cFontName SIZE nFontSize 
       STATUSITEM "0"                 // WIDTH 0 FONTCOLOR BLACK 
       STATUSITEM "Item 1" WIDTH 230  // FONTCOLOR BLACK 
       STATUSITEM "Item 2" WIDTH 230  // FONTCOLOR BLACK 
       STATUSITEM "Item 3" WIDTH 230  // FONTCOLOR BLACK 
    END STATUSBAR 
  
  
    DEFINE TBROWSE oBrw ; 
       AT 1 + iif( IsVistaOrLater(), GetBorderWidth()/2, 0 ), ; 
          1 + iif( IsVistaOrLater(), GetBorderHeight()/2, 0 ) ; 
       WIDTH test.WIDTH - 2 * GetBorderWidth() ; 
       HEIGHT test.HEIGHT - GetTitleHeight() - ; 
          GetProperty( "test", "StatusBar", "Height" ) - ; 
          2 * GetBorderHeight() - 50 ; 
       ENUMERATOR ; 
       FONT  cFontName  SIZE  nFontSize ; 
       GRID  EDIT 
  
       aDatos   := CreateDatos() 
  
       aArray   := aDatos[ 1 ] 
       aHead    := aDatos[ 2 ] 
       aSize    := aDatos[ 3 ] 
       aFoot    := aDatos[ 4 ] 
       aPict    := aDatos[ 5 ] 
       aAlign   := aDatos[ 6 ] 
       aName    := aDatos[ 7 ] 
  
    // hFontHead := aFont[1]                // normal Header 
    // hFontFoot := aFont[2]                //  bold  Footer 
    // aFontHF   := { hFontHead, hFontFoot } 
  
    // aFontHF   := aFont[1]                // normal Header, Footer 
       aFontHF   := aFont[2]                //  bold  Header, Footer 
  
       oBrw := SetArrayTo( "oBrw", "test", aArray, aFontHF, aHead, aSize, aFoot, aPict, aAlign, aName ) 
  
 //    oBrw:nLineStyle     := LINES_NONE 
       oBrw:nWheelLines    := 1 
       oBrw:nClrLine       := COLOR_GRID 
       oBrw:nHeightCell    += 5 
       oBrw:nHeightHead    += 5 
       IF ! Empty( aFoot ) 
          oBrw:nHeightFoot += 5 
       ENDIF 
       IF oBrw:lEnum 
          oBrw:nHeightSpecHd := oBrw:nHeightCell 
       ENDIF 
  
       oCol := oBrw:GetColumn("ColName_7") 
       oCol:bPrevEdit := {|uVl,oBr| mPrevEdit(uVl, oBr) } 
 //      oCol:bPostEdit := {|uVl,oBr,lAp| mPostEdit(uVl, oBr, lAp) } 
 //      oCol:bExtEdit  := {|uvl,oBr    | mExtEdit (uVl, oBr )     } 
  
    END TBROWSE 
  
 // контролы ОБЯЗАТЕЛЬНО после TsBrowse, что бы z-ордер был большим у них, чем у TSB 
  
    nY := test.HEIGHT - GetProperty( "test", "StatusBar", "Height" ) - 80 
    nX := 20 
  
    @ nY, nX LABEL Lbl_Test  VALUE ""  WIDTH 40  HEIGHT 40  BACKCOLOR { 35, 179, 15} 
  
    nX += 40 + 10 
  
    @ nY, nX GETBOX Get_Sum1  WIDTH 40  HEIGHT 20  VALUE 0  PICTURE "999.99" ; 
             VALID mGet_Sum() ON LOSTFOCUS mLostFocus() 
  
              
    nX += 40 + 10 
     
    @ nY, nX GETBOX Get_Sum2  WIDTH 40  HEIGHT 20  VALUE 0  PICTURE "999.99" ; 
             VALID mGet_Sum() ON LOSTFOCUS mLostFocus() 
  
    test.Get_Sum1.Cargo := oBrw 
    test.Get_Sum2.Cargo := oBrw 
  
    oBrw:SetFocus() 
  
    END WINDOW 
  
    DoMethod( "test", "Activate" ) 
  
 RETURN 
  
  
 * ====================================================================== 
  
 STATIC FUNCTION CreateDatos() 
  
    LOCAL i, k := 1000, aDatos, aHead, aSize, aFoot, aPict, aAlign, aName 
  
    aDatos := Array( k ) 
    FOR i := 1 TO k 
       aDatos[ i ] := { " ", ;                         // 1 
          i, ;                                         // 2 
          ntoc( i ) + "_123", ;                        // 3 
          Date() + i, ;                                // 4 
          PadR( "Test line - " + ntoc( i ), 20 ), ;    // 5 
          Round( ( 10000 -i ) * i / 3, 2 ), ;          // 6 
          100.00 * i, ;                                // 7 
          0.12, ;                                      // 8 
          Round( 100.00 * i * 0.12, 2 ), ;             // 9 
          Round( 1234567.00 / i, 3 ), ;                // 10 
          PadR( "Line " + StrZero( i, 5 ), 20 ), ;     // 11 
          Date(), ;                                    // 12 
          Time(), ;                                    // 13 
          i % 2 == 0 }                                 // 14 
    NEXT 
  
    aHead  := AClone( aDatos[ 1 ] ) 
    // AEval(aHead, {|x,n| aHead[ n ] := "Head_" + hb_ntos(n) }) 
    AEval( aHead, {| x, n| aHead[ n ] := "Head" + hb_ntos( n ) + ; 
       iif( n % 2 == 0, CRLF + "SubHead" + hb_ntos( n ), "" ) } ) 
  
    aFoot  := Array( Len( aDatos[ 1 ] ) ) 
    AEval( aFoot, {| x, n| aFoot[ n ] := n } ) 
    // aFoot  := .T.                        // подножие есть с пустыми значениями 
  
    aPict     := Array( Len( aDatos[ 1 ] ) )   // можно не задавать, формируются 
    aPict[ 10 ] := "99999999999.999"           // автоматом для C,N по мах значению 
  
    aSize     := Array( Len( aDatos[ 1 ] ) )   // можно не задавать, формируются 
    aSize[ 10 ] := aPict[ 10 ]                 // автоматом по мах значению в колонке 
  
    aAlign    := Array( Len( aDatos[ 1 ] ) )   // тип поля C   - DT_LEFT 
    aAlign[ 2 ] := DT_CENTER                   // D,L - DT_CENTER 
                                               // N   - DT_RIGHT 
  
    aName     := Array( Len( aDatos[ 1 ] ) ) 
    AEval( aName, {| x, n| aName[ n ] := "ColName_" + hb_ntos( n ) } ) 
  
 RETURN { aDatos, aHead, aSize, aFoot, aPict, aAlign, aName } 
  
 Function GetCellSize( oBrw, nRowPos, nCell, lColSpecHd ) // координаты и размеры ячейки TsBrowse 
 LOCAL nI, ix, nStartX := 0, oCol, cBrw, cForm 
 LOCAL nRow, nCol, nWidth, nHeight 
  
    Default nRowPos    := oBrw:nRowPos, ; 
            nCell      := oBrw:nCell, ; 
            lColSpecHd := .F. 
  
    cForm := oBrw:cParentWnd 
    cBrw  := oBrw:cControlName 
    oCol  := oBrw:aColumns[ nCell ] 
  
    If oBrw:nFreeze > 0 
       For nI := 1 To Min( oBrw:nFreeze , nCell - 1 ) 
          nStartX += oBrw:GetColSizes()[ nI ] 
       Next 
    EndIf 
  
    For nI := oBrw:nColPos To nCell - 1 
       nStartX += oBrw:GetColSizes()[ nI ] 
    Next 
  
    IF lColSpecHd                  // ячейка в SpecHeader 
       nRow    := oBrw:nHeightHead + oBrw:nHeightSuper + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := oBrw:GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 1 ) 
       nHeight := oBrw:nHeightSpecHd - If( oCol:l3DLook, 1, -1 ) 
    else                           // ячейка в таблице 
       nRow    := nRowPos - 1 
       nRow    := ( nRow * oBrw:nHeightCell ) + oBrw:nHeightHead + ; 
                  oBrw:nHeightSuper + oBrw:nHeightSpecHd + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := oBrw:GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 0 ) 
       nHeight := oBrw:nHeightCell - If( oCol:l3DLook, 1, -1 ) 
    endif 
  
    ix := GetControlIndex ( cBrw, cForm )     // размеры и координаты как для 
    if _HMG_aControlContainerRow [ix] == -1   // TGETBOX !!! 
       nRow += oBrw:nTop - 1 
       nCol += oBrw:nLeft 
    else 
       nRow += _HMG_aControlRow [ix] - 1 
       nCol += _HMG_aControlCol [ix] 
    endif 
  
    nRow    += oBrw:aEditCellAdjust[1] 
    nCol    += oBrw:aEditCellAdjust[2] 
    nWidth  += oBrw:aEditCellAdjust[3] + 2 
    nHeight += oBrw:aEditCellAdjust[4] + 2 
  
 Return { nRow, nCol, nWidth, nHeight } 
  
 STATIC FUNCTION mLostFocus() 
 LOCAL ix, lSum, hFocus := GetFocus() 
 LOCAL cForm := _HMG_ThisFormName 
 LOCAL cSm1  := "Get_Sum1" 
 LOCAL cSm2  := "Get_Sum2" 
  
  If hFocus != 0 
     ix := ascan(_HMG_aControlHandles, hFocus) 
     If ix > 0 
        lSum := _HMG_aControlNames[ ix ] == cSm1 .or. ; 
                _HMG_aControlNames[ ix ] == cSm2 
        If ! lSum 
           SetProperty(cForm, cSm1, "Visible", .F.) 
           SetProperty(cForm, cSm2, "Visible", .F.) 
        EndIf 
     EndIf 
  EndIf 
  
  
 RETURN Nil 
  
 STATIC FUNCTION mGet_Sum() 
 LOCAL lRet  := .T., nCell, oCol, nSm1, nSm2, nSum 
 LOCAL cForm := _HMG_ThisFormName 
 LOCAL cName := _HMG_ThisControlName 
 LOCAL oBrw  := GetProperty(cForm, cName, "Cargo") 
 LOCAL cSm1  := "Get_Sum1" 
 LOCAL cSm2  := "Get_Sum2" 
  
  If Valtype(oBrw) == "O" 
     nCell := oBrw:nCell 
     oCol  := oBrw:GetColumn(nCell) 
     If cName == "Get_Sum2" 
        nSm1 := GetProperty(cForm, cSm1, "Value") 
        nSm2 := GetProperty(cForm, cSm2, "Value") 
        nSum := nSm1 * nSm2 
        mPostEdit(nSum, oBrw) 
     EndIf 
  EndIf 
  
 RETURN lRet 
  
 STATIC FUNCTION mPrevEdit( uVal, oBrw ) 
 LOCAL cForm   := oBrw:cParentWnd 
 LOCAL cBrw    := oBrw:cControlName 
 LOCAL nRowPos := oBrw:nRowPos 
 LOCAL nCell   := oBrw:nCell 
 LOCAL oCol    := oBrw:aColumns[ nCell ] 
 LOCAL lRet    := .T., aS, nY, nX, nW, nH, nD := 4 
 LOCAL cLbl    := "Lbl_Test" 
 LOCAL cSm1    := "Get_Sum1" 
 LOCAL cSm2    := "Get_Sum2" 
  
  If oCol:cName == "ColName_7" 
     aS := GetCellSize(oBrw, nRowPos, nCell - 1) 
  
     nY := aS[1]         
     nX := aS[2] 
     nW := aS[3] 
     nH := aS[4] 
     SetProperty(cForm, cSm1, "Row"    , nY) 
     SetProperty(cForm, cSm1, "Col"    , nX) 
     SetProperty(cForm, cSm1, "Width"  , nW) 
     SetProperty(cForm, cSm1, "Height" , nH) 
     SetProperty(cForm, cSm1, "Visible", .T.) 
     SetProperty(cForm, cSm1, "Value"  , 0) 
  
     nY := aS[1] + aS[4] 
     nX := aS[2] 
     nW := aS[3] 
     nH := aS[4] 
     SetProperty(cForm, cSm2, "Row"    , nY) 
     SetProperty(cForm, cSm2, "Col"    , nX) 
     SetProperty(cForm, cSm2, "Width"  , nW) 
     SetProperty(cForm, cSm2, "Height" , nH) 
     SetProperty(cForm, cSm2, "Visible", .T.) 
     SetProperty(cForm, cSm2, "Value"  , 0) 
  
     DoMethod(cForm, cSm1, "SetFocus") 
  
     lRet := .F. 
  EndIf 
  
 RETURN lRet 
  
 STATIC FUNCTION mPostEdit( uVal, oBrw, lApp ) 
 LOCAL cForm   := oBrw:cParentWnd 
 LOCAL cBrw    := oBrw:cControlName 
 LOCAL nCell   := oBrw:nCell 
 LOCAL oCol    := oBrw:aColumns[ nCell ] 
 LOCAL lRet    := .T. 
 LOCAL cLbl    := "Lbl_Test" 
 LOCAL cSm1    := "Get_Sum1" 
 LOCAL cSm2    := "Get_Sum2" 
 LOCAL nSum 
  
  If oCol:cName == "ColName_7" 
     SetProperty(cForm, cSm2, "Visible", .F.) 
     SetProperty(cForm, cSm1, "Visible", .F.) 
     nSum := EVal(oCol:bData) 
     If uVal != nSum 
        oBrw:aArray[oBrw:nAt][nCell] := uVal 
        oBrw:DrawSelect() 
     EndIf 
  EndIf 
  
 RETURN lRet 
 

 
 CLASS TSBcell 
  
  VAR nRow       AS NUMERIC  INIT 0 
  VAR nCol       AS NUMERIC  INIT 0 
  VAR nWidth     AS NUMERIC  INIT 0 
  VAR nHeight    AS NUMERIC  INIT 0 
   
  METHOD New()   INLINE ( Self ) 
  
 ENDCLASS 
  
  
 METHOD GetCellInfo( nRowPos, nCell, lColSpecHd ) CLASS TSBrowse 
 LOCAL nI, ix, nStartX := 0, oCol, cBrw, cForm 
 LOCAL nRow, nCol, nWidth, nHeight 
 LOCAL oCell := TSBcell():New() 
  
    Default nRowPos    := ::nRowPos, ; 
            nCell      := ::nCell, ; 
            lColSpecHd := .F. 
  
    cForm := ::cParentWnd 
    cBrw  := ::cControlName 
    oCol  := ::aColumns[ nCell ] 
  
    If ::nFreeze > 0 
       For nI := 1 To Min( ::nFreeze , nCell - 1 ) 
          nStartX += ::GetColSizes()[ nI ] 
       Next 
    EndIf 
  
    For nI := ::nColPos To nCell - 1 
       nStartX += ::GetColSizes()[ nI ] 
    Next 
  
    IF lColSpecHd  
       nRow    := ::nHeightHead + ::nHeightSuper + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := ::GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 1 ) 
       nHeight := ::nHeightSpecHd - If( oCol:l3DLook, 1, -1 ) 
    else     
       nRow    := nRowPos - 1 
       nRow    := ( nRow * ::nHeightCell ) + ::nHeightHead + ; 
                  ::nHeightSuper + ::nHeightSpecHd + If( oCol:l3DLook, 2, 0 ) 
       nCol    := nStartX + If( oCol:l3DLook, 2, 0 ) 
       nWidth  := ::GetColSizes()[ nCell ] - If( oCol:l3DLook, 2, 0 ) 
       nHeight := ::nHeightCell - If( oCol:l3DLook, 1, -1 ) 
    endif 
  
    ix := GetControlIndex ( cBrw, cForm )   
    if _HMG_aControlContainerRow [ix] == -1 
       nRow += ::nTop - 1 
       nCol += ::nLeft 
    else 
       nRow += _HMG_aControlRow [ix] - 1 
       nCol += _HMG_aControlCol [ix] 
    endif 
  
    nRow    += ::aEditCellAdjust[1] 
    nCol    += ::aEditCellAdjust[2] 
    nWidth  += ::aEditCellAdjust[3] + 2 
    nHeight += ::aEditCellAdjust[4] + 2 
  
    oCell:nRow    := nRow 
    oCell:nCol    := nCol 
    oCell:nWidth  := nWidth 
    oCell:nHeight := nHeight 
  
 Return oCell