#include "color.ch" 
  
 PROCEDURE QOutClr( cMessage, lNewLine ) 
 	LOCAL  cDefColor, cDefFGClr, cCurFGClr, cCurBKClr, cClrPair 
 	STATIC hColors := { ; 
 								"black"    => "N",  ; 
 								"blue"     => "B",  ; 
 								"green"    => "G",  ; 
 								"cyan"     => "BG", ; 
 								"red"      => "R",  ; 
 								"magenta"  => "RB", ; 
 								"brown"    => "GR", ; 
 								"white"    => "W",  ; 
 								"gray"     => "N+", ; 
 								"blue+"    => "B+", ; // b - Bright 
 								"green+"   => "G+", ; 
 								"cyan+"    => "BG+",; 
 								"red+"     => "R+", ; 
 								"magenta+" => "RB+",; 
 								"yellow"   => "GR+",; 
 								"white+"   => "W+"  ; 
 							} 
 	LOCAL cStr 
  
 	hb_default( @cMessage, "" ) 
 	hb_default( @lNewLine, .T. ) 
  
 	hb_HCaseMatch( hColors, .F. ) 
  
 	IF .NOT. Empty( cMessage ) 
 		// Save a colors scheme 
 		cDefColor := SetColor() 
 		cClrPair  := GetClrPair( cDefColor, CLR_STANDARD + 1 ) 
 		cDefFGClr := GetClrFore( cClrPair ) 
 		cCurBKClr := GetClrBack( cClrPair ) 
 		cCurFGClr := cDefFGClr 
  
 		FOR EACH cStr IN hb_ATokens( cMessage, '#' ) 
 			// If a string between #-Tags is equal to any predefined Color,  
 			// and is equal to the default Foreground Color: set current Foreground Color 
 			IF hb_HHasKey( hColors, cStr ) .AND. cCurFGClr == cDefFGClr 
 				cCurFGClr := hColors[ cStr ] 
 			ELSE 
 				SetColor( SetClrPair( cDefColor, CLR_STANDARD + 1, cCurFGClr + '/' + cCurBKClr ) ) 
 				QQOut( cStr ) 
 				// Reset current Foreground Color 
 				cCurFGClr := cDefFGClr 
 			ENDIF 
 		NEXT 
  
 		IF lNewLine 
 			? e"\n" 
 		ENDIF 
 		// Restore a colors scheme 
 		SetColor( cDefColor ) 
 	ENDIF 
 	 
 	RETURN 
 

 
 #ifndef ICS_CH_ 
 #define ICS_CH_ 
  
 #define ICS_PARAM	1 
 #define ICS_PROPS	2 
 #define ICS_VALS	3 
  
 #endif /* ICS_CH_ */ 
 

 
 // This code is based on J Decker original code posted at 
 // https://stackoverflow.com/questions/35003036/toolset-to-parse-icalendar-file-in-c 
 // disclaimer : no support 
 // code provided as a example of minimal things one can do. 
  
 // format for lines is... 
 // PARAMETER[;PARAM_PROPERTY..]:VALUE[,VALUE2..]\n 
  
 #ifndef __DBG_PARTS__ 
 #xtranslate hb_traceLog( [<x,...>] ) => 
 #endif 
  
 #define ICS_PARAMETER 1 
 #define ICS_PROPERTY  2 
 #define ICS_VALUE     3 
  
 FUNCTION IcsToArray2( cInput,  i ) 
  
    LOCAL nStart := 1 
    LOCAL nEnd := 1 
    LOCAL nState := ICS_PARAMETER 
    LOCAL char, cParameter, cProperty, cValue 
    LOCAL aIcs := {} 
    LOCAL aProps := {} 
    LOCAL aValues := {} 
    LOCAL lInQuote := .F. 
  
    hb_default( @cInput, "" ) 
  
    IF hb_eol() $ cInput 
       cInput := StrTran( cInput, hb_eol(), e"\n" ) 
    ENDIF 
  
    FOR EACH char IN cInput 
       SWITCH nState 
       CASE ICS_PARAMETER 
          IF char == ":" .OR. char == ";" 
             cParameter := SubStr( cInput, nStart, nEnd - nStart ) 
             hb_traceLog( "PARAMETER:%s", cParameter ) 
  
             IF char == ";" 
                nState := ICS_PROPERTY 
             ELSE 
                nState := ICS_VALUE 
             ENDIF 
             nStart := nEnd + 1 
          ENDIF 
          EXIT 
  
       CASE ICS_PROPERTY 
          IF char == '"' 
             IF ! lInQuote 
                lInQuote := .T. 
             ELSE 
                lInQuote := .F. 
                EXIT 
             ENDIF 
          ENDIF 
  
          IF lInQuote 
             EXIT 
          ENDIF 
  
          IF char == ";" .OR. char == ":" 
             cProperty := SubStr( cInput, nStart, nEnd - nStart ) 
             hb_traceLog( "PROPERTY:%s", cProperty ) 
  
             AAdd( aProps, cProperty ) 
  
             IF char == ":" 
                nState := ICS_VALUE 
             ENDIF 
             nStart := nEnd + 1 
             EXIT 
          ENDIF 
          EXIT 
  
       CASE ICS_VALUE 
          IF char == e"\n" .OR. char == "," 
             cValue := SubStr( cInput, nStart, nEnd - nStart ) 
             hb_traceLog( "VALUE:%s", cValue ) 
  
             AAdd( aValues, cValue ) 
  
             IF char == e"\n" 
                AAdd( aIcs, { cParameter, AClone( aProps ), AClone( aValues ) } ) 
                aProps  := {} 
                aValues := {} 
                nState := ICS_PARAMETER 
             ENDIF 
             nStart := nEnd + 1 
          ENDIF 
          EXIT 
       ENDSWITCH 
  
       nEnd++ 
    NEXT 
  
    IF nEnd != nStart 
       i := 1 
    ENDIF 
  
    RETURN aIcs 
 

 
 PROCEDURE Main( cFile ) 
  
    LOCAL cStr := hb_MemoRead( cFile ) 
    LOCAL aIcs, err := 0 
  
    aIcs := IcsToArray2( cStr, @err ) 
  
    IF err == 0 
       ? hb_ValToExp( aIcs ), hb_eol() 
       sp_Dump2( aIcs ) 
    ENDIF 
  
    RETURN 
  
 STATIC PROCEDURE sp_Dump2( aSource ) 
  
    LOCAL e1, e2 
  
    hb_default( @aSource, {} ) 
  
    IF ! Empty( aSource ) 
       FOR EACH e1 IN aSource 
          ?? e1[ ICS_PARAM ] 
          FOR EACH e2 IN e1[ ICS_PROPS ] 
             ?? ";" + e2 
          NEXT 
          FOR EACH e2 IN e1[ ICS_VALS ] 
             IF e2:__enumIsFirst() 
                ?? ":" + e2 
             ELSE 
                ?? "," + e2 
             ENDIF 
          NEXT 
          ?? hb_eol() 
       NEXT 
    ENDIF 
  
    RETURN