/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  * 
  * Static FreeImage usage 
  * (c) 2012 Vladimir Chumachenko <ChVolodymyr@yandex.ru> 
  * 
  * Revised by Grigory Filatov <gfilatov@inbox.ru> 
 */ 
  
 #include "FreeImage.ch" 
 #include "MiniGUI.ch" 
  
  
 // Области вывода изображений имеют фиксированные размеры 
  
 // Координаты области изображения из файла 
  
 #define FI_TOP               30 
 #define FI_LEFT              30 
 #define FI_BOTTOM           455 
 #define FI_RIGHT            380 
  
 #define FI_WIDTH            ( FI_RIGHT - FI_LEFT ) 
 #define FI_HEIGHT           ( FI_BOTTOM - FI_TOP ) 
  
 // Координаты области изображения из ресурса 
  
 #define RES_TOP             FI_TOP 
 #define RES_LEFT            ( FI_RIGHT + 50 ) 
 #define RES_BOTTOM          FI_BOTTOM 
 #define RES_RIGHT           780 
  
 #define RES_WIDTH           ( RES_RIGHT - RES_LEFT ) 
 #define RES_HEIGHT          ( RES_BOTTOM - RES_TOP ) 
  
 // Имена ресурсов (соответсвуют определениям Demo.rc), хотя можно определить 
 // свои и связывать их в процедуре загрузки. 
  
 #define PNG_BIRD            'BIRD' 
 #define PNG_SEA             'SEA' 
 #define JPG_TOWN            'TOWN' 
 #define JPG_WATERFALL       'WATERFALL' 
  
  
 // Имя файла, имя ресурса 
  
 Static cFileImg  
 Static cResImg 
  
  
 /****** 
 * 
 *       Вывод графики из файла и ресурса 
 * 
 */ 
  
 Procedure Main 
  
 FI_Initialise() 
  
 Set font to 'Tahoma', 9 
  
 Define window wMain                 ; 
        At 0, 0                      ; 
        Width 810                    ; 
        Height 525                   ; 
        Title 'FreeImage Demo'       ; 
        NoMaximize                   ; 
        NoSize                       ; 
        Icon 'MAINICON'              ; 
        Main                         ; 
        On Release FI_DeInitialise() ; 
        On Paint { || ShowFile(), ShowRes() } 
  
   Define main menu 
  
     Define Popup '&File' 
       MenuItem '&Open'       Action OpenImgFile() 
       Separator 
       MenuItem 'E&xit Alt+X' Action ReleaseAllWindows() 
     End Popup 
  
     // !!! Все пункты меню связаны с именем соответствующего ресурса 
  
     Define Popup '&Resourse' 
       MenuItem 'Bird      (png)' Action OpenImgRes( PNG_BIRD     , 'PNG' ) 
       MenuItem 'Sea       (png)' Action OpenImgRes( PNG_SEA      , 'PNG' ) 
       MenuItem 'Town      (jpg)' Action OpenImgRes( JPG_TOWN     , 'JPG' ) 
       MenuItem 'Waterfall (jpg)' Action OpenImgRes( JPG_WATERFALL, 'JPG' ) 
     End Popup 
  
   End menu 
  
   @ ( FI_TOP - 25 ), ( FI_LEFT - 25 ) Frame frmFile             ; 
                                       Caption 'File'            ; 
                                       Width ( FI_WIDTH   + 45 ) ; 
                                       Height ( FI_HEIGHT + 45 ) 
  
   @ ( RES_TOP - 25 ), ( RES_LEFT - 25 ) Frame frmResource          ; 
                                         Caption 'Resource'         ; 
                                         Width ( RES_WIDTH   + 45 ) ; 
                                         Height ( RES_HEIGHT + 45 ) 
  
 End window 
  
 On Key Alt+X of wMain Action ReleaseAllWindows() 
  
 Center window wMain 
 Activate window wMain 
  
 Return 
  
 ****** End of Main ****** 
  
  
 /****** 
 * 
 *       OpenImgFile() 
 * 
 *       Выбор файла для загрузки 
 * 
 */ 
  
 Static Procedure OpenImgFile 
 Local cFile := GetFile( { { 'Image files (*.bmp;*.jpg;*.jpeg;*.gif;*.png;*.psd;*.tif;*.ico)', ; 
                             '*.bmp;*.jpg;*.jpeg;*.gif;*.png;*.psd;*.tif;*.ico'                ; 
                           }                                                                   ; 
                         }, 'Select image', GetCurrentFolder(), .F., .T. ) 
  
 If !Empty( cFile ) 
    cFileImg := cFile 
    wMain.frmFile.Caption := cFileNoPath( cFile ) 
    ShowFile() 
 Endif 
  
 Return 
  
 ****** End of OpenImgFile ****** 
  
  
 /****** 
 * 
 *       ShowFile() 
 * 
 *       Вывод изображения из файла 
 * 
 */ 
  
 Static Procedure ShowFile 
 Static nHandleFileImg 
 Local nTop         := FI_TOP   , ; 
       nLeft        := FI_LEFT  , ; 
       nBottom      := FI_BOTTOM, ; 
       nRight       := FI_RIGHT , ; 
       cImage                   , ; 
       pps                      , ; 
       hDC                      , ; 
       nWidth                   , ; 
       nHeight                  , ; 
       cID                      , ; 
       aData                    , ; 
       nKoeff                   , ; 
       nHandleClone 
  
 If !( nHandleFileImg == nil ) 
    FI_Unload( nHandleFileImg ) 
    nHandleFileImg := nil 
 Endif 
  
 If IsNil( cFileImg ) 
    Return 
 Else 
    nHandleFileImg := FI_Load( FI_GetFileType( cFileImg ), cFileImg, 0 )  // Загрузка рисунка 
 Endif 
  
 InvalidateRect( Application.Handle, 1, FI_LEFT, FI_TOP, FI_RIGHT, FI_BOTTOM ) 
  
 nWidth  := FI_GetWidth( nHandleFileImg ) 
 nHeight := FI_GetHeight( nHandleFileImg ) 
  
 If ( ( nHeight > FI_HEIGHT ) .or. ( nWidth > FI_WIDTH )  ) 
  
    If ( ( nHeight - FI_HEIGHT ) > ( nWidth - FI_WIDTH ) ) 
       nKoeff := ( FI_HEIGHT / nHeight ) 
    Else 
       nKoeff := ( FI_WIDTH / nWidth ) 
    Endif 
     
    nHeight := Round( ( nHeight * nKoeff ), 0 ) 
    nWidth  := Round( ( nWidth  * nKoeff ), 0 ) 
     
    nHandleClone := FI_Clone( nHandleFileImg ) 
    FI_Unload( nHandleFileImg ) 
     
    nHandleFileImg := FI_Rescale( nHandleClone, nWidth, nHeight, FILTER_BICUBIC ) 
    FI_Unload( nHandleClone ) 
     
 Endif 
  
 If ( nWidth < FI_WIDTH ) 
    nLeft  += Int( ( FI_WIDTH - nWidth ) / 2 ) 
    nRight := ( nLeft + nWidth ) 
 Endif 
  
 If ( nHeight < FI_HEIGHT ) 
    nTop    += Int( ( FI_HEIGHT - nHeight ) / 2 ) 
    nBottom := ( nTop + nHeight ) 
 Endif 
  
 pps := DefinePaintStru() 
 hDC := BeginPaint( Application.Handle, pps ) 
  
 FI_WinDraw( nHandleFileImg, hDC, nTop, nLeft, nBottom, nRight ) 
  
 EndPaint( Application.Handle, pps ) 
  
 Return 
  
 ****** End of ShowFile ****** 
  
  
 /****** 
 * 
 *       OpenImgRes( cRes, cType ) 
 * 
 *       Загрузка рисунка из ресурса 
 * 
 */ 
  
 Static Procedure OpenImgRes( cRes, cType ) 
 Local cData := Win_LoadResource( cRes, cType ) 
  
 If !Empty( cData ) 
    cResImg := cData 
    wMain.frmResource.Caption := ( cRes + ' (' + cType + ')' ) 
    ShowRes() 
 Else 
    MsgExclamation( cRes + ' not found.', 'Error' ) 
 Endif 
  
 Return 
  
 ****** End of OpenImgRes ****** 
  
  
 /****** 
 * 
 *       ShowRes() 
 * 
 *       Вывод рисунка из переменной (ресурса, загруженного в память) 
 * 
 */ 
  
 Static Procedure ShowRes 
 Static nHandleResImg 
 Local nTop         := RES_TOP   , ; 
       nLeft        := RES_LEFT  , ; 
       nBottom      := RES_BOTTOM, ; 
       nRight       := RES_RIGHT , ; 
       cImage                    , ; 
       pps                       , ; 
       hDC                       , ; 
       nWidth                    , ; 
       nHeight                   , ; 
       cID                       , ; 
       aData                     , ; 
       nKoeff                    , ; 
       nHandleClone 
  
 If !( nHandleResImg == nil ) 
    FI_Unload( nHandleResImg ) 
    nHandleResImg := nil 
 Endif 
  
 If Empty( cResImg ) 
    Return 
 Else 
    nHandleResImg := FI_LoadFromMem( FI_GetFileTypeFromMem( cResImg, Len( cResImg ) ), cResImg, 0 ) 
 Endif 
  
 InvalidateRect( Application.Handle, 1, RES_LEFT, RES_TOP, RES_RIGHT, RES_BOTTOM ) 
  
 nWidth  := FI_GetWidth( nHandleResImg ) 
 nHeight := FI_GetHeight( nHandleResImg ) 
  
 If ( ( nHeight > RES_HEIGHT ) .or. ( nWidth > RES_WIDTH )  ) 
  
    If ( ( nHeight - RES_HEIGHT ) > ( nWidth - RES_WIDTH ) ) 
       nKoeff := ( RES_HEIGHT / nHeight ) 
    Else 
       nKoeff := ( RES_WIDTH / nWidth ) 
    Endif 
  
    nHeight := Round( ( nHeight * nKoeff ), 0 ) 
    nWidth  := Round( ( nWidth  * nKoeff ), 0 ) 
  
    nHandleClone := FI_Clone( nHandleResImg ) 
    FI_Unload( nHandleResImg ) 
  
    nHandleResImg := FI_Rescale( nHandleClone, nWidth, nHeight, FILTER_BICUBIC ) 
    FI_Unload( nHandleClone ) 
  
 Endif 
  
 If ( nWidth < FI_WIDTH ) 
    nLeft  += Int( ( FI_WIDTH - nWidth ) / 2 ) 
    nRight := ( nLeft + nWidth ) 
 Endif 
  
 If ( nHeight < FI_HEIGHT ) 
    nTop    += Int( ( FI_HEIGHT - nHeight ) / 2 ) 
    nBottom := ( nTop + nHeight ) 
 Endif 
  
 pps := DefinePaintStru() 
 hDC := BeginPaint( Application.Handle, pps ) 
  
 FI_WinDraw( nHandleResImg, hDC, nTop, nLeft, nBottom, nRight ) 
  
 EndPaint( Application.Handle, pps ) 
  
 Return 
  
 ****** End of ShowRes ****** 
  
  
 #pragma BEGINDUMP 
  
 #include <windows.h> 
 #include "hbapi.h" 
 #include "hbapiitm.h" 
  
 // Определение структуры для рисования 
  
 HB_FUNC_STATIC( DEFINEPAINTSTRU ) 
 { 
    PAINTSTRUCT *pps = (PAINTSTRUCT*) hb_xgrab( sizeof( PAINTSTRUCT ) ); 
    hb_retnl( (LONG) pps ); 
 } 
  
 #pragma ENDDUMP

 
 HB_FUNC( INITMDICHILDWINDOW ) 
 { 
    HWND hwndChild; 
    MDICREATESTRUCT mcs; 
    char rgch[ 150 ]; 
    static int cUntitled; 
    int Style = 0; 
  
    if( hb_parl(9) ) 
       rgch[ 0 ] = 0; 
    else 
    { 
       if( hb_parc(2) == NULL ) 
          wsprintf( rgch, "Untitled%d", cUntitled++ ); 
       else 
       { 
          strncpy( rgch, hb_parc(2), 149 ); 
          rgch[ 149 ] = 0; 
       } 
    } 
  
    if( !hb_parl(7) ) 
       Style = Style | WS_MINIMIZEBOX;   // ??? Эти константы не работаеют нужны WS_MINIMIZE 
  
    if( !hb_parl(8) ) 
       Style = Style | WS_MAXIMIZEBOX;   // ??? Эти константы не работаеют       WS_MAXIMIZE 
  
    if( hb_parl(10) ) 
       Style = Style | WS_VSCROLL; 
  
    if( hb_parl(11) ) 
       Style = Style | WS_HSCROLL; 
  
    // Create the MDI child window 
  
    mcs.szClass = "MdiChildWndClass";      // window class name 
    mcs.szTitle = rgch;                    // window title 
    mcs.hOwner = GetModuleHandle( NULL );  // owner 
    mcs.x = hb_parni( 3 );                 // x position 
    mcs.y = hb_parni( 4 );                 // y position 
    mcs.cx = hb_parni( 5 );                // width 
    mcs.cy = hb_parni( 6 );                // height 
    mcs.style = Style;                     // window style 
    mcs.lParam = 0;                        // lparam 
    hwndChild = ( HWND ) SendMessage( ( HWND ) hb_parnl(1), WM_MDICREATE, 0, ( LPARAM ) ( LPMDICREATESTRUCT ) &mcs ); 
  
    if( hwndChild != NULL ) 
       ShowWindow( hwndChild, SW_SHOW ); 
  
    hb_retnl( ( LONG ) hwndChild ); 
 }