FUNCTION UDF_AddRecID( nUserStru, cFieldName, xOrder, aFldVal, xMin ) 
 LOCAL nPos := FieldPos( cFieldName ), nLen, a, p 
 LOCAL xKey, lApp, lOver := .F., xOrd1, xOrd2, nDec 
  
  IF ! Empty( xOrder ) 
     IF Valtype(xOrder) == "A"  
        xOrd1 := xOrder[1] 
        xOrd2 := xOrder[2] 
     ELSE 
        xOrd1 := xOrder 
     ENDIF 
     OrdSetFocus( xOrd1 ) 
  ENDIF 
   
  IF leto_TableLock( nUserStru, 1 ) 
  
     dbGoBottom() 
     xKey := FieldGet( nPos ) 
     IF Empty(xKey) .and. ! Empty(xMin) 
        xKey := xMin 
        IF ValType( xKey ) == "C" 
           nLen := hb_FieldLen( nPos ) 
           If left(xKey, 1) == "0" .and. ! "." $ xKey 
              xKey := left(xKey+space(nLen), nLen) 
           Else 
              xKey := right(space(nLen)+xKey, nLen) 
           EndIf 
        ENDIF 
     ENDIF 
  
     IF ValType( xKey ) == "N" 
        xKey ++ 
        IF hb_FieldType(nPos) $ 'NF' 
           lOver := xKey > Val( Replicate( "9", hb_FieldLen( nPos ) ) ) 
        ELSEIF hb_FieldLen( nPos ) == 2 
           lOver := xKey > 0x7FFF 
        ELSEIF hb_FieldLen( nPos ) == 4 
           lOver := xKey > 0x7FFFFFFF 
        ENDIF 
     ELSEIF ValType( xKey ) == "C" 
        nLen := Len(xKey) 
        If "." $ xKey 
           nDec := nLen - RAt(".", xKey) 
           xKey := Str( Val(xKey) + 1, nLen, nDec ) 
        ElseIf left(xKey, 1) == "0" 
           xKey :=   StrZero( Val(xKey) + 1, nLen ) 
        Else 
           xKey :=       Str( Val(xKey) + 1, nLen ) 
        EndIf 
        lOver := ('*' $ xKey) 
     ENDIF 
  
     IF lOver 
        lApp := .F. 
     ELSE 
        lApp := ( UDF_AddRec( nUserStru, xOrd2 ) != Nil ) 
     ENDIF 
  
     IF lApp 
        If ! empty(aFldVal) 
           FOR EACH a IN aFldValue 
               IF ( p := FieldPos(a[1]) ) > 0 
                  IF ! ( p == nPos .or. hb_FieldType(p) $ "+=^" ) 
                     FieldPut(p, a[2]) 
                  ENDIF 
               ENDIF 
           NEXT 
        EndIf 
        FieldPut( nPos, xKey ) 
        dbCommit() 
     ENDIF 
     leto_TableUnLock( nUserStru, 1 ) 
  ELSE 
     lApp := .F. 
  ENDIF 
  
 RETURN if( lApp, leto_rec( nUserStru ), Nil ) 
     
 FUNCTION UDF_AddRec( nUserStru, xOrder ) 
 LOCAL lApp, lSetDel, xRet 
  
  IF xOrder != Nil 
     OrdSetFocus( xOrder ) 
  ENDIF 
  lSetDel := Set( _SET_DELETED, .f. ) 
  dbGoTop() 
  Set( _SET_DELETED, lSetDel ) 
  IF ! Eof() .and. Deleted() .and. Empty( OrdKeyVal() ) 
     IF( lApp := leto_RecLock( nUserStru ) ) 
        dbRecall() 
     ENDIF 
  ELSE 
     dbAppend() 
     IF ( lApp := ! NetErr() ) 
        leto_RecLock( nUserStru, RecNo() ) 
     ENDIF 
  ENDIF 
  IF lApp 
     xRet := leto_rec( nUserStru ) 
  ENDIF 
  
 RETURN xRet 
  
 на клиенте  
 DO WHILE ! EOF() 
      aRec := RecGet()      // {{cFieldName, xFieldValue}, ... } 
      cRec := Leto_Udf("UDF_AddRecID", 'IDREC', {'IDR', 'DEL'}, aRec) 
      If cRec = Nil 
         ? "error ...." 
      EndIf 
      SKIP 
 ENDDO