SET MSVC=2019 
  
 SET VCL=%~dp0 
  
 SET PATH=%VCL%bin;%PATH% 
  
 SET VCE=%VCL%bin\x86 
  
 SET VER=10.0.18362.0 
  
 SET PATH=%VCE%;%VCL%sdk\Redist\%VER%\ucrt\DLLs\x86;%VCL%sdk\bin\x86;%PATH% 
  
 SET INCLUDE=%VCL%include;%VCL%sdk\include\ucrt;%VCL%sdk\include\um 
 SET INCLUDE=%INCLUDE%;%VCL%sdk\include\shared 
 SET INCLUDE=%INCLUDE%;%VCL%atlmfc\include;%VCL%atlmfc\src\mfc;%VC\%atlmfc\src\mfc 
  
 SET LIB=%VCL%lib\x86;%VCL%sdk\lib\um\x86;%VCL%sdk\lib\ucrt\x86;%VCL%atlmfc\lib\x86; 
  
  
 SET SY=%VCL%SY32.EXE 
 SET FU=%VCL%FU32.EXE 
 SET DT=%VCL%DT32.EXE 
 

 
 @echo off 
 if exist \BK19\BIN\hb19.cmd Call \BK19\BIN\hb19.cmd %1 %2 %3 %4 %5 %6 %7 %8  
 

 
 @echo off 
 if     %1.==O. goto Obj 
 if not %1.==.  goto e 
  
 rem ------------------- Start compile, link 
 :Start 
 SET BK=\BK19 
  
 SET HB=%BK%\HB32 
 SET VC=%BK%\MSVC 
 SET BIN=%HB%\bin 
  
 set HB_BK=%BK% 
 set HB_HB=%HB_BK%\hb32 
 set HB_VC=%HB_BK%\MSVC 
  
 Call %HB_VC%\vcvar.cmd 
 Call %HB_HB%\hbvar.cmd 
  
 SET BIN=%BIN%;%VCE% 
  
 rem -------------------------- Keys for Harbour.exe, cl.exe 
 SET HL=-n -m -es0 -w0 -ql  
 SET CL=/nologo /EHsc /W3 /O2 /DWIN32 /DNDEBUG /D_WINDOWS /D_MBCS 
  
 rem -------------------------- No modification variable !!! 
 SET O=.\C 
 SET C=.\C 
 SET R=.\RES 
 SET W=.\WRK 
 SET OU=%C% 
 SET ERR=N 
  
 if NOT exist %W%\_hbSets.cmd ( 
    Echo **************************************** 
    Echo *** File not found  %W%\_hbSets.cmd ! 
    Echo **************************************** 
    pause 
    exit 
 ) 
  
 rem ---------------------- Set variable Enveroment ------------------ 
 Call %W%\_hbSets.cmd 
  
 if NOT exist %P%.prg ( 
    Echo *************************************** 
    Echo *** File not found  %P%.prg ! 
    Echo *************************************** 
    pause 
    exit 
 )  
  
 for %%i in ( %P% ) Do ( 
     SET PT=%%~pi 
     SET PP=%%~ni 
     SET EX=%%~xi 
 ) 
  
 if exist %W%\%PP%.EXE  Del  %W%\%PP%.EXE  > nul 
 if exist %C%\%PP%.obj  Del  %C%\%PP%.obj  > nul 
  
 rem ------------------ FileName out protokol 
 SET OCMD=_hb_.txt 
  
 echo %P% > %OCMD% 
 echo %P% 
 echo -------------------------- 
  
 SET OBJ=%BK%\OBJ 
  
 SET LIB=%BK%\lib\;%LIB% 
 SET INCLUDE=.\Include;%BK%\MiniGui\Include;%INCLUDE% 
 SET PATH=%BIN%;%PATH% 
  
 if not exist %C%\*.tmp goto Compile 
  
 rem --------------------------- Create obj for selected project 
 :ObjCreate 
 for %%d in ( %C%\*.tmp ) Do Call %0 O %%d 
  
 if %ERR%==Y goto err 
  
 rem --------------------------- Create Lib for selected project 
 :LibCreate 
 if not exist %C%\*.obj      goto Compile 
 if not exist %W%\o_%PP%.txt goto Compile 
  
 if exist %C%\%PP%.lib  Del  %C%\%PP%.lib    > nul 
 lib.exe  /OUT:%C%\%PP%.lib  @%W%\o_%PP%.txt > nul 
  
 rem --------------------------- Create Lib for all project 
 if %LNM%.==.             goto Compile 
 if not exist %W%\o_*.txt goto Compile 
  
 for %%i in ( %LNM% ) Do ( 
     SET LCT=%%~pi 
     SET LNM=%%~ni 
     SET LEX=%%~xi 
 ) 
  
 if %LCT%.==. goto LibName 
 if not exist %LCT% md %LCT% 
 :LibName 
 if %LCT%.==. SET LCT=%C% 
 if exist %LCT%\%LNM%.lib   Del %LCT%\%LNM%.lib                     > nul 
 for %%d in ( %W%\o_*.txt ) Do  lib.exe  /OUT:%LCT%\%LNM%.lib  @%%d > nul 
  
 rem --------------------------- Compile Harbour 
 :Compile 
 HARBOUR.EXE  %HL%  -i%INCLUDE% -o%C%\  %C%\%PP%.prg  2>> %OCMD% 
 if errorlevel 1 SET ERR=Y 
  
 if %ERR%==Y goto err 
  
 cl.exe  /TC  %C%\%PP%.c  %CL%  /Fp%O%\%PP%.pch /Fo%O%\ /Fd /c  >> %OCMD% 
  
 rem --------------------------- Resource and linker 
 if exist  %R%\%PP%.RC ( 
  
    echo %R%\%PP%.rc              >> %OCMD% 
  
    pushd %R% 
 rem   RC.EXE              %PP%.RC   >> ..\%OCMD% 
    %BK%\BIN\RC\RC.EXE   %PP%.RC  >> ..\%OCMD% 
    if errorlevel 1 SET ERR=Y 
    popd 
  
    LINK.EXE /RELEASE  @%W%\L_%PP%.TXT %R%\%PP%.RES >> %OCMD% 
    if errorlevel 1 SET ERR=Y 
 ) else ( 
    LINK.EXE /RELEASE  @%W%\L_%PP%.TXT  >> %OCMD% 
    if errorlevel 1 SET ERR=Y 
 ) 
  
 :err 
 if %ERR%==Y goto Notepad 
  
 rem --------------------------- Copy EXE to project 
 if not exist %OU% md %OU%                               > nul 
 if exist %W%\%PP%.EXE copy %W%\%PP%.EXE %OU%\%NEXE%.exe > nul 
 if exist %W%\%PP%.EXE del  %W%\%PP%.EXE                 > nul 
 goto e 
  
 rem ---------------------- Start Notepad for error view 
 :Notepad 
 %BK%\BIN\prj.exe  /r  .\%OCMD%  %NINI%  %NSEC%  * 
 rem Start %NPAD% .\%OCMD% 
 goto e 
  
 rem ---------------------- Compile obj for lib selected project 
 :Obj 
 if %2.==.  goto ObjEnd 
 SET ERO=N 
 for %%i in ( %2 ) Do SET PO=%%~ni 
 for %%i in ( %2 ) Do SET EO=%%~xi 
 if not %EO%==.tmp goto ObjEnd 
 if exist %C%\%PO%.obj del %C%\%PO%.obj > nul 
  
 HARBOUR.EXE  %HL%  -i%INCLUDE% -o%C%\  @%C%\%PO%.tmp       2>> %OCMD%  
 if errorlevel 1 SET ERO=Y 
 if %ERO%==Y goto ObjEnd 
 if exist %C%\%PO%.tmp del %C%\%PO%.tmp > nul 
 cl.exe /TC %C%\%PO%.c  %CL%  /Fp%C%\%PO%.pch /Fo%C%\ /Fd /c >> %OCMD%  
 if errorlevel 1 SET ERO=Y 
 if %ERO%==Y goto ObjEnd 
  
 :ObjEnd 
 if %ERO%==Y SET ERR=Y  
 goto e 
  
 :e