METHOD InsColNumber( nWidth, nColumn, cName ) CLASS TSBrowse 
    LOCAL oCol 
  
    nWidth  := hb_defaultValue( nWidth , 80 ) 
    nColumn := hb_defaultValue( nColumn, 1 ) 
    cName   := hb_defaultValue( cName, iif( ::lIsDbf, "ORDKEYNO", "ARRAYNO" ) ) 
  
    IF ::lIsDbf 
  
       DEFINE COLUMN oCol DATA 'hb_ntos(iif( IndexOrd() > 0, ORDKEYNO(), RecNo() ))' ; 
          HEADER '#' ; 
          FOOTER ' ' ; 
          ALIGN 1, 1, 1 ; 
          WIDTH nWidth ; 
          PICTURE '9999999' ; 
          MOVE 0 ; 
          DBLCURSOR ; 
          NAME &(cName) 
  
       oCol:lEdit := .F. 
       oCol:cAlias := ::cAlias 
       oCol:cFooting := {| nc, ob | nc := ob:nLen, iif( Empty( nc ), '', hb_ntos( nc ) ) } 
  
 #ifndef __XHARBOUR__ 
       oCol:cData := 'hb_macroblock("' + oCol:cField + '")' 
       oCol:bData := hb_macroBlock( oCol:cField ) 
 #else 
       oCol:cData := '{|| ' + oCol:cField + '}' 
       oCol:bData := &( '{|| ' + oCol:cField + '}' ) 
 #endif 
       ELSEIF ::lIsArr 
  
          DEFINE COLUMN oCol DATA {|| NIL } ; 
             HEADER '#' ; 
             FOOTER ' ' ; 
             ALIGN 1, 1, 1 ; 
             WIDTH nWidth ; 
             PICTURE '9999999' ; 
             MOVE 0 ; 
             DBLCURSOR ; 
             NAME &(cName) 
  
          oCol:cFooting := {| nc, ob | nc := ob:nLen, iif( Empty( nc ), '', hb_ntos( nc ) ) } 
          oCol:bValue := {| xx, ob | xx := ob, hb_ntos( ob:nAt ) } 
  
       ENDIF 
  
       oCol:lEmptyValToChar := .T. 
       oCol:cFieldTyp := 'N' 
       oCol:nFieldLen := 10 
       oCol:nFieldDec := 0 
  
       IF nColumn > 0 .and. nColumn <= Len( ::aColumns ) 
          ::InsColumn( nColumn, oCol ) 
       ENDIF 
  
 RETURN oCol 
 

 
       DEFINE TBROWSE oBrw AT nY, nX Alias ( uAlias ) WIDTH nWidth HEIGHT nHeight HEADER aCols ; 
              AUTOCOLS SELECTOR 20 ; 
              ON INIT  {|ob| ob:nColOrder     :=  0 , ; 
                             ob:lNoGrayBar    := .F., ; 
                             ob:lNoLiteBar    := .F., ; 
                             ob:lNoResetPos   := .F., ; 
                             ob:nStatusItem   :=  0 , ; 
                             ob:lNoKeyChar    := .T., ; 
                             ob:nWheelLines   :=  1 , ; 
                             ob:nCellMarginLR :=  1 , ; 
                             ob:nLineStyle := LINES_ALL , ; 
                             ob:nClrLine   := COLOR_GRID, ; 
                             ob:lCheckBoxAllReturn := .T. } 
  
          oBrw:Cargo := uParam 
  
          lEdit := Eval( bSetUp, oBrw ) 
          lEdit := iif( ValType( lEdit ) == "L", lEdit, .F. ) 
  
          WITH OBJECT oBrw 
             :lEditable := lEdit 
             :lCellBrw := ( lEdit .OR. lCellBrw ) 
             //:nClrLine := COLOR_GRID 
             //:nClrHeadBack := { CLR_WHITE, COLOR_GRID } 
             :lUpdate := .T. 
             //:Cargo := uParam 
             :bRClicked := {|| _SetThisFormInfo( oBrw:cParentWnd ), SBrowse_Record( oBrw, , bRecord ), _SetThisFormInfo() } 
             :lRecLockArea := .T. 
 ... 
 

 
  
 #define  _HMG_OUTLOG 
 #include "minigui.ch" 
 #include "tsbrowse.ch" 
 #include "dbinfo.ch" 
  
 *----------------------------------- 
 Function Main() 
 *----------------------------------- 
    Local cTitle := "Test Browse: Right Click For Record View", ; 
          bSetup := { |oBrw,lAft| SetMyBrowser( oBrw, lAft ) }, ; 
          cFont  := "Tahoma", nSize := 10 
  
    CreateTable() 
  
    USE Test NEW 
  
    SET AUTOADJUST ON NOBUTTONS 
  
    SET FONT TO cFont, nSize 
  
    DEFINE FONT Normal FONTNAME cFont SIZE nSize 
    DEFINE FONT Bold   FONTNAME cFont SIZE nSize BOLD 
  
    SET DEFAULT ICON TO GetStartupFolder() + "\demo.ico" 
  
    DEFINE WINDOW sample AT 0,0 WIDTH 740 HEIGHT 580 ; 
       TITLE "Open Table via SBrowse" ; 
       MAIN NOSHOW ; 
       ON INIT ( SBrowse( "Test", cTitle, bSetup,,,,,, .T. ), This.t_1.Enabled := .T. ) ; 
       ON RELEASE ( dbCloseArea( "Test" ), hb_dbDrop( "Test" ) ) 
  
       DEFINE TIMER t_1 INTERVAL 1000 ACTION iif( Empty(CountChildWindows()), ThisWindow.Release(), ) 
  
       This.t_1.Enabled := .F. 
  
    END WINDOW 
  
    sample.Center() 
    sample.Activate() 
  
 Return Nil 
  
 *----------------------------------- 
 Function CreateTable 
 *----------------------------------- 
  
    DBCREATE("Test", {{"CODE", "C", 3, 0},{"NAME", "C", 50, 0},{"RESIDENTS", "N", 11, 0},{"NOTES", "M", 10, 0}},,.T.) 
  
    DBAPPEND() 
    REPLACE CODE WITH 'LTU', NAME WITH 'Lithuania', RESIDENTS WITH 3369600 
    DBAPPEND() 
    REPLACE CODE WITH 'USA', NAME WITH 'United States of America', RESIDENTS WITH 305397000 
    DBAPPEND() 
    REPLACE CODE WITH 'POR', NAME WITH 'Portugal', RESIDENTS WITH 10617600 
    DBAPPEND() 
    REPLACE CODE WITH 'POL', NAME WITH 'Poland', RESIDENTS WITH 38115967 
    DBAPPEND() 
    REPLACE CODE WITH 'AUS', NAME WITH 'Australia', RESIDENTS WITH 21446187 
    DBAPPEND() 
    REPLACE CODE WITH 'FRA', NAME WITH 'France', RESIDENTS WITH 64473140 
    DBAPPEND() 
    REPLACE CODE WITH 'RUS', NAME WITH 'Russia', RESIDENTS WITH 141900000 
    DBAPPEND() 
    REPLACE CODE WITH 'LAT', NAME WITH 'Latvja', RESIDENTS WITH 7654321 
    DBAPPEND() 
    REPLACE CODE WITH 'DEM', NAME WITH 'Germanija', RESIDENTS WITH 1234567 
    USE 
  
 Return Nil 
  
 *----------------------------------- 
 Function SetMyBrowser( oBrw, lAft ) 
 *----------------------------------- 
 Local cFormName := oBrw:cParentWnd, cTitle, oCol, hFont 
  
    If Empty(lAft) 
       SetProperty( cFormName, "MinWidth", 920 ) 
       SetProperty( cFormName, "MinHeight", 480 ) 
  
       oBrw:nHeightCell += 5 
       oBrw:nHeightHead += 12 
       oBrw:nClrFocuFore := CLR_BLACK 
       oBrw:nClrFocuBack := COLOR_GRID 
  
       hFont := GetFontHandle( "Bold" ) 
       oBrw:hFontSupHd   := hFont 
       oBrw:nHeightSuper := oBrw:nHeightHead 
  
       cTitle := " [" + oBrw:cAlias + "] " + DBINFO( DBI_FULLPATH ) 
  
       ADD SUPER HEADER TO oBrw FROM 1 TO 2                TITLE " "+RddName() 
       ADD SUPER HEADER TO oBrw FROM 3 TO oBrw:nColCount() TITLE cTitle 
  
       FOR EACH oCol IN oBrw:aColumns 
           oCol:hFontHead := hFont 
           oCol:hFontFoot := hFont 
       NEXT 
  
    Else 
       oCol := ATail(oBrw:aColumns) 
       ATail(oBrw:aSuperHead)[ 2] := oBrw:nColumn(oCol:cName) 
       IF oBrw:nLen > oBrw:nRowCount() 
          oBrw:ResetVScroll( .T. ) 
       ENDIF 
       oBrw:SetNoHoles() 
       oBrw:SetFocus() 
    EndIf 
  
 Return .T. // editable browse (return .F. is readonly) 
  
 *----------------------------------- 
 Function CountChildWindows 
 *----------------------------------- 
 Local i, nFormCount := Len (_HMG_aFormHandles), nCnt := 0 
  
    FOR i := 1 TO nFormCount 
       IF _HMG_aFormType [ i ] <> "A" 
    IF _IsWindowDefined ( _HMG_aFormNames [ i ] ) 
       nCnt++ 
    ENDIF 
       ENDIF 
    NEXT 
  
 Return nCnt 
 

 
 FUNCTION SBrowse( uAlias, cTitle, bSetUp, aCols, nWidth, nHeight, lSql, lModal, lNumber ) 
 ... 
    LOCAL uParam, bRecord, nClr, oCol 
 ... 
       ON KEY ESCAPE ACTION {|| iif( oBrw:IsEdit, oBrw:SetFocus(), ThisWindow.RELEASE ) } 
  
       IF lRec 
          nY := Len( oBrw:aColumns ) 
          oBrw:aColumns[ nY - 1 ]:nWidth += 50 
          oBrw:aColumns[ nY - 1 ]:cName  := "KEY" 
          oBrw:aColumns[ nY ]:lEdit := .F. 
          oBrw:aColumns[ nY ]:cName := "VALUE" 
          FOR EACH oCol IN oBrw:aColumns 
              oCol:cPicture := NIL 
              oCol:nAlign   := DT_LEFT 
          NEXT 
          oBrw:AdjColumns( nY ) 
          IF HB_ISOBJECT( oBrw:Cargo ) .and. oBrw:ClassName == "TSBROWSE" .and. oBrw:Cargo:lIsDbf 
             oBrw:Cargo:lRecLockArea := .T. 
             oCol := oBrw:aColumns[3] 
             oCol:lEdit := .T. 
             oCol:bPrevEdit := {|uv,obr| 
                  Local lRet := .T., nn, cn, oc, ob 
                  nn := obr:nAt 
                  cn := obr:GetValue(2) 
                  obr:aColumns[ obr:nCell ]:Cargo := NIL 
                  ob := obr:Cargo 
                  IF !HB_ISOBJECT( ob ) .or. !ob:lIsDbf 
                     RETURN .F. 
                  ENDIF 
                  nn := obr:nAt 
                  oc := ob:GetColumn( cn ) 
                  IF Empty( oc:cFieldTyp ) .or. oc:cName == "SELECTOR" .or. oc:cName == "ORDKEYNO" 
                     lRet := .F. 
                  ELSEIF oc:cFieldTyp $ "T=@+^" 
                     lRet := .F. 
                  ENDIF 
                  IF lRet 
                     obr:aColumns[ obr:nCell ]:Cargo := uv 
                  ENDIF 
                  Return lRet 
                  } 
             oCol:bPostEdit := {|uv,obr| 
                  Local nn, cn, oc, ob, uo, nm 
                  nn := obr:nAt 
                  cn := obr:GetValue(2) 
                  uo := obr:aColumns[ obr:nCell ]:Cargo 
                  IF uo != NIL .and. uo == uv 
                     RETURN Nil 
                  ENDIF 
                  ob := obr:Cargo 
                  IF !HB_ISOBJECT( ob ) .or. !ob:lIsDbf 
                     RETURN Nil 
                  ENDIF 
                  nn := obr:nAt 
                  oc := ob:GetColumn( cn ) 
                  nm := oc:nEditMove 
                  oc:nEditMove := 0 
                  ob:PostEdit(uv, ob:nColumn(oc:cName)) 
                  oc:nEditMove := nm 
                  Return Nil 
                  } 
          ENDIF 
       ENDIF 
  
       IF ! lbSetUp .or. lRec 
          oBrw:SetNoHoles() 
          oBrw:SetFocus() 
          IF lRec 
             oBrw:GoRight() 
          ENDIF 
       ENDIF 
  
       IF HB_ISBLOCK( bAfter ) ; EVal( bAfter, oBrw, .T. ) 
       ELSE                    ; Eval( bSetUp, oBrw, .T. ) 
       ENDIF 
 ...