METHOD SeekRec( xVal, lSoftSeek , lFindLast, nRowPos )  CLASS TSBrowse 
    LOCAL cAlias, nRecOld, lRet := .F.  
    DEFAULT lSoftSeek := .T., lFindLast := .T., nRowPos := ::nRowPos 
  
    cAlias  := ::cAlias  
  	nRecOld := (cAlias)->( Recno() )  
    
  	IF (cAlias)->( dbSeek( xVal, lSoftSeek, lFindLast ) )  
  	   ::GoToRec((cAlias)->( RecNo() ), nRowPos )  
  	   lRet := .T.  
  	ELSE  
  	   (cAlias)->( dbGoto(nRecOld) )  
  	ENDIF 
    
 RETURN lRet  
  
 METHOD FindRec( Block, lNext, nRowPos )  CLASS TSBrowse 
    LOCAL i, n := 0 
    LOCAL cAlias, nRecOld 
    LOCAL lArr := HB_ISARRAY(Block) 
  	LOCAL lRet := .F.  
    DEFAULT lNext := .F., nRowPos := ::nRowPos 
  
    cAlias  := ::cAlias  
  	nRecOld := (cAlias)->( Recno() )  
  
    IF lNext 
       (cAlias)->( dbSkip(1) ) 
    ELSE 
       (cAlias)->( dbGotop() ) 
    ENDIF 
  
    DO WHILE (cAlias)->( !EOF() ) 
       n ++ 
       IF lArr 
          FOR i := 1 TO Len(Block) 
              lRet := !Empty(EVal( Block[ i ], Self, i )) 
              IF lRet 
                 EXIT 
              ENDIF 
          NEXT 
       ELSE 
          lRet := !Empty(EVal( Block, Self, 0 )) 
       ENDIF 
       IF lRet 
          EXIT 
       ENDIF 
       DO EVENTS 
       (cAlias)->( dbSkip(1) ) 
    ENDDO 
    
  	IF lRet 
  	   ::GoToRec(( cAlias)->( RecNo() ), nRowPos )  
  	ELSE  
  	   (cAlias)->( dbGoto(nRecOld) )  
  	ENDIF  
    
 RETURN lRet  
  
 METHOD ScopeRec( xScopeTop, xScopeBottom, lBottom )  CLASS TSBrowse 
    LOCAL cAlias := ::cAlias 
      
    (cAlias)->( ORDSCOPE(0, xScopeTop   ) )  
    (cAlias)->( ORDSCOPE(1, xScopeBottom) )  
  
    ::Reset(lBottom) 
  
 RETURN Nil 
 

 
 *-----------------------------------------------------------------------------* 
 #ifndef __XHARBOUR__ 
 FUNCTION _LogFile( lCrLf, ... ) 
 #else 
 FUNCTION _LogFile( ... ) 
 #endif 
 *-----------------------------------------------------------------------------* 
    LOCAL hFile, i, xVal, cTp 
    LOCAL aParams := hb_AParams() 
    LOCAL nParams := Len( aParams ) 
    LOCAL cFile := hb_defaultValue( _SetGetLogFile(), GetStartUpFolder() + "\_MsgLog.txt" ) 
 #ifdef __XHARBOUR__ 
    LOCAL lCrLf 
 #endif 
    IF !Empty( cFile ) 
       hFile := iif( File( cFile ), FOpen( cFile, FO_READWRITE ), FCreate( cFile, FC_NORMAL ) ) 
       IF hFile == F_ERROR 
          RETURN .F. 
       ENDIF 
       FSeek( hFile, 0, FS_END ) 
 #ifdef __XHARBOUR__ 
       IF nParams > 0 
          lCrLf := aParams[ 1 ] 
       ENDIF 
 #endif 
       IF ( lCrLf := hb_defaultValue( lCrLf, .T. ) ) 
          FWrite( hFile, CRLF, 2 ) 
       ENDIF 
  
       IF     nParams == 2 .and. HB_ISNIL(aParams[ 2 ]) .and. lCrLf 
       ELSEIF nParams >  1 
 //         IF lCrlf 
 //            FWrite( hFile, CRLF, 2 ) 
 //         ENDIF 
          FOR i := 2 TO nParams 
             xVal := aParams[ i ] 
             cTp  := ValType( xVal ) 
             IF     cTp == 'C' ; xVal := iif( Empty( xVal ), "'" + "'", Trim( xVal ) ) 
             ELSEIF cTp == 'N' ; xVal := hb_ntos( xVal ) 
             ELSEIF cTp == 'L' ; xVal := iif( xVal, ".T.", ".F." ) 
 #ifdef __XHARBOUR__ 
             ELSEIF cTp == 'D' ; xVal := DToC( xVal ) 
 #else 
             ELSEIF cTp == 'D' ; xVal := hb_DToC( xVal, 'DD.MM.YYYY' ) 
 #endif 
             ELSEIF cTp == 'A' ; xVal := "ARRAY["  + hb_ntos( Len( xVal ) ) + "]" 
             ELSEIF cTp == 'H' ; xVal :=  "HASH["  + hb_ntos( Len( xVal ) ) + "]" 
             ELSEIF cTp == 'B' ; xVal := "'" + "B" + "'" 
             ELSEIF cTp == 'T' ; xVal := hb_TSToStr( xVal, .T. ) 
             ELSEIF cTp == 'U' ; xVal := 'NIL' 
             ELSE              ; xVal := "'" + cTp + "'" 
             ENDIF 
             FWrite( hFile, xVal + Chr( 9 ) ) 
          NEXT 
 //      ELSE 
 //         FWrite( hFile, CRLF, 2 ) 
       ENDIF 
       FClose( hFile ) 
    ENDIF 
  
 RETURN .T. 
 

 
    DEFINE WINDOW test                                ; 
       AT 0,0 WIDTH nWwnd HEIGHT 720                  ; 
       MINWIDTH 600 MINHEIGHT 620                     ; 
       TITLE "(" + MsgAboutDim(5) + ") " + SHOW_TITLE ; 
       ICON  "1MAIN_ICO"                              ; 
       MAIN TOPMOST                                   ; 
       ON MAXIMIZE ( ResizeForm(oBrw, .T.) )          ; 
       ON SIZE     ( ResizeForm(oBrw, .F.) )          ; 
       BACKCOLOR { 93,114,148 }                       ; 
       ON INIT ( OnInitTest(oBrw,cParam), This.Topmost := .F., oBrw:SetFocus() ) 
 ... 
 * ================================================================================ 
 STATIC FUNCTION ResizeForm( oBrw, lMaximize ) 
    Local nW 
  
 // ? procname(), lMaximize, '_HMG_MouseState', _HMG_MouseState 
  
    ResizeTsb( oBrw, lMaximize ) 
  
    IF _HMG_MouseState == 0 
  
       // установим новую ширину PROGRESSBAR 
       nW := This.Button_Exit.Col + This.Button_Exit.Width + 20 
       This.PBar_1.Width := This.ClientWidth - nW - 20 
       This.PBar_1.SetFocus 
      
       oBrw:SetFocus() 
  
    ENDIF 
  
 RETURN NIL 
  
 * ================================================================================ 
 STATIC FUNCTION ResizeTsb( oBrw, lMaximize ) 
    Local nK, nN, nS, nW, nH, nCol, oCol, cBrw 
  
    STATIC oCargo 
  
    DEFAULT lMaximize := .F. 
  
 //? procname(), lMaximize, '_HMG_MouseState', _HMG_MouseState 
  
    If ISNIL(oCargo) 
       oCargo               := oKeyData() 
       oCargo:nHeightSuper  := oBrw:nHeightSuper  
       oCargo:nHeightHead   := oBrw:nHeightHead   
       oCargo:nHeightSpecHd := oBrw:nHeightSpecHd 
       oCargo:nHeightCell   := oBrw:nHeightCell   
       oCargo:nHeightFoot   := oBrw:nHeightFoot   
       oCargo:aKfc          := array(Len( oBrw:aColumns )) 
       AFill( oCargo:aKfc, 0 ) 
    EndIf 
  
    IF _HMG_MouseState > 0 .or. lMaximize 
       WITH OBJECT oBrw 
       nW := _GetClientRect( :hWnd )[3]  
       nN := nK := 0 
       For nCol := 1 To Len( :aColumns ) 
           oCol := :aColumns[ nCol ] 
           oCargo:aKfc[ nCol ] := 0 
           If nCol == 1 .and. :lSelector; LOOP 
           ElseIf ! oCol:lVisible       ; LOOP 
           ElseIf oCol:lBitMap          ; LOOP 
           EndIf 
           oCargo:aKfc[ nCol ] := oCol:nWidth / nW 
           If oCargo:aKfc[ nCol ] > nK 
              nN := nCol 
              nK := oCargo:aKfc[ nCol ] 
           Endif 
       Next 
       oCargo:nColMaxKfc := nN 
       END WITH 
    ENDIF 
  
    IF _HMG_MouseState == 0 
 //? 
 //? procname(), oCargo:nColMaxKfc, oCargo:aKfc, oBrw:lPainted 
 //AEval(oCargo:aKfc, {|k,i| _LogFile(.T., i, k) }) 
 //? 
       WITH OBJECT oBrw 
       // new size TsBrowse 
       cBrw      := :cControlName 
       :lEnabled := .F. 
       This.&(cBrw).Enabled := .F. 
       :Move( :nLeft, :nTop, This.ClientWidth, This.ClientHeight - :nTop, .T. ) 
       // new width columns 
       nW := _GetClientRect( :hWnd )[3]  
       nN := oCargo:nColMaxKfc 
       nS := 0  
       For nCol := 1 To Len(:aColumns) 
           oCol := :aColumns[ nCol ] 
           If Empty( oCargo:aKfc[ nCol ] ); LOOP 
           EndIf 
           oCol:nWidth := int( oCargo:aKfc[ nCol ] * nW ) 
           nS          += oCol:nWidth 
       Next 
       :aColumns[ nN ]:nWidth += ( nW - nS ) 
       // new rows table 
  
       :nHeightSuper  := oCargo:nHeightSuper  
       :nHeightHead   := oCargo:nHeightHead   
       :nHeightSpecHd := oCargo:nHeightSpecHd 
       :nHeightCell   := oCargo:nHeightCell   
       :nHeightFoot   := oCargo:nHeightFoot   
  
       nH := _GetClientRect( :hWnd )[4]  
       nS := nH - :nHeightHead - :nHeightSuper  - ; 
                  :nHeightFoot - :nHeightSpecHd - ; 
             iif( :lNoHScroll, 0, GetHScrollBarHeight() ) 
  
       nS -= ( Int( nS / :nHeightCell ) * :nHeightCell ) 
       nN := If( :nHeightSuper  > 0, 1, 0 ) + ; 
             If( :nHeightHead   > 0, 1, 0 ) + ; 
             If( :nHeightSpecHd > 0, 1, 0 ) + ; 
             If( :nHeightFoot   > 0, 1, 0 ) 
  
       If nN > 0 
          nK := int( nS / nN ) 
          If :nHeightFoot   > 0 
             :nHeightFoot   += nK 
             nS             -= nK 
          EndIf 
          If :nHeightSuper  > 0 
             :nHeightSuper  += nK 
             nS             -= nK 
          EndIf 
          If :nHeightSpecHd > 0 
             :nHeightSpecHd += nK 
             nS             -= nK 
          EndIf 
          If :nHeightHead   > 0 
             :nHeightHead   += nS 
          EndIf 
       EndIf       
       :lEnabled := .T. 
       This.&(cBrw).Enabled := .T. 
       :Paint() 
 //      :Refresh(.T.) 
       END WITH 
    ENDIF 
    
 RETURN NIL 
 ... 
 

 
 CLASS TSBrowse FROM TControl 
 ... 
    DATA   aOldParams   
 ... 
 METHOD SetNoHoles( nDelta, lSet ) CLASS TSBrowse 
  
    LOCAL nH, nK, nHeight, nHole, nCol, oCol, aRect 
     
    DEFAULT nDelta := 0, lSet := .T. 
  
    If ISARRAY( ::aOldParams ) .and. Len( ::aOldParams ) > 4 
       ::nHeightSuper  := ::aOldParams[1] 
       ::nHeightHead   := ::aOldParams[2] 
       ::nHeightSpecHd := ::aOldParams[3] 
       ::nHeightCell   := ::aOldParams[4] 
       ::nHeightFoot   := ::aOldParams[5] 
    EndIf 
     
    nHole := _GetClientRect( ::hWnd )[4]      - ; 
              ::nHeightHead - ::nHeightSuper  - ; 
              ::nHeightFoot - ::nHeightSpecHd - ; 
          If( ::lNoHScroll, 0, GetHScrollBarHeight() ) 
    
    nHole   -= ( Int( nHole / ::nHeightCell ) * ::nHeightCell ) 
    nHole   -= nDelta 
    nHeight := nHole 
  
    If lSet 
  
       nH := If( ::nHeightSuper  > 0, 1, 0 ) + ; 
             If( ::nHeightHead   > 0, 1, 0 ) + ; 
             If( ::nHeightSpecHd > 0, 1, 0 ) + ; 
             If( ::nHeightFoot   > 0, 1, 0 ) 
  
       If nH > 0 
  
          nK := int( nHole / nH ) 
  
          If ::nHeightFoot   > 0 
             ::nHeightFoot   += nK 
             nHole           -= nK 
          EndIf 
          If ::nHeightSuper  > 0 
             ::nHeightSuper  += nK 
             nHole           -= nK 
          EndIf 
          If ::nHeightSpecHd > 0 
             ::nHeightSpecHd += nK 
             nHole           -= nK 
          EndIf 
          If ::nHeightHead   > 0 
             ::nHeightHead   += nHole 
          EndIf 
  
       Else 
  
          SetProperty( ::cParentWnd, ::cControlName, "Height", ; 
          GetProperty( ::cParentWnd, ::cControlName, "Height" ) - nHole ) 
  
       EndIf 
     
       If Empty( ::aOldParams ) 
  
          ::Display() 
  
          aRect           := _GetClientRect( ::hWnd ) 
          ::aOldParams    := array(7) 
          ::aOldParams[1] := ::nHeightSuper  
          ::aOldParams[2] := ::nHeightHead   
          ::aOldParams[3] := ::nHeightSpecHd 
          ::aOldParams[4] := ::nHeightCell   
          ::aOldParams[5] := ::nHeightFoot   
          ::aOldParams[6] := { aRect[3], aRect[4] }     // client { width, height } 
          ::aOldParams[7] := array(Len( ::aColumns )) 
  
          For nCol := 1 To Len( ::aColumns ) 
              ::aOldParams[7][ nCol ] := 0 
              oCol := ::aColumns[ nCol ] 
              If nCol == 1 .and. ::lSelector; LOOP 
              ElseIf oCol:lBitMap           ; LOOP 
              EndIf 
              If ! Empty(::aOldParams[6][1]) 
                 ::aOldParams[7][ nCol ] := oCol:nWidth / ::aOldParams[6][1] 
              EndIf 
          Next 
  
       Else 
  
          If ::lEnabled 
             ::lEnabled := .F. 
          EndIf 
  
          ::Paint() 
          ::lEnabled := .T. 
          ::Refresh(.F.) 
  
       EndIf 
  
    EndIf 
  
 RETURN nHeight  
 

 
 METHOD OnReSize( nWidth, nHeight, lTop ) CLASS TSBrowse 
  
    LOCAL nCnt, aCol, nCol, oCol, nKfc, lRet := .F. 
    LOCAL nColMaxKfc := 0, nW, nS, nN 
    LOCAL nTop := iif( empty( lTop ), ::nTop, 0 ) 
  
    IF _HMG_MouseState == 0 .and. ISARRAY( ::aOldParams[7] ) 
  
       aCol := ::aOldParams[7] 
       nCnt := Min( Len(aCol), Len( ::aColumns ) ) 
       nKfc := 0 
       lRet := .T. 
  
       For nCol := 1 To nCnt 
           oCol := ::aColumns[ nCol ] 
           If nCol == 1 .and. ::lSelector; LOOP 
           ElseIf ! oCol:lVisible        ; LOOP 
           ElseIf oCol:lBitMap           ; LOOP 
           EndIf 
           If aCol[ nCol ] > nKfc 
              nColMaxKfc := nCol 
              nKfc := aCol[ nCol ] 
           Endif 
       Next 
  
       ::lEnabled := .F. 
       ::Move( ::nLeft, ::nTop, nWidth, nHeight - nTop, .T. ) 
  
       nW := _GetClientRect( ::hWnd )[3]  
       nN := nS := 0 
  
       For nCol := 1 To nCnt 
           oCol := ::aColumns[ nCol ] 
           If nCol == 1 .and. ::lSelector; LOOP 
           ElseIf ! oCol:lVisible        ; LOOP 
           ElseIf oCol:lBitMap           ; LOOP 
           EndIf 
           nKfc        := aCol[ nCol ] 
           oCol:nWidth := int( nKfc * nW ) 
           nS          += oCol:nWidth 
           nN          := nCol 
       Next 
  
       nN := iif( nColMaxKfc > 0, nColMaxKfc, nN ) 
       ::aColumns[ nN ]:nWidth += ( nW - nS ) 
       ::lEnabled := .T. 
       ::SetNoHoles() 
  
    ENDIF 
  
 Return lRet 
  
 Применение 
 ... 
    DEFINE WINDOW test                                ; 
 ... 
       ON MAXIMIZE   ResizeForm(oBrw)                 ; 
       ON SIZE       ResizeForm(oBrw)                 ; 
 ... 
         DEFINE TBROWSE oBrw AT 46+10, 0            ; 
 ... 
         END TBROWSE 
  
        oBrw:SetNoHoles()   // убрать дырку внизу таблицы  
 ... 
    END WINDOW 
 ... 
 STATIC FUNCTION ResizeForm( oBrw ) 
    Local nW 
  
    oBrw:OnResize( This.ClientWidth, This.ClientHeight )  // сработает 1 раз при _HMG_MouseState == 0 (внутри анализ) 
  
    IF _HMG_MouseState == 0 
  
       // установим новую ширину PROGRESSBAR 
       nW := This.Button_Exit.Col + This.Button_Exit.Width + 20 
       This.PBar_1.Width := This.ClientWidth - nW - 20 
       This.PBar_1.SetFocus 
      
       oBrw:SetFocus() 
  
    ENDIF 
  
 RETURN NIL 
 

 
 ... 
    DEFINE WINDOW Form_0 ; 
       WIDTH 700 ; 
       HEIGHT 600 ; 
       TITLE "(4) TsBrowse DBASE SHARED Demo" ; 
       MAIN   ; //    NOMAXIMIZE NOSIZE ; 
       ON INIT     oBr:SetFocus() ;       
       ON RELEASE  dbCloseArea( aAlias[1] ) ; 
       ON MAXIMIZE ResizeForm( oBr ) ; 
       ON SIZE     ResizeForm( oBr ) 
 ... 
    Form_0.Activate 
  
 RETURN 
  
 FUNC ResizeForm( oBrw ) 
    LOCAL nW := This.ClientWidth 
    LOCAL nH := This.ClientHeight - This.StatusBar.Height 
     
    oBrw:OnResize( nW - 10, nH - 5 ) 
  
 RETURN Nil 
  
 ... 
 FUNCTION CreateBrowse() 
 ... 
    oBrw:nWheelLines  := 1 
    oBrw:nClrLine     := COLOR_GRID          // цвет линий между ячейками таблицы 
    oBrw:lNoChangeOrd := TRUE                // убрать сортировку по полю 
    oBrw:nColOrder    := 0                   // убрать значок сортировки по полю 
    oBrw:lCellBrw     := TRUE 
 //   oBrw:lNoVScroll   := TRUE                // отключить показ горизонтального скролинга 
    oBrw:lNoHScroll   := TRUE                // отключить показ горизонтального скролинга 
    oBrw:hBrush       := CreateSolidBrush( 242, 245, 204 )   // цвет фона под таблицей 
 ... 
 STATIC FUNCTION RecInsert(oBrw) 
 ... 
             oBrw:GotoRec(nRecno, nRow + nPos) 
              
             If ! oBrw:lNoVScroll .and. oBrw:nLen > oBrw:nRowCount() 
                oBrw:ResetVScroll( .T. ) 
                oBrw:oHScroll:SetRange( 0, 0 ) 
             EndIf 
  
             oBrw:nCell := 2                          // передвинуть МАРКЕР на 2 колонку 
 ... 
 

