/* 
  * MINIGUI - Harbour Win32 GUI library Demo 
  */ 
  
 #include "minigui.ch" 
 #include "i_winuser.ch" 
  
 FUNCTION MAIN 
  
    DEFINE WINDOW Form_1 ; 
          AT 0, 0 ; 
          WIDTH 640 HEIGHT 380 ; 
          TITLE 'Harbour MiniGUI Demo' ; 
          MAIN ; 
          FONT 'Arial' SIZE 10 ; 
          NOMAXIMIZE ; 
          NOMINIMIZE ; 
          NOSIZE 
  
       DEFINE STATUSBAR 
          STATUSITEM ' HMG Power Ready!' 
       END STATUSBAR 
  
       ON KEY ESCAPE ACTION ThisWindow.RELEASE 
  
       DEFINE LABEL Label_1 
          COL 10 
          ROW 30 
          WIDTH 100 
          HEIGHT 30 
          VALUE 'Label Test 1' 
          BORDER .T. 
          CLIENTEDGE .F. 
          CENTERALIGN .T. 
          VCENTERALIGN .T. 
       END LABEL 
  
       DEFINE LABEL Label_2 
          COL 120 
          ROW 30 
          WIDTH 100 
          HEIGHT 30 
          VALUE 'Label Test 2' 
          BORDER .F. 
          CLIENTEDGE .T. 
          CENTERALIGN .T. 
          VCENTERALIGN .T. 
       END LABEL 
  
       DEFINE BUTTON B 
          ROW 240 
          COL 10 
          CAPTION 'Remove Border' 
          ACTION ( ChangeStyle( GetControlHandle( 'Label_1', 'Form_1' ), , WS_BORDER ) ) 
       END BUTTON 
  
       DEFINE BUTTON B2 
          ROW 240 
          COL 120 
          WIDTH 140 
          CAPTION 'Remove ClientEdge' 
          ACTION ( ChangeStyle( GetControlHandle( 'Label_2', 'Form_1' ), , WS_EX_CLIENTEDGE, .T. ) ) 
       END BUTTON 
  
    END WINDOW 
  
    Form_1.Center() 
  
    Form_1.Activate() 
  
 RETURN NIL 
 

 
       @ y, x LABEL &cN VALUE "Info win" WIDTH nWBtn HEIGHT nHBtn ; 
             FONTCOLOR aBtnFClr[1] BACKCOLOR aBtnBClr[1]            ; 
             CENTERALIGN VCENTERALIGN BORDER CLIENTEDGE             ; 
             ON MOUSEHOVER {|| MouseFocus_Label(.T., This.Cargo) }  ; 
             ON MOUSELEAVE {|| MouseFocus_Label(.F., This.Cargo) }  ; 
             ON CLICK {| | _wPost(This.Cargo:nPost, This.Index ) }  ; 
             ON INIT  {|o| 
                        This.Cargo := oHmgData() 
                        o := This.Cargo 
                        o:oObj    := This.Object 
                        o:cObj    := o:oObj:Name  
                        o:nObj    := 1 
                        o:cAvi    := "Avi_1"  // на др. Label свои имена avi контролов 
                        o:lAction := .F. 
                        o:lHover  := .F. 
                        o:lBorder  := .T. 
                        o:lClientEdge := .T. 
                        Return Nil 
                        } 
 ... 
 в ON INIT окна сделать 
  FOR EACH oLbl IN ow:GetObj4Type( "LABEL" ) 
     Default oLbl:Cargo := oHmgData()  
     IF Empty(oLbl:Cargo:cAvi) ; LOOP  // label без avi пропускаем 
     ENDIF 
     oAvi := ow:GetObj( oLbl:Cargo:cAvi ) 
     Default oAvi:Cargo := oHmgData()  
     oAvi:Cargo:cFile := _HMG_aControlCaption[ oAvi:Index ]  // avi file тут  
     oAvi:Cargo:oLabel := oLbl       // запомнили в avi объект label 
     oLbl:Cargo:oAvi := oAvi         // запомнили в label объект avi 
     oLbl:Cargo:cAviFile := oAvi:Cargo:cFile  // если надо, продублировали на label имя avi file 
  NEXT  
 ... 
 

 
 /* 
  * DrawBoxGradient.prg 
  * 
  * Author: P.Chornyj <myorg63@mail.ru> 
 */ 
  
 ANNOUNCE RDDSYS 
  
 #include "minigui.ch" 
  
 #define NONE      0 
 #define BOX       2 
 #define PANEL     3 
  
 PROCEDURE Main () 
  
    LOCAL aColor := HMG_n2RGB( GetSysColor( 15 ) ) 
  
    SET FONT TO "Arial", 12 
  
    DEFINE WINDOW x ; 
          WIDTH 640 ; 
          HEIGHT 420 ; 
          TITLE "Draw Box and Panel Gradient Sample" ; 
          MAIN ; 
          NOMAXIMIZE NOSIZE ; 
          BACKCOLOR aColor 
  
       DRAW GRADIENT IN WINDOW x AT 20, 20 TO 200, 300 BORDER BOX 
  
       @ 95, 110 LABEL Label_1 VALUE "Gradient Box In" AUTOSIZE TRANSPARENT FONTCOLOR YELLOW 
  
       DRAW GRADIENT IN WINDOW x AT 20, 320 TO 200, 610 ; 
          VERTICAL BORDER PANEL 
  
       @ 95, 410 LABEL Label_2 VALUE "Gradient Panel" AUTOSIZE TRANSPARENT FONTCOLOR YELLOW 
  
       DRAW GRADIENT IN WINDOW x AT 250, 20 TO 278, 300 ; 
          VERTICAL BORDER BOX ; 
          BEGINCOLOR { 255, 255, 255 } ; 
          ENDCOLOR { 220, 220, 220 } 
  
       @ 255, 110 LABEL Label_3 VALUE "Gradient Box In" AUTOSIZE TRANSPARENT 
  
       DRAW GRADIENT IN WINDOW x AT 250, 320 TO 278, 610 ; 
          VERTICAL BORDER PANEL ; 
          BEGINCOLOR { 255, 255, 255 } ; 
          ENDCOLOR { 200, 200, 216 } 
  
       @ 255, 410 LABEL Label_4 VALUE "Gradient Panel" AUTOSIZE TRANSPARENT 
  
       DRAW GRADIENT IN WINDOW x AT 300, 20 TO 302, 316 ; 
          BORDER NONE ; 
          BEGINCOLOR { 250, 0, 0 } ; 
          ENDCOLOR { 130, 0, 0 } 
  
       DRAW GRADIENT IN WINDOW x AT 300, 316 TO 302, 610 ; 
          BORDER NONE ; 
          BEGINCOLOR { 130, 0, 0 } ; 
          ENDCOLOR { 250, 0, 0 } 
  
       @ 330, 240 BUTTON Button_1 ; 
          CAPTION "&Switch" ; 
          ACTION SwitchBoxPanel() ; 
          WIDTH 150 HEIGHT 26 
  
    END WINDOW 
  
    CENTER WINDOW x 
  
    ACTIVATE WINDOW x 
  
 RETURN 
  
 PROCEDURE SwitchBoxPanel() 
  
       ERASE WINDOW x 
  
       DRAW GRADIENT IN WINDOW x AT 20, 20 TO 200, 300 VERTICAL BORDER PANEL 
  
       x.Label_1.VALUE := "Gradient Panel" 
  
       DRAW GRADIENT IN WINDOW x AT 20, 320 TO 200, 610 ; 
          BORDER BOX 
  
       x.Label_2.VALUE := "Gradient Box In" 
  
       DRAW GRADIENT IN WINDOW x AT 250, 20 TO 278, 300 ; 
          VERTICAL BORDER PANEL ; 
          BEGINCOLOR { 255, 255, 255 } ; 
          ENDCOLOR { 200, 200, 216 } 
  
       x.Label_3.VALUE := "Gradient Panel" 
  
       DRAW GRADIENT IN WINDOW x AT 250, 320 TO 278, 610 ; 
          VERTICAL BORDER BOX ; 
          BEGINCOLOR { 255, 255, 255 } ; 
          ENDCOLOR { 220, 220, 220 } 
  
       x.Label_4.VALUE := "Gradient Box In" 
  
       DRAW GRADIENT IN WINDOW x AT 300, 20 TO 302, 316 ; 
          BORDER NONE ; 
          BEGINCOLOR { 250, 0, 0 } ; 
          ENDCOLOR { 130, 0, 0 } 
  
       DRAW GRADIENT IN WINDOW x AT 300, 316 TO 302, 610 ; 
          BORDER NONE ; 
          BEGINCOLOR { 130, 0, 0 } ; 
          ENDCOLOR { 250, 0, 0 } 
  
       InvalidateRect( x.HANDLE, 0 ) 
  
 RETURN