/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  * 
 */ 
  
 #include "minigui.ch" 
 #include "TSBrowse.ch" 
  
 #translate dbcreate(<file>, <struct>) => hb_dbcreatetemp(<file>, <struct>) 
  
 Function Main 
 	dbcreate('test',{{'nazwa','C',30,0},; 
 		{'ilosc','N',12,2},; 
 		{'cena','N',14,2}}) 
  
 	if select('test') == 0 
 		dbusearea(.t.,,'test') 
 	endif 
 	for i := 1 to 100 
 		test->(dbappend()) 
 		test->nazwa := "Item " + hb_ntos(i) 
 		test->ilosc := test->(recno()) 
 		test->cena := (test->ilosc * HB_Random(100)) 
 	next 
 	test->(dbgotop()) 
  
 define window tabsample at 0,0 width 400 height 300 title 'Add control test' main backcolor AQUA 
  
 	DEFINE TBROWSE Brw_1 AT 10, 10 OF o_dlu ALIAS "test" WIDTH 330 HEIGHT 120 
  
 	ADD COLUMN TO Brw_1 DATA {|| test->nazwa } ALIGN DT_LEFT, DT_CENTER, DT_CENTER ; 
 			TITLE 'Nazwa' SIZE 100 
 	ADD COLUMN TO Brw_1 DATA {|| test->ilosc } ALIGN DT_RIGHT, DT_CENTER,DT_CENTER TITLE 'Ilosc' SIZE 70 
 	ADD COLUMN TO Brw_1 DATA {|| test->cena } ALIGN DT_RIGHT, DT_CENTER, DT_CENTER TITLE 'Cena' SIZE 70 
  
 	Brw_1:SetColor( { 2 }, { { | | IIf( test->(OrdKeyNo()) % 2 == 0, RGB(255,255,255), RGB(200, 200, 200) ) }}) 
  
 	Brw_1:nHeightCell += 6 
 	Brw_1:nHeightFoot += 4 
 	Brw_1:nWheelLines := 1 
  
 	Brw_1:nHeightHead := 14 
  
 	END TBROWSE 
  
 	tabsample.Brw_1.Hide 
  
    define tab tab1 at 10,10 width 370 height 220 backcolor AQUA 
  
       define page 'Page1' 
  
          define button b1 
             row 30 
             col 10 
             caption 'Press here to add a control' 
             width 180 
             action addnewcontrols({'lbl1','text1'}) 
          end button    
  
       end page 
  
       define page 'Page2' 
        
          define button b2 
             row 30 
             col 10 
             caption 'Press here to add a control' 
             width 180 
             action addnewcontrol2('Brw_1') 
          end button    
  
       end page 
  
    end tab 
  
    on key escape action thiswindow.release() 
  
 end window 
  
 tabsample.center 
 tabsample.activate 
  
 Return nil 
  
  
 function addnewcontrols(actrl) 
 local c1, c2 
  
 c1 := actrl[1] 
 c2 := actrl[2] 
  
 if iscontroldefined(&c1,tabsample) 
    tabsample.&(c1).release 
 endif 
  
 define label &c1 
    parent tabsample 
    row 50 
    col 10 
    width 40 
    value 'label' 
    backcolor AQUA 
 end label 
  
 if iscontroldefined(&c2,tabsample) 
    tabsample.&(c2).release 
 endif 
  
 define textbox &c2 
    parent tabsample 
    row 50 
    col 50 
    width 100 
 end textbox 
  
 tabsample.tab1.addcontrol(c1,1,84,10) 
 tabsample.tab1.addcontrol(c2,1,80,50) 
  
 return nil 
  
  
 function addnewcontrol2(ctrl) 
  
 if iscontroldefined(&ctrl,tabsample) 
    tabsample.&(ctrl).Show 
 endif 
  
 tabsample.tab1.addcontrol(ctrl,2,80,10) 
  
 return nil