#include "hbgtinfo.ch" 
  
 FUNCTION bkInit( cIniName, aParams ) 
    Local cPath := hb_curDrive() + ":\" + Curdir() + '\' 
    Local cName := hb_ProgName(), cTmp, cCP, nHis 
    Local cExe  := Lower(hb_fnameName(cName)) 
    LOCAL cCapt := cExe 
    LOCAL aPal  := {}, cPal, nPal 
  
    FOR nPal := 0 TO 9 
        cTmp := Lower( gIniC7(cIniName, [PALETTE_]+hb_ntos(nPal), 'Name', '') ) 
        IF Empty(cTmp) 
           EXIT 
        ENDIF 
        AAdd(aPal, cTmp) 
    NEXT 
  
    FOR EACH cTmp IN aParams 
       IF Left( cTmp,4 ) == "-cp=" 
          cCP := Upper( Substr( cTmp, 5 ) ) 
  
       ELSEIF Left( cTmp,4 ) == "-his=" 
          nHis := Val( Substr( cTmp, 6 ) ) 
          IF nHis < 0 .OR. nHis > 2 
             nHis := Nil 
          ENDIF 
  
       ELSEIF Left( cTmp,5 ) == "-pal=" 
          nPal := Val( Substr( cTmp, 6 ) ) + 1 
          IF nPal > 0 
             nPal := iif( nPal > Len(aPal), Len(aPal), nPal ) 
             cPal := aPal[ nPal ] 
          ENDIF 
  
       ENDIF 
    NEXT 
    IF !Empty(cCP) 
       hb_cdpSelect( cCP ) 
    ENDIF 
    IF nHis != NIL 
       TEdit():options["savehis"] := nHis 
    ENDIF 
    IF !Empty(cPal) 
       TEdit():cDefPal := cPal 
    ENDIF 
  
    cTmp := Lower(gIniC7(cIniName, [OPTIONS], 'PathInHead', 'off')) 
  
    If 'off' $ cTmp 
       cCapt := cPath + Repl(' .', 3) + space(1) + '-' + space(1) + cExe 
    EndIf 
  
    CLS ; hb_gtInfo( HB_GTI_WINTITLE, cCapt ) 
  
    TEdit():bNew := {|oe| iif( oe:y1 == oe:aRectFull[1]+1, ( oe:lTopPane := .F., oe:y1-- ), ), ; 
                          oe:bWriteTopPane := {|o,l,y| StbLine(o,l,y) } } 
  
 RETURN Nil 
 

 
 METHOD WriteTopPane( lClear ) CLASS TEdit 
  
    LOCAL y := ::y1 - 1, nCol := Col(), nRow := Row(), nF9 := 0 
    LOCAL cLen := Ltrim(Str(Len(::aText))), nchars := Len(cLen) 
  
    IF ::oParent != Nil .AND. ::x1 == ::oParent:x2 + 2 
       Scroll( ::y1, ::x1-1, ::y2, ::x1-1 ) 
    ENDIF 
  
    If ::lTopPane 
       DispBegin() 
       SetColor( ::cColorPane ) 
       Scroll( y, ::x1, y, ::x2 ) 
       IF ::oParent != Nil .AND. ::x1 == ::oParent:x2 + 2 
          Scroll( ::y1, ::x1-1, ::y2, ::x1-1 ) 
       ENDIF 
       SetColor( ::cColor ) 
       DevPos( nRow, nCol ) 
       DispEnd() 
    EndIf 
  
    IF ::bWriteTopPane != Nil 
       Eval( ::bWriteTopPane, Self, lClear, y ) 
    ELSE 
       IF ::lTopPane 
          DispBegin() /* 
          SetColor( ::cColorPane ) 
          Scroll( y, ::x1, y, ::x2 ) */ 
          IF Empty( lClear ) 
             DevPos( y, ::x1 ) 
             IF ::x2 - ::x1 > 54 
                DevOut( "F9-menu" ) 
                DevPos( y, ::x1+8 ) 
                nF9 := 8 
             ENDIF 
             DevOut( Iif( hb_hGetDef(::options,"pathinhead",.F.), NameShortcut(::cFileName,::nTopName,'~'), ; 
                cp_Left( ::lUtf8, hb_fnameNameExt(::cFileName), ::nTopName ) ) ) 
             IF !Empty( cDopMode ) 
                DevPos( y, ::x1 ) 
                DevOut( Padr( cDopMode, 8 ) ) 
             ENDIF 
             DevPos( y, ::x1 + nF9 + ::nTopName + 2 ) 
             DevOut( Iif( ::lUpdated, "* ", "  " ) + Lower( ::cp ) ) 
             DevPos( y, ::x1 + nF9 + ::nTopName + 12 ) 
             DevOut( PAdl(Ltrim(Str(::nLine)),nchars) + "/" + cLen ) 
             DevPos( y, ::x1 + nF9 + ::nTopName + 12 + nchars*2 + 3 ) 
             DevOut( "[" + Ltrim(Str(::PosToCol()-::x1+::nxFirst)) + "]" ) 
             SetColor( ::cColorWB ) 
             DevPos( y, ::x2-3 ) 
             IF ::lF3 .OR. (::nby1 >= 0 .AND. ::nby2 >= 0) 
                DevOut( "Sele" ) 
             ELSE 
                DevOut( Iif( ::nMode == 0, Iif( ::lReadOnly, "View", "Edit" ), ; 
                   Iif( ::nMode == 1, " Vim", " Cmd" ) ) ) 
             ENDIF 
          ENDIF 
          SetColor( ::cColor ) 
          DevPos( nRow, nCol ) 
          DispEnd() 
       ENDIF 
    ENDIF 
  
    RETURN Nil