HB_FUNC ( MCISENDSTRING ) 
 { 
  
         DWORD nError; 
  
         nError = mciSendString( hb_parc( 1 ), 
                                 hb_parc( 2 ), 
                                 hb_parcsiz( 2 ), 
                                 (HWND) hb_parnl( 3 ) ); 
  
         hb_retni( nError ); 
  
 } 
 

/****************************************************************************** 
       Programa: TMp3 class 
         Version: 1.0 (c) Cristobal Molla [cemese@terra.es] 
  
       Revised by Grigory Filatov <gfilatov@inbox.ru> 
  
 ******************************************************************************/ 
  
 #include "hbclass.ch" 
 #include "directry.ch" 
  
 #define BUFFER                  200 
 #define CRLF                    hb_OsNewLine() 
 #define TRUE                    .T. 
 #define FALSE                   .F. 
 #define MCI_MODE_UNKNOW         0 
 #define MCI_MODE_NOTREADY       1 
 #define MCI_MODE_PAUSED         2 
 #define MCI_MODE_PLAYING        3 
 #define MCI_MODE_STOPPED        4 
  
  
  
 CLASS TMp3 
  
         DATA nId        INIT 0 
         DATA nStatus    INIT 0 
         DATA lOpened    INIT FALSE 
  
         METHOD ERROR( nError, cMetodo ) 
         METHOD New() 
         METHOD Open( cFile ) 
         METHOD Close() 
         METHOD Status() 
         METHOD Play() 
         METHOD Pause() 
         METHOD Stop() 
  
 ENDCLASS 
  
  
  
 METHOD ERROR( nError, cMetodo ) CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL cError            as character 
         LOCAL cTexto            as character 
  
         // Inicializacion de variables.---------------------------------------- 
         cError := Space( BUFFER ) 
  
         // Muestra el mensaje de error.---------------------------------------- 
         MCIGetErrorString( nError, @cError ) 
         IF Empty( cError ) 
                 cTexto := "Error desconocido al ejecutar el comando " 
                 cTexto += cMetodo + " del dispositivo MP3    " + CRLF 
                 cTexto += CRLF 
                 cTexto += "Cуdigo de Error: " 
                 cTexto += hb_ValtoStr( nError ) 
         ELSE 
                 cTexto := "Error al ejecutar el comando " 
                 cTexto += cMetodo + " del dispositivo MP3    " + CRLF 
                 cTexto += CRLF 
                 cTexto += "Cуdigo de Error: " 
                 cTexto += hb_ValtoStr( nError ) + CRLF 
                 cTexto += "Error: " +  cError + "    " + CRLF 
                 CTexto += "Llamado desde: " + ProcName( 2 ) 
         ENDIF 
         MsgInfo( cTexto, "Atenciуn" ) 
  
 RETURN NIL 
  
  
  
 METHOD New() CLASS TMp3 
  
         ::nId     := 0 
         ::nStatus := MCI_MODE_UNKNOW 
         ::lOpened := FALSE 
  
 RETURN self 
  
  
  
 METHOD Open( cFile ) CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL cFileName         as character 
         LOCAL nError            as numeric 
         LOCAL cComando          as character 
         LOCAL cReturn           as character 
  
         // Control de parametros.---------------------------------------------- 
         IF !File( cFile ) 
                 MsgInfo( "No existe el archivo " + cFile, "TMp3 Class" ) 
                 RETURN ::lOpened 
         ENDIF 
  
         // Inicializacion de variables.---------------------------------------- 
         cFileName := _GetShortPathName( cFile ) 
         cComando  := "OPEN " + cFileName + " TYPE MPEGVIDEO ALIAS MP3" 
         cReturn   := Space( BUFFER ) 
  
         // Abre el fichero especificado.--------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Open()" ) 
         ELSE 
                 ::nId     := MCIGetDeviceId( "MP3" ) 
                 ::nStatus := ::Status() 
                 ::lOpened := TRUE 
         ENDIF 
  
 RETURN ::lOpened 
  
  
  
 METHOD Close() CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL nError            as numeric 
         LOCAL cComando          as character 
         LOCAL cReturn           as character 
  
         // Inicializacion de variables.---------------------------------------- 
         cComando := "CLOSE MP3" 
         cReturn  := Space( BUFFER ) 
  
         // Obtiene el modo.---------------------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Close()" ) 
         ELSE 
                 ::lOpened := FALSE 
         ENDIF 
  
 RETURN ::lOpened 
  
  
  
 METHOD Status() CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL nError            AS NUMERIC 
         LOCAL cComando          AS CHARACTER 
         LOCAL cReturn           AS CHARACTER 
  
         // Inicializacion de variables.---------------------------------------- 
         cComando := "STATUS MP3 MODE " 
         cReturn  := Space( BUFFER ) 
  
         // Obtiene el modo.---------------------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Status()" ) 
         ELSE 
                 DO CASE 
                 CASE cReturn == "not ready" 
                         ::nStatus := MCI_MODE_NOTREADY 
                 CASE cReturn == "paused" 
                         ::nStatus := MCI_MODE_PAUSED 
                 CASE cReturn == "playing" 
                         ::nStatus := MCI_MODE_PLAYING 
                 CASE cReturn == "stopped" 
                         ::nStatus := MCI_MODE_STOPPED 
                 OTHERWISE 
                         ::nStatus := MCI_MODE_UNKNOW 
                 ENDCASE 
         ENDIF 
  
 RETURN cReturn 
  
  
  
 METHOD Play() CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL nError 
         LOCAL cComando 
         LOCAL cReturn 
  
         // Inicializacion de variables.---------------------------------------- 
         IF ::Status() == "paused" 
                  cComando := "RESUME MP3" 
         ELSE 
                  cComando := "PLAY MP3 FROM 0" 
         ENDIF 
         cReturn  := Space( BUFFER ) 
  
         // Obtiene el modo.---------------------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Play()" ) 
         ELSE 
         ENDIF 
  
 RETURN NIL 
  
  
  
 METHOD Pause() CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL nError 
         LOCAL cComando 
         LOCAL cReturn 
  
         // Inicializacion de variables.---------------------------------------- 
         cComando := "PAUSE MP3" 
         cReturn  := Space( BUFFER ) 
  
         // Obtiene el modo.---------------------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Pause()" ) 
         ELSE 
         ENDIF 
  
 RETURN NIL 
  
  
  
 METHOD Stop() CLASS TMp3 
  
         // Declaracion de variables.------------------------------------------- 
         LOCAL nError 
         LOCAL cComando 
         LOCAL cReturn 
  
         // Inicializacion de variables.---------------------------------------- 
         cComando := "STOP MP3" 
         cReturn  := Space( BUFFER ) 
  
         // Obtiene el modo.---------------------------------------------------- 
         nError := MCISendString( cComando, @cReturn, GetActiveWindow() ) 
         IF nError > 0 
                 ::ERROR( nError, "TMp3:Stop()" ) 
         ELSE 
         ENDIF 
  
 RETURN NIL 
  
  
 #pragma BEGINDUMP 
  
 // Ficheros de definiciones de C. 
 #include <windows.h> 
 #include <mmsystem.h> 
  
 // Ficheros de definiciones de Harbour. 
 #include "hbapi.h" 
  
 /****************************************************************************** 
  Procedimiento: MCISendString( cComando, cBuffer ) 
     Parametros: cComando        - Caracter. Comando a ejecutar. 
                 cBuffer         - Caracter. Buffer para almacenar la respuesta 
                                   del comando. 
       Devuelve: 
          Notas: 
    Prototipo C: MCIERROR mciSendString( 
                                         LPCTSTR lpszCommand, 
                                         LPTSTR lpszReturnString, 
                                         UINT cchReturn, 
                                         HANDLE hwndCallback 
                                       ); 
  
                 The mciSendString function sends a command string to an MCI 
                 device. The device that the command is sent to is specified 
                 in the command string. 
  
                 Parameters 
                 ---------- 
                 lpszCommand 
                 Address of a null-terminated string that specifies an MCI 
                 command string. For more information about the command strings, 
                 see Command Strings. 
  
                 lpszReturnString 
                 Address of a buffer that receives return information. If no 
                 return information is needed, this parameter can be NULL. 
  
                 cchReturn 
                 Size, in characters, of the return buffer specified by the 
                 lpszReturnString parameter. 
  
                 hwndCallback 
                 Handle of a callback window if the “notify” flag was 
                 specified in the command string. 
  
                 Return Values 
                 ------------- 
                 Returns zero if successful or an error otherwise. The low-order 
                 word of the returned doubleword value contains the error return 
                 value. If the error is device-specific, the high-order word of 
                 the return value is the driver identifier; otherwise, the 
                 high-order word is zero. For a list of possible error values, 
                 see Constants: MCIERR Return Values. To retrieve a text 
                 description of mciSendString return values, pass the return 
                 value to the mciGetErrorString function. 
 ******************************************************************************/ 
 HB_FUNC ( MCISENDSTRING ) 
 { 
  
         // Declaracion de variables.------------------------------------------- 
         DWORD nError; 
 	BYTE bBuffer[ 255 ]; 
  
         // Envio del comando.-------------------------------------------------- 
         nError = mciSendString( ( LPSTR) hb_parc( 1 ), ( LPTSTR ) bBuffer, 254, ( HWND ) hb_parnl( 3 ) ); 
  
 	hb_storc( bBuffer, 2 ); 
  
         // Control de error.--------------------------------------------------- 
         hb_retnl( nError ); 
  
 } 
  
  
  
 /****************************************************************************** 
  Procedimiento: MCIGetErrorString( nError, @cError ) 
     Parametros: nError          - Numerico. Numero del error devuelto por 
                                   mciSendCommand() o mciSendString(). 
                 cError          - Cadena de caracteres con el texto 
                                   descriptivo del error. Inicializada. Pasada 
                                   por referencia. 
       Devuelve: lError          - Logico. Verdadero si se encontro la 
                                   descripcion del error, falso en caso 
                                   contrario 
          Notas: Devuelve la descripcion de error al enviar un comando MCI. 
    Prototipo C: BOOL mciGetErrorString( 
                                         DWORD fdwError, 
                                         LPTSTR lpszErrorText, 
                                         UINT cchErrorText 
                                         ); 
  
                 The mciGetErrorString function retrieves a string that 
                 describes the specified MCI error code. 
  
                 Parameters 
                 ---------- 
                 fdwError 
                 Error code returned by the mciSendCommand or mciSendString 
                 function. 
  
                 lpszErrorText 
                 Address of a buffer that receives a null-terminated string 
                 describing the specified error. 
  
                 cchErrorText 
                 Length of the buffer, in characters, pointed to by the 
                 lpszErrorText parameter. 
  
                 Return Values 
                 ------------- 
                 Returns TRUE if successful or FALSE if the error code is not 
                 known. 
 ******************************************************************************/ 
 HB_FUNC ( MCIGETERRORSTRING ) 
 { 
  
 	BYTE bBuffer[ 255 ]; 
  
         // Devuelve la descripcion del error.---------------------------------- 
         hb_retl( mciGetErrorString( hb_parnl( 1 ), ( LPTSTR ) bBuffer, 254 ) ); 
  
 	hb_storc( bBuffer, 2 ); 
 } 
  
  
  
 /****************************************************************************** 
  Procedimiento: MCIGetDeviceID() 
     Parametros: cDispositivo    - Caracter. Nombre del dispositivo o del alias 
                                   abierto satisfactoriamente. 
       Devuelve: El identificador con el nombre del dispositivo o su 
                 alias o cero si no esta abierto. 
          Notas: Obtiene el identifiacdor de un dispositivo MCI. 
    Prototipo C: MCIDEVICEID mciGetDeviceID( 
                                             LPCTSTR lpszDevice 
                                           ); 
  
                 The mciGetDeviceID function retrieves the device identifier 
                 corresponding to the name of an open device. 
  
                 Parameters 
                 ---------- 
                 lpszDevice 
                 Address of a null-terminated string that specifies the device 
                 name or the alias name by which the device is known. 
  
                 Return Values 
                 ------------- 
                 Returns the device identifier assigned to the device when it 
                 was opened if successful. The identifier is used in the 
                 mciSendCommand function. If the device name is not known, if 
                 the device is not open, or if there was not enough memory to 
                 complete the operation, the return value is zero. 
 ******************************************************************************/ 
 HB_FUNC ( MCIGETDEVICEID ) 
 { 
  
         // Obtiene el ID del dispositivo o alias MCI. 
         hb_retni( mciGetDeviceID( hb_parc( 1 ) ) ); 
  
 } 
  
 #pragma ENDDUMP