#include "minigui.ch" 
  
 Function Main 
  
 	DEFINE WINDOW Form_1 ; 
 		AT 0,0 ; 
 		WIDTH 640 HEIGHT 480 ; 
 		TITLE 'MiniGUI ToolBar Demo' ; 
 		ICON 'DEMO.ICO' ; 
 		MAIN ; 
 		FONT 'Arial' SIZE 10  
  
 		DEFINE STATUSBAR 
 			STATUSITEM 'HMG Power Ready!'  
 		END STATUSBAR 
  
 		DEFINE MAIN MENU  
 			POPUP '&File' 
 				ITEM 'Get ToolBar_C Button_1'	    ACTION MsgInfo ( if ( Form_1.ToolBar_c.Button_1c.Value , '.T.' , '.F.' ) , 'Button_1c' ) 
 				ITEM 'Get ToolBar_C Button_2'	    ACTION MsgInfo ( if ( Form_1.ToolBar_c.Button_2c.Value , '.T.' , '.F.' ) , 'Button_2c' ) 
 				ITEM 'Get ToolBar_C Button_3'	    ACTION MsgInfo ( if ( Form_1.ToolBar_c.Button_3c.Value , '.T.' , '.F.' ) , 'Button_3c' ) 
 	    			SEPARATOR	 
 				ITEM 'Set ToolBar_C Button_1'	    ACTION Form_1.ToolBar_c.Button_1c.Value := .T.  
 				ITEM 'Set ToolBar_C Button_2'	    ACTION Form_1.ToolBar_c.Button_2c.Value := .T.  
 				ITEM 'Set ToolBar_C Button_3'	    ACTION Form_1.ToolBar_c.Button_3c.Value := .T.  
 			    	SEPARATOR	 
 				ITEM '&Exit'			ACTION Form_1.Release 
 			END POPUP 
 			POPUP '&Help' 
 				ITEM '&About'		ACTION MsgInfo ("MiniGUI ToolBar demo")  
 			END POPUP 
 		END MENU 
  
 		DEFINE SPLITBOX  
  
 			DEFINE TOOLBAR ToolBar_a BUTTONSIZE 45,40 FONT 'Arial' SIZE 8  FLAT 
  
 				BUTTON Button_1a ; 
 					CAPTION '&Undo' ; 
 					PICTURE 'button4.bmp' ; 
 					ACTION MsgInfo('Click! 1') 
  
 				BUTTON Button_2a ; 
 					CAPTION '&Save' ; 
 					PICTURE 'button5.bmp' ; 
 					WHOLEDROPDOWN  
  
 					DEFINE DROPDOWN MENU BUTTON Button_2a  
 						ITEM 'Exit'	ACTION Form_1.Release 
 						ITEM 'About'	ACTION MsgInfo ("MiniGUI ToolBar Demo")  
 					END MENU 
  
 				BUTTON Button_3a ; 
 					CAPTION '&Close' ; 
 					PICTURE 'button6.bmp' ; 
 					ACTION MsgInfo('Click! 3') ; 
 					DROPDOWN 
  
 					DEFINE DROPDOWN MENU BUTTON Button_3a  
 						ITEM 'Disable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .F. 
 						ITEM 'Enable ToolBar 1 Button 1'	ACTION Form_1.Button_1a.Enabled := .T. 
 					END MENU 
  
 			END TOOLBAR 
 /* 
 			DEFINE TOOLBAR ToolBar_b BUTTONSIZE 45,40 FONT 'ARIAL' SIZE 8 FLAT  
  
 				BUTTON Button_1b ; 
 					CAPTION 'More ToolBars...' ; 
 					PICTURE 'button7.bmp' ; 
 					ACTION MsgInfo('Click! 1');  
  
 				BUTTON Button_2b ; 
 					CAPTION 'Button 2' ; 
 					PICTURE 'button8.bmp' ; 
 					ACTION MsgInfo('Click! 2');  
 					SEPARATOR 
  
 				BUTTON Button_3b ; 
 					CAPTION 'Button 3' ; 
 					PICTURE 'button7.bmp' ; 
 					ACTION MsgInfo('Click! 3') 
  
 			END TOOLBAR 
  
 			DEFINE TOOLBAR ToolBar_c BUTTONSIZE 45,40 FONT 'Arial' SIZE 8 CAPTION 'ToolBar 3' FLAT 
  
 				BUTTON Button_1c ; 
 					CAPTION 'Check 1' ; 
 					PICTURE 'button4.bmp' ; 
 					ACTION MsgInfo('Hey!'); 
 					CHECK GROUP 
  
 				BUTTON Button_2c ; 
 					CAPTION 'Check 2' ; 
 					PICTURE 'button5.bmp' ; 
 					ACTION MsgInfo('Hey!') ;  
 					CHECK GROUP 
  
 				BUTTON Button_3c ; 
 					CAPTION 'Check 3' ; 
 					PICTURE 'button6.bmp' ; 
 					ACTION MsgInfo('Hey!') ; 
 					SEPARATOR; 
 					CHECK GROUP 
  
 				BUTTON Button_4c ; 
 					CAPTION 'Help Check' ; 
 					PICTURE 'button9.bmp' ; 
 					ACTION MsgInfo('Hey!') ; 
 					CHECK  
  
 			END TOOLBAR 
 */ 
 		END SPLITBOX 
  
 	END WINDOW 
  
 	CENTER WINDOW Form_1 
  
 	ACTIVATE WINDOW Form_1 
  
 Return Nil 
 

  * Fixed: Problem with AUTOSIZE property handling in the CHECKLABEL control. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo in folder \samples\Basic\CheckLabel_3) 
   * Enhanced: Added 'VCENTERALIGN' clause (optional) for vertical aligning of 
            a text in CHECKLABEL control. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo in folder \samples\Basic\CheckLabel_2) 
   * Modified: A Switcher control was used for managing of the logical variables 
            in the function InputWindow(). 
            Note: an obsolete behaviour may be restored via adding the 
            definition of the constant HMG_LEGACY_ON to the header file 
            minigui.ch. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo at folder \samples\Basic\MAINDEMO_(SYNTAX_I)) 
   * Enhanced: Added an auxiliary conversion function 
            HMG_ClrToHTML( nClr ) --> cHtmlClr ( format "#rrggbb" ) 
            Example: 
              ? HMG_ClrToHTML( CLR_BLUE ) --> #000080 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see Tsb2xml.prg in folder \samples\Advanced\Tsb_Brw2xml) 
   * Updated: Adaptation FiveWin Class TSBrowse 9.0 in HMG: 
            - fixed the processing of the variable :lNoMoveCols in the method 
              RButtonDown(). The bug was reported by Sylvain Larche. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
   * Updated: HbSQLite3 library: 
            - update for using SQLITE3 version 3.27.0dev (from 3.26.0). 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
   * Updated: Harbour Compiler 3.2.0dev (SVN 2018-12-31 15:32): 
            * Updated: OpenSSL wrapper for using of the version 1.0.2q. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (look at ReadMe.txt in folder \harbour) 
   * Updated: HMGS-IDE v.1.4.3.5 Project Manager and Two-Way Visual Form Designer. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (look for what's new at changelog.txt in folder \Ide) 
   * New: 'Switcher control for logical variables' sample. 
            Syntax: 
              @ <row>,<col> SWITCHER <name> [ OF <parent> ] ; 
                HEIGHT 46 ; 
                IMAGE { 'MINIGUI_SWITCH_ON', 'MINIGUI_SWITCH_OFF' } ; 
                [ VALUE <cValue> ] ; 
                [ FONT <fontname> SIZE <fontsize> ] ; 
                [ LEFTCHECK ] [ CHECKED ] ; 
                [ ON MOUSEHOVER <bMouseHover> ] ; 
                [ ON MOUSELEAVE <bMouseLeave> ] ; 
                [ ON CLICK <bMouseClick> ] 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see in folder \samples\Basic\CheckLabel_3) 
   * New: 'Media Player Test' sample. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo2.prg in folder \samples\Basic\PLAYER_1) 
   * Updated: 'Print Pie Graph' sample: the updated data for December 2018. 
            Windows 10 is the leader for the first time since July 2015. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see demo.prg in folder \samples\Basic\GraphPrint) 
   * Updated: 'RichEdit Extended' samples: 
            - a correction in the function _SetFontSizeRTF(). 
            Contributed by Pierpaolo Martinello <pier.martinello[at]alice.it> 
            (see in folders \samples\Advanced\RicheditEx and 
            \samples\Advanced\RicheditEx_2) 
   * Updated: 'MiniGUI DataBase Utility' sample: 
            - fixed a command line processing. 
            Contributed by Grigory Filatov <gfilatov@inbox.ru> 
            (see in folder \Utils\mgDBU) 
   * Updated: MPM utility: 
            - added permit of execution of a batch file with an admin privilege 
            request. Based upon a contribution of Pierpaolo Martinello 
            (see in folder \Utils\MPM) 
 

 
 * ----------------------------------------------------------------------------------- * 
 STATIC FUNC InitCols()                           // Создание колонок tsb 
 * ----------------------------------------------------------------------------------- * 
    LOCAL cR08    := 'R08' 
    LOCAL cR09    := 'R09' 
    LOCAL cPicKol := '99999999' 
    LOCAL cPicCen := '9999999.99' 
    LOCAL cPicSum := '9999999.99' 
  
    Stru2Cols(R08_Stru(), cR08) 
    // 
    sCols( R08.B_2 , cHeading, 'Sheet'             ) 
    sCols( R08.B_2 , bDecode , {|cv| alltrim(cv) } ) 
                    
    sCols( R08.D_E , cHeading, 'Excel' + CRLF + 'line' )                    // для документа 
    sCols( R08.D_E , nAlign  , DT_CENTER ) 
    sCols( R08.D_E , nWidth  , TxtWidth(5) ) 
    sCols( R08.D_E , bDecode , {|nv| hb_ntos(nv) } ) 
                    
    sCols( R08.D_2 , cHeading, gTxt(Pavadz) + CRLF + 'Sheet' + CRLF + 'File name'  ) 
    sCols( R08.D_2 , nAlign  , DT_CENTER ) 
    sCols( R08.D_2 , nWidth  , TxtWidth(25) ) 
    sCols( R08.D_2 , bData   , {|| alltrim(D_2) + chr(13) + chr(10) + ; 
                                   alltrim(B_2) + chr(13) + chr(10) + ; 
                                   alltrim(B_0) } ) 
  
    sCols( R08.K_E1, cHeading, 'Excel' + CRLF + 'line' )                    // для клиента 
    sCols( R08.K_E1, nAlign  , DT_CENTER ) 
    sCols( R08.K_E1, nWidth  , TxtWidth(5) ) 
    sCols( R08.K_E1, bData   , {|| hb_ntos(K_E1) + chr(13) + chr(10) + ;    // наименование 
                                   hb_ntos(K_E2) + chr(13) + chr(10) + ;    // рег. nr      
                                   hb_ntos(K_E3) } )                        // pvn. nr         
  
    sCols( R08.K_2 , cHeading, gTxt(Nosut)  + CRLF + gTxt(RegNr)   + CRLF + gTxt(PvnNr)   ) 
    sCols( R08.K_2 , nWidth  , TxtWidth(30) ) 
    sCols( R08.K_2 , bData   , {|| Alltrim(K_2) + chr(13) + chr(10) + ;     // наименование 
                                   Alltrim(K_4) + chr(13) + chr(10) + ;     // рег. nr 
                                   Alltrim(K_6) } )                         // pvn. nr   
  
    sCols( R08.K_E4, cHeading, 'Excel' + CRLF + 'line' )                    // для клиента адресов 
    sCols( R08.K_E4, nAlign  , DT_CENTER ) 
    sCols( R08.K_E4, nWidth  , TxtWidth(5) ) 
    sCols( R08.K_E4, bData   , {|| hb_ntos(K_E4) + chr(13) + chr(10) + ;    // Adr. jur. 
                                   hb_ntos(K_E5) + chr(13) + chr(10) + ;    // Adr. fiz. 
                                   hb_ntos(K_E6) } )                        // telefon      
                    
    sCols( R08.K_8 , cHeading, gTxt(AdrJur) + CRLF + gTxt(AdrFiz) + CRLF + gTxt(Telef)    ) 
    sCols( R08.K_8 , nWidth  , TxtWidth(30) ) 
    sCols( R08.K_8 , bData   , {|| Alltrim(K_8) + chr(13) + chr(10) + ;     // Adr. jur. 
                                   Alltrim(K_A) + chr(13) + chr(10) + ;     // Adr. fiz. 
                                   Alltrim(K_C) } )                         // telefon   
  
    sCols( R08.K_E4, cHeading, 'Excel' + CRLF + 'line' )                    // для клиента данных банка 
    sCols( R08.K_E4, nAlign  , DT_CENTER ) 
    sCols( R08.K_E4, nWidth  , TxtWidth(5) ) 
    sCols( R08.K_E4, bData   , {|| hb_ntos(K_E1) + chr(13) + chr(10) + ;    // Banka 
                                   hb_ntos(K_E4) + chr(13) + chr(10) + ;    // Kods 
                                   hb_ntos(K_E6) } )                        // Konts    
                    
    sCols( R08.K_E , cHeading, gTxt(Banka) + CRLF + gTxt(BankKod) + CRLF + gTxt(BankScet) ) 
    sCols( R08.K_E , nWidth  , TxtWidth(30) ) 
    sCols( R08.K_E , bData   , {|| Alltrim(K_E) + chr(13) + chr(10) + ;     // Banka 
                                   Alltrim(K_G) + chr(13) + chr(10) + ;     // Kods  
                                   Alltrim(K_I) } )                         // Konts   
  
  
    Stru2Cols(R09_Stru(), cR09) 
 ... 
 FUNC Child_R08( oWnd ) 
 .. 
    dbSelectArea(cR08) 
  
    AAdd(aCols, gCols( R08.D_2 )) 
    AAdd(aCols, gCols( R08.K_2 )) 
    AAdd(aCols, gCols( R08.K_8 )) 
    AAdd(aCols, gCols( R08.K_E )) 
     
    DEFINE WINDOW &cWnd                              ; 
 ... 
       DEFINE TBROWSE &cBrw OBJ oBrw AT y, x ALIAS ALIAS() WIDTH w HEIGHT h CELL 
  
       :hFontHead := GetFontHandle( "TsbHeader" ) 
       :hFontFoot := GetFontHandle( "TsbFooter" ) 
        
       :nWheelLines  := 1 
       :lNoHScroll   := .T. 
       :lFooting     := .T. 
       :lDrawFooters := .T. 
       :lNoGrayBar   := .T. 
       :lNoLiteBar   := .F. 
       :lNoResetPos  := .F. 
       :lPickerMode  := .F. 
       :nLineStyle   := LINES_ALL 
       :nClrLine     := COLOR_GRID 
       :lNoChangeOrd := .T. 
       :nColOrder    := 0 
  
       AEval( aCols, {| oc| :AddColumn( oc ) } ) 
  
       :SetColor( { CLR_FOCUSB }, { { |a,b,c| If( c:nCell == b, {RGB( 66, 255, 236), RGB(209, 227, 248)}, ;   
                                                                {RGB(220, 220, 220), RGB(220, 220, 220)} ) } } )             
  
       :nMemoHV := 1                   // список документов по уникальному тэгу клиента однострочный 
 //      :nMemoHV := 0                  // список  документов в три строки 
       :nHeightCell -= 1 
       :ResetVScroll( .T. ) 
       :oHScroll:SetRange( 0, 0 ) 
       :AdjColumns() 
  
       END TBROWSE 
  
       oBrw:SetNoHoles() 
       oBrw:SetFocus() 
 ... 
 Достичь того же можно и такими действиями и возможно это лучше в каких то случаях 
    AAdd(aCols, gCols( R08.D_2 )) 
    aCols[1]:cHeading := gTxt(Pavadz) 
    aCols[1]:bData := {|| alltrim(D_2) } 
    AAdd(aCols, gCols( R08.K_2 )) 
    aCols[2]:cHeading := gTxt(Nosut) 
    aCols[2]:bData := {|| Alltrim(K_2) }  
    AAdd(aCols, gCols( R08.K_8 )) 
    aCols[3]:cHeading := gTxt(AdrJur) 
    aCols[3]:bData := {|| Alltrim(K_8) }  
    AAdd(aCols, gCols( R08.K_E )) 
    aCols[4]:cHeading := gTxt(Bank) 
    aCols[4]:bData := {|| Alltrim(K_E) }  
 ... 
 

 
 CLASS ColorN2H 
 ... 
   VAR nDef              INIT CLR_SILVER 
   VAR cDef              INIT HMG_ClrToHTML( CLR_SILVER ) // HEX_SILVER 
 ... 
 METHOD Def( nDef, cDef ) CLASS ColorN2H 
    LOCAL aClr 
  
    If nDef != Nil .and. HB_ISNUMERIC(nDef) 
       ::nDef := nDef 
    EndIf 
  
    If cDef != Nil .and. HB_ISCHAR(cDef) 
       ::cDef := cDef 
    EndIf 
  
    aClr := {                            ; 
              CLR_BLACK                , ; 
              CLR_MAROON               , ; 
              CLR_DARKRED              , ; 
              CLR_RED                  , ; 
              CLR_ORANGERED            , ; 
              CLR_DARKGREEN            , ; 
              CLR_GREEN                , ; 
              CLR_OLIVE                , ; 
              CLR_DARKORANGE           , ; 
              CLR_ORANGE               , ; 
              CLR_GOLD                 , ; 
              CLR_LAWNGREEN            , ; 
              CLR_LIME                 , ; 
              CLR_CHARTREUSE           , ; 
              CLR_DARKGOLDENROD        , ; 
              CLR_SADDLEBROWN          , ; 
              CLR_CHOCOLATE            , ; 
              CLR_GOLDENROD            , ; 
              CLR_FIREBRICK            , ; 
              CLR_FORESTGREEN          , ; 
              CLR_OLIVEDRAB            , ; 
              CLR_BROWN                , ; 
              CLR_SIENNA               , ; 
              CLR_DARKOLIVEGREEN       , ; 
              CLR_GREENYELLOW          , ; 
              CLR_LIMEGREEN            , ; 
              CLR_YELLOWGREEN          , ; 
              CLR_CRIMSON              , ; 
              CLR_PERU                 , ; 
              CLR_TOMATO               , ; 
              CLR_DARKSLATEGRAY        , ; 
              CLR_CORAL                , ; 
              CLR_SEAGREEN             , ; 
              CLR_YELLOW               , ; 
              CLR_SANDYBROWN           , ; 
              CLR_DIMGRAY              , ; 
              CLR_DARKKHAKI            , ; 
              CLR_MIDNIGHTBLUE         , ; 
              CLR_MEDIUMSEAGREEN       , ; 
              CLR_SALMON               , ; 
              CLR_DARKSALMON           , ; 
              CLR_LIGHTSALMON          , ; 
              CLR_SPRINGGREEN          , ; 
              CLR_NAVY                 , ; 
              CLR_PURPLE               , ; 
              CLR_TEAL                 , ; 
              CLR_GRAY                 , ; 
              CLR_LIGHTCORAL           , ; 
              CLR_INDIGO               , ; 
              CLR_MEDIUMVIOLETRED      , ; 
              CLR_BURLYWOOD            , ; 
              CLR_DARKBLUE             , ; 
              CLR_DARKMAGENTA          , ; 
              CLR_DARKSLATEBLUE        , ; 
              CLR_DARKCYAN             , ; 
              CLR_TAN                  , ; 
              CLR_KHAKI                , ; 
              CLR_ROSYBROWN            , ; 
              CLR_DARKSEAGREEN         , ; 
              CLR_SLATEGRAY            , ; 
              CLR_LIGHTGREEN           , ; 
              CLR_DEEPPINK             , ; 
              CLR_PALEVIOLETRED        , ; 
              CLR_PALEGREEN            , ; 
              CLR_LIGHTSLATEGRAY       , ; 
              CLR_MEDIUMSPRINGGREEN    , ; 
              CLR_CADETBLUE            , ; 
              CLR_DARKGRAY             , ; 
              CLR_LIGHTSEAGREEN        , ; 
              CLR_MEDIUMAQUAMARINE     , ; 
              CLR_PALEGOLDENROD        , ; 
              CLR_NAVAJOWHITE          , ; 
              CLR_WHEAT                , ; 
              CLR_HOTPINK              , ; 
              CLR_STEELBLUE            , ; 
              CLR_MOCCASIN             , ; 
              CLR_PEACHPUFF            , ; 
              CLR_SILVER               , ; 
              CLR_LIGHTPINK            , ; 
              CLR_BISQUE               , ; 
              CLR_PINK                 , ; 
              CLR_DARKORCHID           , ; 
              CLR_MEDIUMTURQUOISE      , ; 
              CLR_MEDIUMBLUE           , ; 
              CLR_SLATEBLUE            , ; 
              CLR_BLANCHEDALMOND       , ; 
              CLR_LEMONCHIFFON         , ; 
              CLR_TURQUOISE            , ; 
              CLR_DARKTURQUOISE        , ; 
              CLR_LIGHTGOLDENRODYELLOW , ; 
              CLR_DARKVIOLET           , ; 
              CLR_MEDIUMORCHID         , ; 
              CLR_LIGHTGRAY            , ; 
              CLR_AQUAMARINE           , ; 
              CLR_PAPAYAWHIP           , ; 
              CLR_ORCHID               , ; 
              CLR_ANTIQUEWHITE         , ; 
              CLR_THISTLE              , ; 
              CLR_MEDIUMPURPLE         , ; 
              CLR_GAINSBORO            , ; 
              CLR_BEIGE                , ; 
              CLR_CORNSILK             , ; 
              CLR_PLUM                 , ; 
              CLR_LIGHTSTEELBLUE       , ; 
              CLR_LIGHTYELLOW          , ; 
              CLR_ROYALBLUE            , ; 
              CLR_MISTYROSE            , ; 
              CLR_BLUEVIOLET           , ; 
              CLR_LIGHTBLUE            , ; 
              CLR_POWDERBLUE           , ; 
              CLR_LINEN                , ; 
              CLR_OLDLACE              , ; 
              CLR_SKYBLUE              , ; 
              CLR_CORNFLOWERBLUE       , ; 
              CLR_MEDIUMSLATEBLUE      , ; 
              CLR_VIOLET               , ; 
              CLR_PALETURQUOISE        , ; 
              CLR_SEASHELL             , ; 
              CLR_FLORALWHITE          , ; 
              CLR_HONEYDEW             , ; 
              CLR_IVORY                , ; 
              CLR_LAVENDERBLUSH        , ; 
              CLR_WHITESMOKE           , ; 
              CLR_LIGHTSKYBLUE         , ; 
              CLR_LAVENDER             , ; 
              CLR_SNOW                 , ; 
              CLR_MINTCREAM            , ; 
              CLR_BLUE                 , ; 
              CLR_FUCHSIA              , ; 
              CLR_DODGERBLUE           , ; 
              CLR_DEEPSKYBLUE          , ; 
              CLR_ALICEBLUE            , ; 
              CLR_GHOSTWHITE           , ; 
              CLR_CYAN                 , ; 
              CLR_LIGHTCYAN            , ; 
              CLR_AZURE                , ; 
              CLR_WHITE                  ; 
            }                             
  
    AEval(aClr, {|nclr| ::oNH:Set( nclr, HMG_ClrToHTML( nclr ) ) }) 
  
    ::nLenN := Len( hb_ntos(::oNH:Len) ) 
  
 RETURN Self    
 ...