#include "hbwin+.ch" 
  
 PROCEDURE main( cDir ) 
  
    LOCAL cDirectory 
  
    if hb_dirExists( cDir ) 
       cDirectory := cDir 
    else 
       hb_fnameSplit( hb_dirBase(), @cDirectory ) 
    endif 
  
    if hb_dirExists( cDirectory ) 
       if hb_fileExists( cDirectory + "quit" ) 
          hb_FileDelete( cDirectory + "quit" ) 
       endif 
  
       ErrorLevel( WatchDirectory( cDirectory ) != 0, 1, 0 ) 
    else 
       ErrorLevel( -1 ) 
    endif 
  
    RETURN 
  
  
  
 FUNCTION WatchDirectory( cDir ) 
  
    LOCAL pChangeHandle 
    LOCAL nWaitStatus  
    LOCAL lRunAnyway := .t. 
  
    // watch file name changes ( file was CREATED, RENAMED or DELETED)  
    pChangeHandle := wapi_FindFirstChangeNotification( cDir, .F., FILE_NOTIFY_CHANGE_FILE_NAME ) 
  
    if INVALID_HANDLE_VALUE( pChangeHandle ) 
       ? "ERROR: FindFirstChangeNotification function failed." 
       return wapi_GetLastError()  
    endif  
  
    // Change notification is set. Now we can wait on notification handle. 
    do while lRunAnyway 
       ? "Waiting for notification..." 
       // If the function succeeds, the return value indicates 
       // the event that caused the function to return.  
       nWaitStatus = wapi_WaitForSingleObject( pChangeHandle, INFINITE )  
  
       switch nWaitStatus  
       case WAIT_OBJECT_0  
          // A file was CREATED, RENAMED or DELETED in the directory. 
          // _Refresh_ this directory and _restart_ the notification. 
          RefreshDirectory( cDir, @lRunAnyway )  
  
          if lRunAnyway 
             if ! wapi_FindNextChangeNotification( pChangeHandle ) 
                ? "ERROR: FindNextChangeNotification function failed." 
                return wapi_GetLastError()  
             endif 
          else 
             wapi_FindCloseChangeNotification( pChangeHandle ) 
          endif 
  
          exit 
  
       case WAIT_TIMEOUT 
          // A timeout occurred, this would happen if some value other  
          // than INFINITE is used in the Wait call and no changes occur. 
          // In a single-threaded environment you might not want an 
          // INFINITE wait. 
          ? "No changes in the timeout period." 
          exit 
  
       otherwise 
          ? "ERROR: Unhandled nWaitStatus." 
          return wapi_GetLastError()  
       endswitch 
    end while 
  
    RETURN 0 
  
 /*--- 
 */ 
 PROCEDURE RefreshDirectory( cDir,lRunAnyway ) 
    // This is where you might place code to refresh your 
    // directory listing, but not the subtree because it 
    // would not be necessary. 
    ? hb_strFormat( "Directory (%1$s) changed.", cDir ) 
  
    if hb_fileExists( cDir + "quit" ) 
       lRunAnyway := .f. 
    endif 
  
    RETURN

#include "hbwapi.h" 
  
 /* 
 HANDLE WINAPI  
    FindFirstChangeNotification( LPCTSTR lpPathName, BOOL bWatchSubtree, DWORD dwNotifyFilter ); 
 */ 
 HB_FUNC( WAPI_FINDFIRSTCHANGENOTIFICATION ) 
 { 
    if( HB_ISCHAR( 1 ) ) 
    { 
       HANDLE handle; 
       void   *hText; 
  
       handle = FindFirstChangeNotification( HB_PARSTRDEF( 1, &hText, NULL ),  
                                             hbwapi_par_BOOL( 2 ), hbwapi_par_DWORD( 3 ) ); 
       hb_strfree( hText ); 
  
       if ( INVALID_HANDLE_VALUE == handle ) 
       {  
          hbwapi_SetLastError( GetLastError() ); 
  
          hb_retptr( NULL ); 
       } 
       else 
       { 
          hbwapi_ret_raw_HANDLE( handle ); 
       } 
    } 
    else 
    { 
       hb_retptr( NULL ); 
    } 
 } 
  
 //BOOL FindNextChangeNotification(HANDLE hChangeHandle); 
 HB_FUNC( WAPI_FINDNEXTCHANGENOTIFICATION ) 
 { 
    HANDLE handle = hbwapi_par_raw_HANDLE( 1 ); 
  
    if( handle ) 
    { 
       hbwapi_ret_L( FindNextChangeNotification( handle ) ); 
    } 
    else 
    { 
       hb_retl( HB_FALSE ); 
    } 
 } 
  
 //BOOL WINAPI FindCloseChangeNotification( HANDLE hChangeHandle ); 
 HB_FUNC( WAPI_FINDCLOSECHANGENOTIFICATION ) 
 { 
    HANDLE handle = hbwapi_par_raw_HANDLE( 1 ); 
  
    if( handle ) 
    { 
       hbwapi_ret_L( FindCloseChangeNotification( handle ) ); 
    } 
    else 
    { 
       hb_retl( HB_FALSE ); 
    } 
 } 
  
 HB_FUNC( INVALID_HANDLE_VALUE ) 
 { 
    HANDLE handle = hbwapi_par_raw_HANDLE( 1 ); 
  
    if ( NULL != handle ) 
    { 
       hbwapi_ret_L( ( INVALID_HANDLE_VALUE == handle )  ); 
    } 
 }